mirror of
https://github.com/gentoo-mirror/gentoo.git
synced 2026-11-21 10:37:22 -08:00
kde-apps/k3b: 24.08.0 version bump
Signed-off-by: Andreas Sturmlechner <asturm@gentoo.org>
This commit is contained in:
@@ -1 +1,2 @@
|
||||
DIST k3b-24.05.2.tar.xz 10690836 BLAKE2B 2e9ec4f9a235dd2474019bbb81bd9ca17f399abb4ec594028592513cb53cad0fb454a23e6ba1c356a538a9137cecf9646211a0cad2105e58ec07fed223924b05 SHA512 be8f3c391db45f8af087ec2d4783fb0cff99c58b999f353ad57c12a6e06e40ef14a969755e196816388a122214870d86ac339dcc2ae288a6c87116d609948fdf
|
||||
DIST k3b-24.08.0.tar.xz 10700700 BLAKE2B 862cbc99a3dce93ecfe89d2cb3d995a6f1aacb11a43b298c7ea33c8e04b7a1201516e14ebb09d83a7920ca7639557109cc2ac77cd2e7a272e67c0b04422d9777 SHA512 15b09c4b06b9550c0b8d80eaaf4e077d47e8be3eabef25178d10adf5d2039cb0f7a68963fcff67b7419e2713e4719bc6aeade0821ae51d246b196721b0f3f682
|
||||
|
||||
@@ -0,0 +1,106 @@
|
||||
# Copyright 1999-2024 Gentoo Authors
|
||||
# Distributed under the terms of the GNU General Public License v2
|
||||
|
||||
EAPI=8
|
||||
|
||||
ECM_HANDBOOK="forceoptional"
|
||||
ECM_TEST="true"
|
||||
PVCUT=$(ver_cut 1-3)
|
||||
KFMIN=6.5.0
|
||||
QTMIN=6.7.2
|
||||
inherit ecm gear.kde.org
|
||||
|
||||
DESCRIPTION="Full-featured burning and ripping application based on KDE Frameworks"
|
||||
HOMEPAGE="https://apps.kde.org/k3b/ https://userbase.kde.org/K3b"
|
||||
|
||||
LICENSE="GPL-2 FDL-1.2"
|
||||
SLOT="6"
|
||||
KEYWORDS="~amd64 ~arm64 ~ppc64 ~riscv ~x86"
|
||||
IUSE="dvd ffmpeg flac lame mad musepack sndfile sox taglib vcd vorbis webengine"
|
||||
|
||||
REQUIRED_USE="flac? ( taglib ) lame? ( taglib ) sox? ( taglib )"
|
||||
|
||||
DEPEND="
|
||||
>=dev-qt/qtbase-${QTMIN}:6[dbus,gui,network,widgets,xml]
|
||||
>=kde-apps/libkcddb-${PVCUT}:6
|
||||
>=kde-frameworks/karchive-${KFMIN}:6
|
||||
>=kde-frameworks/kbookmarks-${KFMIN}:6
|
||||
>=kde-frameworks/kcmutils-${KFMIN}:6
|
||||
>=kde-frameworks/kcompletion-${KFMIN}:6
|
||||
>=kde-frameworks/kconfig-${KFMIN}:6
|
||||
>=kde-frameworks/kconfigwidgets-${KFMIN}:6
|
||||
>=kde-frameworks/kcoreaddons-${KFMIN}:6
|
||||
>=kde-frameworks/kfilemetadata-${KFMIN}:6[taglib?]
|
||||
>=kde-frameworks/ki18n-${KFMIN}:6
|
||||
>=kde-frameworks/kiconthemes-${KFMIN}:6
|
||||
>=kde-frameworks/kio-${KFMIN}:6
|
||||
>=kde-frameworks/kjobwidgets-${KFMIN}:6
|
||||
>=kde-frameworks/knewstuff-${KFMIN}:6
|
||||
>=kde-frameworks/knotifications-${KFMIN}:6
|
||||
>=kde-frameworks/knotifyconfig-${KFMIN}:6
|
||||
>=kde-frameworks/kwidgetsaddons-${KFMIN}:6
|
||||
>=kde-frameworks/kxmlgui-${KFMIN}:6
|
||||
>=kde-frameworks/solid-${KFMIN}:6
|
||||
media-libs/libsamplerate
|
||||
dvd? ( media-libs/libdvdread:= )
|
||||
ffmpeg? ( >=media-video/ffmpeg-4.4.0:0= )
|
||||
flac? ( >=media-libs/flac-1.2:=[cxx] )
|
||||
lame? ( media-sound/lame )
|
||||
mad? ( media-libs/libmad )
|
||||
musepack? ( >=media-sound/musepack-tools-444 )
|
||||
sndfile? ( media-libs/libsndfile )
|
||||
taglib? ( >=media-libs/taglib-1.5:= )
|
||||
vorbis? (
|
||||
media-libs/libogg
|
||||
media-libs/libvorbis
|
||||
)
|
||||
webengine? ( >=dev-qt/qtwebengine-${QTMIN}:6 )
|
||||
"
|
||||
RDEPEND="${DEPEND}
|
||||
app-cdr/cdrdao
|
||||
app-cdr/cdrtools
|
||||
dev-libs/libburn
|
||||
media-sound/cdparanoia
|
||||
dvd? ( >=app-cdr/dvd+rw-tools-7 )
|
||||
sox? ( media-sound/sox )
|
||||
vcd? ( media-video/vcdimager )
|
||||
"
|
||||
|
||||
DOCS+=( ChangeLog {FAQ,PERMISSIONS,README}.txt )
|
||||
|
||||
src_configure() {
|
||||
local mycmakeargs=(
|
||||
-DK3B_BUILD_API_DOCS=OFF
|
||||
-DK3B_BUILD_EXTERNAL_ENCODER_PLUGIN=ON
|
||||
-DK3B_BUILD_WAVE_DECODER_PLUGIN=ON
|
||||
-DK3B_ENABLE_HAL_SUPPORT=OFF
|
||||
-DK3B_ENABLE_MUSICBRAINZ=OFF
|
||||
-DK3B_DEBUG=$(usex debug)
|
||||
-DK3B_ENABLE_DVD_RIPPING=$(usex dvd)
|
||||
-DK3B_BUILD_FFMPEG_DECODER_PLUGIN=$(usex ffmpeg)
|
||||
-DK3B_BUILD_FLAC_DECODER_PLUGIN=$(usex flac)
|
||||
-DK3B_BUILD_LAME_ENCODER_PLUGIN=$(usex lame)
|
||||
-DK3B_BUILD_MAD_DECODER_PLUGIN=$(usex mad)
|
||||
-DK3B_BUILD_MUSE_DECODER_PLUGIN=$(usex musepack)
|
||||
-DK3B_BUILD_SNDFILE_DECODER_PLUGIN=$(usex sndfile)
|
||||
-DK3B_BUILD_SOX_ENCODER_PLUGIN=$(usex sox)
|
||||
-DK3B_ENABLE_TAGLIB=$(usex taglib)
|
||||
-DK3B_BUILD_OGGVORBIS_DECODER_PLUGIN=$(usex vorbis)
|
||||
-DK3B_BUILD_OGGVORBIS_ENCODER_PLUGIN=$(usex vorbis)
|
||||
$(cmake_use_find_package webengine Qt6WebEngineWidgets)
|
||||
)
|
||||
|
||||
ecm_src_configure
|
||||
}
|
||||
|
||||
pkg_postinst() {
|
||||
ecm_pkg_postinst
|
||||
|
||||
elog "If you get warnings on start-up, uncheck the \"Check system"
|
||||
elog "configuration\" option in the \"Misc\" settings window."
|
||||
elog
|
||||
local group=cdrom
|
||||
use kernel_linux || group=operator
|
||||
elog "Make sure you have proper read/write permissions on optical device(s)."
|
||||
elog "Usually, it is sufficient to be in the ${group} group."
|
||||
}
|
||||
Reference in New Issue
Block a user