dev-util/dbus-test-runner: 19.04.0 version bump

Package-Manager: Portage-2.3.77, Repoman-2.3.17
Signed-off-by: Andreas Sturmlechner <asturm@gentoo.org>

dev-util/dbus-test-runner/Manifest

@@ -1 +1,2 @@
 DIST dbus-test-runner-15.04.0_p100.tar.xz 304760 BLAKE2B 0afe953376482276229ddf7a5f8e6b9a79c6ea6003f658b38f292099ec42d65b9c4a913f963bf013a2999066c4ad97bf7bc593074c1d393aa2d000d51d7f7f7b SHA512 4ff94fe022d69c0bc83b35fb14397fb59daa0b6a9ff9d7f0c93582bc5468ba6e495d4b95f9b4d8cb56f0b782d4582dc2cb67fc087aefa59295a3b40ecdbfa34d
+DIST dbus-test-runner-19.04.0.tar.gz 444289 BLAKE2B dc3b11c8d376103b320d98d211bf1ace035a2de5a1caceadd946bfdc46a6aab3fcf69fae15c7142500b9487a9832275a6157f887c8efcbbb56d13c8841609dd0 SHA512 5906225f0ce429ea218d7eb4c67281b7ef368d6a173965b214f4f4501e729002ca3293a94fd8afd3002f301cd1f2208cba01c733f678c2d51661220e8a7ce971

dev-util/dbus-test-runner/dbus-test-runner-19.04.0.ebuild

@@ -0,0 +1,51 @@
+# Copyright 1999-2019 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+PYTHON_COMPAT=( python3_{5,6} )
+inherit flag-o-matic python-single-r1
+
+DESCRIPTION="Run executables under a new DBus session for testing"
+HOMEPAGE="https://launchpad.net/dbus-test-runner"
+SRC_URI="https://launchpad.net/${PN}/$(ver_cut 1-2)/${PV}/+download/${P}.tar.gz"
+
+LICENSE="GPL-3"
+SLOT="0"
+KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~ia64 ~ppc ~ppc64 ~sparc ~x86"
+IUSE="test"
+REQUIRED_USE="${PYTHON_REQUIRED_USE}"
+
+# now optional:
+#	test? ( dev-util/bustle )
+BDEPEND="
+	dev-util/gdbus-codegen
+	dev-util/intltool
+"
+COMMON_DEPEND="${PYTHON_DEPS}
+	dev-libs/dbus-glib
+	dev-libs/glib:2
+"
+DEPEND="${COMMON_DEPEND}
+	test? ( dev-python/dbusmock[${PYTHON_USEDEP}] )
+"
+RDEPEND="${COMMON_DEPEND}
+	dev-python/dbusmock[${PYTHON_USEDEP}]
+"
+
+src_prepare() {
+	default
+
+	# bind to specific Python version (with dbusmock installed)
+	sed -i -e "s:python3:${EPYTHON}:" \
+		libdbustest/dbus-mock.c tests/test-libdbustest-mock.c || die
+}
+
+src_configure() {
+	econf --disable-static
+}
+
+src_install() {
+	default
+	find "${D}" -name '*.la' -type f -delete || die
+}