app-crypt/signify: verify-sig, EAPI 8

Signed-off-by: Anna Vyalkova <cyber+gentoo@sysrq.in>
Closes: https://github.com/gentoo/gentoo/pull/23417
Signed-off-by: Michał Górny <mgorny@gentoo.org>

app-crypt/signify/Manifest

@@ -1 +1,3 @@
+DIST signify-30.sha.sig 246 BLAKE2B b5c26ad1d90ce562a5e6e8cb0a26c031da6bcc9d04cdd668f7b81410ba38ef1777db8f1a4b38fc515c251c840baf38e3df6b3f730a59a0921180ccb88f457fe5 SHA512 b0aea8736b4508ce5a45a296e11150218d694351b15d87478cad235869a6b0150d1893247d1600ea1679d47e71e87e629f5cf4932ecafa2ad4f05aa962f1743d
 DIST signify-30.tar.gz 94593 BLAKE2B 2d432cef9990a8ce23d0f05449ef02dcf7a00f4328a25dcab98cd25c2c74875fd8ea7ed7a67b7e4ac6c9f432a91564edcc1fc9260627c37352c19cc17581aea3 SHA512 4a1ebcdbf7aa74865b97cadbf5380460702306b6d0a77306e6c943bb0c3419ca929ecd3455522da4448d780a56c8eddeb26fb4d7fb006fc3bf23f69693c39e87
+DIST signify-30.tar.xz 73824 BLAKE2B 27de72ac82d9b66346185292cad71e57af0767111123ba0c618a7d5d4add2e5502b546ffd53ffa2956c66b8f00d2b1a96d21958125d5649d6efb23254c0f56ac SHA512 e760fd89de8a3fea76bd0aa52c683e1d331968620190f4ac487bbca30da00f8d6e2636bbe3c59b0e6fa925b1bbcf81516f50c0bc37707ae7e7465b61fee5c372

app-crypt/signify/signify-30-r1.ebuild

@@ -0,0 +1,47 @@
+# Copyright 1999-2021 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+VERIFY_SIG_METHOD="signify"
+inherit toolchain-funcs verify-sig
+
+DESCRIPTION="Cryptographically sign and verify files"
+HOMEPAGE="http://www.openbsd.org/ https://github.com/aperezdc/signify"
+SRC_URI="
+	https://github.com/aperezdc/${PN}/releases/download/v${PV}/${P}.tar.xz
+	verify-sig? (
+		https://github.com/aperezdc/${PN}/releases/download/v${PV}/SHA256.sig
+			-> ${P}.sha.sig
+	)"
+
+LICENSE="BSD-1"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+
+RDEPEND=">=dev-libs/libbsd-0.7"
+DEPEND="${RDEPEND}"
+BDEPEND="verify-sig? ( sec-keys/signify-keys-signify )"
+
+PATCHES=( "${FILESDIR}"/${PN}-30-man_compress.patch )
+
+VERIFY_SIG_OPENPGP_KEY_PATH="${BROOT}/usr/share/signify-keys/${P}.pub"
+
+src_unpack() {
+	if use verify-sig; then
+		# Too many levels of symbolic links
+		cp "${DISTDIR}"/${P}.{sha.sig,tar.xz} "${WORKDIR}" || die
+		verify-sig_verify_signed_checksums \
+			${P}.sha.sig sha256 ${P}.tar.xz
+	fi
+	default
+}
+
+src_configure() {
+	tc-export CC
+}
+
+src_install() {
+	emake DESTDIR="${ED}" PREFIX="/usr" install
+	einstalldocs
+}