gentoo-mirror/gentoo
1
0
Fork 0
mirror of https://github.com/gentoo-mirror/gentoo.git synced 2026-08-06 12:58:16 -07:00
Code Issues Projects Releases Wiki Activity

dev-python/mkdocs-git-revision-date-localized-plugin: add version 1.0.0

Browse Source 
Package-Manager: Portage-3.0.30, Repoman-3.0.3
Signed-off-by: Andrew Ammerlaan <andrewammerlaan@gentoo.org>
This commit is contained in:
Andrew Ammerlaan
2022-02-21 20:31:06 +01:00
parent ab030263d1
commit c2cfc7dcd8
2 changed files with 58 additions and 0 deletions
Download Patch File Download Diff File Expand all files Collapse all files

1
dev-python/mkdocs-git-revision-date-localized-plugin/Manifest
View File

@@ -1,2 +1,3 @@
DIST mkdocs-git-revision-date-localized-plugin-0.11.1.tar.gz 369943 BLAKE2B 261813f3d63d6b1bfb021aab3f9db96f7977ac8f6bf6239158f1d8045e1eb5b21b89f2c4eb493634944b202334f59ce589797624137bfc643cda3ef52969bd73 SHA512 fb5e1c1b65f431585dc6a6887fc079a3181e73286697c331317a69f7748453af61abfb8fc58eb55203f09c9a70c752781dd834d03e13184ddb0bb761aa10e371
DIST mkdocs-git-revision-date-localized-plugin-0.12.1.tar.gz 370763 BLAKE2B 6b69b34a18288d042aa754bcb6f3c6a3b96de0016db1ef888d2b0fe09f479964e6d0473d8af700aec904befb79d5a56e775847c87cd06b1ffc90cfdbe6e73b18 SHA512 4368ae0341fa9e3af08f93cce883b03cc9bd3bef16dcec7314c7e439d6524726173ffb60bbc11bcdd9e3c9ef5f1fa7d24a1c01dc543241061c61a8b0f5044614
DIST mkdocs-git-revision-date-localized-plugin-1.0.0.tar.gz 375656 BLAKE2B 3dc850f219ca0396015c474d714412253b05075f5ad55fbfdcc4ed90468466e6c6735904517d598b66cf408c222e83ed35d176b1379a26a97b64d88bcbff06b6 SHA512 632f4e2d0ce8fc0f90707918526e49e2752ecc36c2623eb0df76d49476f6e4b347265166f5f1d6148475bb01bdb61a6337a3edf6ccba2cccb2c372a9aba70cac

57
dev-python/mkdocs-git-revision-date-localized-plugin/mkdocs-git-revision-date-localized-plugin-1.0.0.ebuild Normal file
View File

@@ -0,0 +1,57 @@
# Copyright 1999-2022 Gentoo Authors
# Distributed under the terms of the GNU General Public License v2
EAPI=8
DISTUTILS_USE_PEP517="setuptools"
PYTHON_COMPAT=( python3_{8..10} )
DOCS_BUILDER="mkdocs"
DOCS_DEPEND="
dev-python/mkdocs-i18n
dev-python/mkdocs-material
dev-python/mkdocs-git-authors-plugin
dev-python/mkdocs-git-revision-date-localized-plugin
"
inherit distutils-r1 docs
DESCRIPTION="Display the localized date of the last git modification of a markdown file"
HOMEPAGE="
https://github.com/timvink/mkdocs-git-revision-date-localized-plugin/
https://pypi.org/project/mkdocs-git-revision-date-localized-plugin/
"
SRC_URI="https://github.com/timvink/${PN}/archive/v${PV}.tar.gz -> ${P}.tar.gz"
LICENSE="MIT"
SLOT="0"
KEYWORDS="~amd64"
RDEPEND="
>=dev-python/Babel-2.7.0[${PYTHON_USEDEP}]
dev-python/GitPython[${PYTHON_USEDEP}]
>=dev-python/mkdocs-1.0[${PYTHON_USEDEP}]
"
BDEPEND="
test? (
dev-python/click[${PYTHON_USEDEP}]
dev-python/mkdocs-material[${PYTHON_USEDEP}]
dev-vcs/git
)
doc? ( dev-vcs/git )
"
distutils_enable_tests pytest
python_prepare_all() {
# mkdocs-git-revision-date-localized-plugin's tests need git repo
if use test || use doc; then
git init -q || die
git config --global user.email "you@example.com" || die
git config --global user.name "Your Name" || die
git add . || die
git commit -qm 'init' || die
fi
distutils-r1_python_prepare_all
}