media-plugins/calf: Sync with 0.90.1 changes

Package-Manager: Portage-2.3.62, Repoman-2.3.12
Signed-off-by: Andreas Sturmlechner <asturm@gentoo.org>

media-plugins/calf/calf-9999.ebuild

@@ -1,8 +1,9 @@
 # Copyright 1999-2019 Gentoo Authors
 # Distributed under the terms of the GNU General Public License v2
 
-EAPI=6
-inherit autotools gnome2-utils
+EAPI=7
+
+inherit autotools xdg
 
 DESCRIPTION="A set of open source instruments and effects for digital audio workstations"
 HOMEPAGE="http://calf-studio-gear.org/"
@@ -17,23 +18,35 @@ fi
 
 LICENSE="LGPL-2.1"
 SLOT="0"
-IUSE="cpu_flags_x86_sse gtk jack lash lv2 static-libs experimental"
+IUSE="cpu_flags_x86_sse experimental gtk jack lash lv2 static-libs"
 
-RDEPEND="dev-libs/atk
+REQUIRED_USE="jack? ( gtk )"
+
+BDEPEND="
+	virtual/pkgconfig
+"
+DEPEND="
+	dev-libs/atk
 	dev-libs/expat
 	dev-libs/glib:2
-	media-sound/fluidsynth
-	jack? ( virtual/jack )
+	media-sound/fluidsynth:=
 	gtk? (
 		x11-libs/cairo
-		x11-libs/gtk+:2
 		x11-libs/gdk-pixbuf
+		x11-libs/gtk+:2
 		x11-libs/pango
 	)
+	jack? ( virtual/jack )
 	lash? ( media-sound/lash )
-	lv2? ( media-libs/lv2 )"
-DEPEND="${RDEPEND}
-	virtual/pkgconfig"
+	lv2? ( media-libs/lv2 )
+"
+RDEPEND="${DEPEND}"
+
+PATCHES=(
+	"${FILESDIR}/${PN}-0.90.1-no-automagic.patch"
+	"${FILESDIR}/${PN}-0.90.1-htmldir.patch"
+	"${FILESDIR}/${PN}-0.90.1-desktop.patch"
+)
 
 src_prepare() {
 	default
@@ -41,24 +54,23 @@ src_prepare() {
 }
 
 src_configure() {
-	# automagic...
-	#$(use_with gtk gui)
-	#$(use_with jack)
-	econf \
-		--prefix="${EPREFIX}"/usr \
-		--without-obsolete-check \
-		$(use_with lash) \
-		$(use_with lv2 lv2) \
-		$(usex lv2 "--with-lv2-dir=${EPREFIX}/usr/$(get_libdir)/lv2" "") \
-		$(use_enable static-libs static) \
-		$(use_enable cpu_flags_x86_sse sse) \
+	local myeconfargs=(
+		--prefix="${EPREFIX}"/usr
+		--without-obsolete-check
 		$(use_enable experimental)
+		$(use_enable gtk gui)
+		$(use_enable jack)
+		$(use_with lash)
+		$(use_with lv2 lv2)
+		$(usex lv2 "--with-lv2-dir=${EPREFIX}/usr/$(get_libdir)/lv2" "")
+		$(use_enable static-libs static)
+		$(use_enable cpu_flags_x86_sse sse)
+	)
+	econf "${myeconfargs[@]}"
 }
 
-pkg_postinst() {
-	gnome2_icon_cache_update
-}
-
-pkg_postrm() {
-	gnome2_icon_cache_update
+src_install() {
+	default
+	mv "${ED}"/usr/share/bash-completion/completions/calf \
+		"${ED}"/usr/share/bash-completion/completions/calfjackhost
 }