xfce-base/xfce4-power-manager: Bump to 4.19.4

Signed-off-by: Michał Górny <mgorny@gentoo.org>

xfce-base/xfce4-power-manager/Manifest

@@ -1,2 +1,3 @@
 DIST xfce4-power-manager-4.18.4.tar.bz2 1241669 BLAKE2B 7fe0caca8ed87d1178bc2feb6704b7415ba03c2630962798e949e7d6e13956eee26dfd5bdd098d765a28776896e1881d3bf7913f48c6187cf372379300680185 SHA512 829151b99c279a01037544e8a0a2bbe3cb4c1ec90d8943b3159947d819f94e8f73a8e73db255e1151ca59278583a28448b00d6fc002bd1f8a724c1c16c44fb1b
 DIST xfce4-power-manager-4.19.3.tar.bz2 1513388 BLAKE2B dfdad39878e9ee1181053ebbd8248bc7eb9ddccb6bb156d8d6093bcaab657549fc182db5ec766c968dd7a1534c7e3131d468a8cba0876f34b6a61ff8012a6b3e SHA512 984dfc52f4863bf9c9e05e5ae021c4146e5a2f7edff39582d676717073123937980387c1712ce4657c8a4816caf59f73d9e1fd3fa4c54e37ad46c2233f528f23
+DIST xfce4-power-manager-4.19.4.tar.bz2 1523085 BLAKE2B c12de53fe8048575f30eb93eacf27f1758cab078033ded834d40b3c6fbd2deaceba11628f90e8714ab8f6244f91d1a0b5c8b55c4ad9acef735096f6d210d0a39 SHA512 b82f2892a9ba1b9c21bb27aed655d59a05aeadedeec154c2682e7ab0ffdfbc0bd071d573dba1238e48e6b276e3b45628819fccbf27b38d8e845fa02e703812b0

xfce-base/xfce4-power-manager/xfce4-power-manager-4.19.4.ebuild

@@ -0,0 +1,85 @@
+# Copyright 1999-2024 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+inherit xdg-utils
+
+DESCRIPTION="Power manager for the Xfce desktop environment"
+HOMEPAGE="
+	https://docs.xfce.org/xfce/xfce4-power-manager/start
+	https://gitlab.xfce.org/xfce/xfce4-power-manager/
+"
+SRC_URI="https://archive.xfce.org/src/xfce/${PN}/${PV%.*}/${P}.tar.bz2"
+
+LICENSE="GPL-2+"
+SLOT="0"
+KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~loong ~ppc ~ppc64 ~riscv ~x86"
+IUSE="+panel-plugin policykit wayland X"
+REQUIRED_USE="|| ( wayland X )"
+
+DEPEND="
+	>=dev-libs/glib-2.72.0
+	>=sys-power/upower-0.99.10
+	>=x11-libs/gtk+-3.24.0:3[wayland?,X?]
+	>=x11-libs/libnotify-0.7.0
+	>=xfce-base/xfconf-4.12:=
+	>=xfce-base/libxfce4ui-4.18.4:=[gtk3(+)]
+	>=xfce-base/libxfce4util-4.19.2:=
+	panel-plugin? ( >=xfce-base/xfce4-panel-4.14.0:= )
+	policykit? ( >=sys-auth/polkit-0.102 )
+	wayland? (
+		>=dev-libs/wayland-1.20
+	)
+	X? (
+		>=x11-libs/libX11-1.6.7
+		>=x11-libs/libXrandr-1.5.0
+		>=x11-libs/libXext-1.0.0
+		x11-libs/libXtst
+	)
+"
+RDEPEND="
+	${DEPEND}
+"
+DEPEND+="
+	x11-base/xorg-proto
+"
+BDEPEND="
+	dev-util/gdbus-codegen
+	>=sys-devel/gettext-0.19.8
+	virtual/pkgconfig
+	wayland? (
+		>=dev-libs/wayland-protocols-1.25
+		>=dev-util/wayland-scanner-1.20
+	)
+"
+
+src_configure() {
+	local myconf=(
+		$(use_enable policykit polkit)
+		$(use_enable panel-plugin xfce4panel)
+		$(use_enable wayland)
+		$(use_enable X x11)
+	)
+
+	econf "${myconf[@]}"
+}
+
+src_install() {
+	default
+	find "${D}" -name '*.la' -delete || die
+}
+
+pkg_postinst() {
+	xdg_icon_cache_update
+
+	if ! has_version sys-apps/systemd && ! has_version sys-auth/elogind
+	then
+		elog "Suspend/hibernate support requires a logind provider installed"
+		elog "(sys-apps/systemd or sys-auth/elogind)"
+	fi
+}
+
+pkg_postrm() {
+	xdg_icon_cache_update
+}