kde-frameworks/kfilemetadata: 6.28.0 version bump

Signed-off-by: Andreas Sturmlechner <asturm@gentoo.org>

kde-frameworks/kfilemetadata/Manifest

@@ -1 +1,2 @@
 DIST kfilemetadata-6.27.0.tar.xz 699016 BLAKE2B 30b0b4e66e309e7af26fd964088fbb6a38f2ac3be7939265328f976618138d5dd7bd60d98147d8e899aaa541cdedcecfd63364eaf4c5d1af2a04d9c9736147b7 SHA512 003b101c3905e43bfe463eb95a997233306f97a1e59661ea26c863b1200930446861fbb8e89864d6b2449424f1655dce9d2aed24813369b568803410148c2d4b
+DIST kfilemetadata-6.28.0.tar.xz 703164 BLAKE2B c0e8423a6c10a2889391c0f8eb16c7304d99ec3758bcfa2c22491a29d2278ebed468e9965745630aea996ab069ad0e86e2e702375659c4bdabce897f0671685e SHA512 c3a4632bd32a0a2d2a3ae2666e409f8851c9e59dcdffbd579aa552f125e7e8c6d59ed3d35c0716d1e9536ea31e23b12b8c0dff89410e0d3086080a3d9b6bbe94

kde-frameworks/kfilemetadata/kfilemetadata-6.28.0.ebuild

@@ -0,0 +1,64 @@
+# Copyright 1999-2026 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+PYTHON_COMPAT=( python3_{11..14} )
+QTMIN=6.10.1
+inherit ecm frameworks.kde.org optfeature python-any-r1
+
+DESCRIPTION="Library for extracting file metadata"
+
+LICENSE="LGPL-2+"
+KEYWORDS="~amd64 ~arm64 ~loong ~ppc64 ~riscv ~x86"
+IUSE="epub exif ffmpeg mobi pdf taglib"
+
+RESTRICT="test"
+
+RDEPEND="
+	>=dev-qt/qtbase-${QTMIN}:6[gui,xml]
+	=kde-frameworks/karchive-${KDE_CATV}*:6
+	=kde-frameworks/kcodecs-${KDE_CATV}*:6
+	=kde-frameworks/kcoreaddons-${KDE_CATV}*:6
+	=kde-frameworks/ki18n-${KDE_CATV}*:6
+	epub? ( app-text/ebook-tools )
+	exif? ( media-gfx/exiv2:= )
+	ffmpeg? ( media-video/ffmpeg:0= )
+	mobi? ( kde-apps/kdegraphics-mobipocket:6 )
+	pdf? ( app-text/poppler[qt6(-)] )
+	taglib? ( media-libs/taglib:= )
+"
+DEPEND="${RDEPEND}
+	kernel_linux? ( sys-apps/attr )
+"
+BDEPEND="test? ( ${PYTHON_DEPS} )"
+
+CMAKE_SKIP_TESTS=(
+	# FIXME: bug 644650, fails on tmpfs (but not for everyone)
+	usermetadatawritertest
+)
+
+pkg_setup() {
+	use test && python-any-r1_pkg_setup
+}
+
+src_configure() {
+	local mycmakeargs=(
+		$(cmake_use_find_package epub EPub)
+		$(cmake_use_find_package exif LibExiv2)
+		$(cmake_use_find_package ffmpeg FFmpeg)
+		$(cmake_use_find_package mobi QMobipocket6)
+		-DENABLE_MOBIPOCKET_TEXT_EXTRACTION=OFF
+		$(cmake_use_find_package pdf Poppler)
+		$(cmake_use_find_package taglib Taglib)
+	)
+
+	ecm_src_configure
+}
+
+pkg_postinst() {
+	if [[ -z "${REPLACING_VERSIONS}" ]]; then
+		optfeature "Microsoft Word/Powerpoint file indexing" app-text/catdoc
+		optfeature "Microsoft Excel file indexing" dev-libs/libxls
+	fi
+}