media-sound/flacon: add 9.4.0

Closes: https://bugs.gentoo.org/877661
Signed-off-by: Philipp Rösner <rndxelement@protonmail.com>
Closes: https://github.com/gentoo/gentoo/pull/27859
Signed-off-by: Joonas Niilola <juippis@gentoo.org>
This commit is contained in:
Philipp Rösner
2022-11-18 10:17:55 +02:00
committed by Joonas Niilola
parent c5a292a42f
commit c25b4e0b4e
2 changed files with 89 additions and 0 deletions
+1
View File
@@ -2,3 +2,4 @@ DIST flacon-5.5.1.tar.gz 2336502 BLAKE2B 524fe5fa28126f56452515ca1ce1572343dad8b
DIST flacon-8.2.0.tar.gz 3757221 BLAKE2B dff0dc849c326a53ad167efea3106ca2d057121081822a821f2daa4cc2140a858960f1b4cdc2935f3e569aac25c25ceece2d171056788b9f541355c540457550 SHA512 9799c1a27426a2f67d782f15a3a1d210c5dc61b00b30b9c4143047a243f2d46cb0eb651c18919fa1ac2a8fdc2f54c83ec2e0b46a00254c908230e7ffb34965bc
DIST flacon-9.0.0.tar.gz 3762192 BLAKE2B abebc21e31fee43f4970b6e56724bfb0b6f2cc7d33e2539def102b329f1228886f7f0fcbb20a2e100a7ba77f6f45bf5ac032151ab0f830676dbf4ce24da0ce3f SHA512 3780f94a4c6c6812eb0a0efd4e677926d8cc53c15f692701cd20df0441f551d4639b632c08a36146873ad11cdb9cdaa4e726845eb05ae15ecc29a1dac250a928
DIST flacon-9.1.0.tar.gz 3769110 BLAKE2B 9e0c4aaef3f6019a8c8196a204e8281ca4250df441ea14127d9347f26557091e87019388bd2942afc39e45a7864d653e2ae887f665ce190f18e646448c3f8e3e SHA512 be35c61e082be7d05bebee5f99192201f91e90f3a80827ac5808e6798f7ed0ada28ab7c2456702c443be51356ec192cd059408c2c3feb5b48b5bab048d0efb00
DIST flacon-9.4.0.tar.gz 3772714 BLAKE2B b45d6f934e80ae1d3546c1c54fdab22dac38d7ccf01b903a8c820145465c5732d34d6118bafcbbb4bde8c5bb528a707ebbee8b6a53ab5a1c29f1562a52c61382 SHA512 9dfd4ce558c4e3ce902c3b2e43b3c3fb94606f68dd550f774e3704d19ce6a28e887a7410054d6becfe3d20166aa687b7689821d6ee095e4efdc30e35a85e70ad
+88
View File
@@ -0,0 +1,88 @@
# Copyright 1999-2022 Gentoo Authors
# Distributed under the terms of the GNU General Public License v2
EAPI=8
# Tests require lots of disk space
CHECKREQS_DISK_BUILD=10G
inherit check-reqs cmake optfeature virtualx xdg-utils
DESCRIPTION="Extracts audio tracks from an audio CD image to separate tracks"
HOMEPAGE="https://flacon.github.io/"
SRC_URI="https://github.com/flacon/flacon/archive/v${PV}.tar.gz -> ${P}.tar.gz"
LICENSE="LGPL-2.1+"
SLOT="0"
KEYWORDS="~amd64 ~x86"
IUSE="test"
BDEPEND="
dev-qt/linguist-tools:5
virtual/pkgconfig
"
RDEPEND="
app-i18n/uchardet
dev-qt/qtcore:5
dev-qt/qtgui:5
dev-qt/qtnetwork:5
dev-qt/qtwidgets:5
media-libs/taglib
"
DEPEND="${RDEPEND}
dev-qt/qtconcurrent:5
test? (
dev-qt/qttest:5
media-libs/flac
media-sound/mac
media-sound/shntool
media-sound/ttaenc
media-sound/wavpack
)
"
PATCHES=(
"${FILESDIR}"/${PN}-9.0.0-no-man-compress.patch
)
RESTRICT="!test? ( test )"
pkg_pretend() {
use test && check-reqs_pkg_pretend
}
pkg_setup() {
use test && check-reqs_pkg_setup
}
src_configure() {
local mycmakeargs=(
-DBUILD_TESTS="$(usex test)"
)
cmake_src_configure
}
src_test() {
virtx "${BUILD_DIR}/tests/${PN}_test" || die
}
pkg_postinst() {
optfeature_header "${PN} optionally supports formats listed below."
optfeature 'FLAC input and output support' media-libs/flac
optfeature 'WavPack input and output support' media-sound/wavpack
optfeature 'APE input support' media-sound/mac
optfeature 'ALAC output support' media-sound/alac_decoder
optfeature 'TTA input support' media-sound/ttaenc
optfeature 'AAC output support' media-libs/faac
optfeature 'MP3 output support' media-sound/lame
optfeature 'Vorbis output support' media-sound/vorbis-tools
optfeature 'MP3 Replay Gain support' media-sound/mp3gain
optfeature 'Vorbis Replay Gain support' media-sound/vorbisgain
xdg_icon_cache_update
xdg_desktop_database_update
}
pkg_postrm() {
xdg_icon_cache_update
xdg_desktop_database_update
}