net-im/element-desktop-bin: add 1.10.9

Closes: https://bugs.gentoo.org/838313
Signed-off-by: Duje Mihanović <duje.mihanovic@skole.hr>
Closes: https://github.com/gentoo/gentoo/pull/25025
Signed-off-by: Joonas Niilola <juippis@gentoo.org>

net-im/element-desktop-bin/Manifest

@@ -1 +1,2 @@
 DIST element-desktop_1.10.7_amd64.deb 95797406 BLAKE2B bf189092b2c008d53e7f77aea8cb846c77b20f66110876ac83c7105f3c3a44edd759ffeb2d0a8e027ca4bccbb0ed3b225d3d2ac139a378a462a25a74b1c4dc62 SHA512 72bb749498e95920933156a27d0bd547cfe8ab02b9aa976fdc7574501a7e77d9f6af47e2a951c121251a313d621c32150631ece6aaf3ec0a0856363d482fbd5a
+DIST element-desktop_1.10.9_amd64.deb 96015622 BLAKE2B 49045e4feae24a3cd369266885253f5c2ad861e3089d8bd3ce72070e60653cd959a92ebd98e2668f6fedfa3e2da722895f9091ab8418df15fe52a99c2c88133b SHA512 47281a5013165cb642c6bad35f68df3be00e9d2a8397098668429afed49513b8aa09f9adace12b4625bf958ce41250b0cee570bf500875ce5b0cba1b6dac283a

net-im/element-desktop-bin/element-desktop-bin-1.10.9.ebuild

@@ -0,0 +1,81 @@
+# Copyright 2020-2022 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+inherit unpacker xdg
+
+MY_PN="element-desktop"
+
+DESCRIPTION="A glossy Matrix collaboration client for desktop (binary package)"
+HOMEPAGE="https://element.io"
+SRC_URI="https://packages.riot.im/debian/pool/main/e/element-desktop/${MY_PN}_${PV}_amd64.deb"
+S="${WORKDIR}"
+
+LICENSE="Apache-2.0"
+SLOT="0"
+KEYWORDS="~amd64"
+IUSE="+emoji"
+RESTRICT="splitdebug"
+
+RDEPEND="app-accessibility/at-spi2-atk:2
+	app-crypt/libsecret
+	dev-db/sqlcipher
+	dev-libs/atk
+	dev-libs/expat
+	dev-libs/nspr
+	dev-libs/nss
+	media-libs/alsa-lib
+	media-libs/mesa
+	net-print/cups
+	x11-libs/cairo
+	x11-libs/gdk-pixbuf:2
+	x11-libs/gtk+:3
+	x11-libs/libdrm
+	x11-libs/libxcb
+	x11-libs/libX11
+	x11-libs/libXcomposite
+	x11-libs/libXcursor
+	x11-libs/libXdamage
+	x11-libs/libXext
+	x11-libs/libXfixes
+	x11-libs/libXi
+	x11-libs/libXrandr
+	x11-libs/libXrender
+	x11-libs/libXtst
+	x11-libs/libXScrnSaver
+	x11-libs/pango
+	emoji? ( media-fonts/noto-emoji )"
+DEPEND="${RDEPEND}"
+
+QA_PREBUILT="opt/Element/chrome-sandbox
+	opt/Element/element-desktop
+	opt/Element/libEGL.so
+	opt/Element/libGLESv2.so
+	opt/Element/libffmpeg.so
+	opt/Element/libvk_swiftshader.so
+	opt/Element/libvulkan.so.1
+	opt/Element/swiftshader/libEGL.so
+	opt/Element/swiftshader/libGLESv2.so"
+
+src_prepare() {
+	default
+	rm opt/Element/{LICENSE.electron.txt,LICENSES.chromium.html} || die
+}
+
+src_install() {
+	mv usr/share/doc/${MY_PN} usr/share/doc/${PF} || die
+	gunzip usr/share/doc/${PF}/changelog.gz || die
+
+	insinto /
+	doins -r usr
+	doins -r opt
+	local f
+	for f in ${QA_PREBUILT}; do
+		fperms +x "/${f}"
+	done
+	fperms u+s /opt/Element/chrome-sandbox
+
+	dosym ../../opt/Element/${MY_PN} /usr/bin/${MY_PN}
+	dosym ${MY_PN} /usr/bin/riot-desktop
+}