mirror of
https://github.com/gentoo-mirror/gentoo.git
synced 2026-09-24 04:59:14 -07:00
x11-terms/kitty: add 0.24.3
no-rc option has changed meaning from "don't auto-modify user .bashrc" to "don't use a hack'ish env-modifying method to load kitty.bash". Method can make sense on some distros, but we have /etc/bash/bashrc.d on Gentoo which x11-terms/kitty-shell-integration uses. It also has less limitations by working for shells that kitty did not start as well as remote ones if the stand-alone shell-integration package is installed there. So, still keep no-rc. Signed-off-by: Ionen Wolkens <ionen@gentoo.org>
This commit is contained in:
Ionen Wolkens
@@ -1,3 +1,5 @@
|
||||
DIST kitty-0.23.1.tar.xz 4444184 BLAKE2B f452e338fb72f723f2c028f90c20654cf80c5ee1aff924954f81f16445c9f4c10c77bd67d47ae5564b45496012dd1b7de447cdf3974b6913a39d170749878a73 SHA512 2d0c822e6bfca41b0a5e5e71e62f5073792b10c236287a509a6c790e19d098205c8719dbcb4aa630abbbaa3d44d6c9986c13efde7a9556772a89709383a0fe94
|
||||
DIST kitty-0.24.2.tar.xz 4601672 BLAKE2B 6e253863d81f2ef04f5d185cfe4379fe08818992a12a06da2ce2b0958912c4a0dc164b2ac6e8e74e383716e7040b2390bd1123ab4d8d282ede602dfea5cc756f SHA512 6d49b20dbd96ed0a1ed49a4523b65593c547ea2fec46f4c2557e26cdb5048ebaadb2c2118c7a2dd346f83ecab2d0a341d2322ae37ebe49184e22055581c631e7
|
||||
DIST kitty-0.24.2.tar.xz.sig 566 BLAKE2B f6f179a90acd2572549bc16e42ad637cb5d35e7488050e97fb285cc55b2cf04d1a5188949cc3172401090e2bcabcd239879f07acfef513090d5e1dd6688098a3 SHA512 6b415e87bf1f076e32da61cb7a64c3fd6e3a17ff8606cbfef8f92cfaa6b38123472a827ed4e8ff3cd54e8a74bd328e98b29104fdf18eca6e25bb1b170add3180
|
||||
DIST kitty-0.24.3.tar.xz 4614252 BLAKE2B 04c9904e20aae0ed12d41dc01ea4fbb5e36430e50087821845c0bd3e6d8dd0ab2a090f8ebff8fd66fe9f2b0a3efe52f0434008b4484cbe27a58b05c6e4f56d73 SHA512 2b1482164fb1aabfa2f775f24d0ffbbbd1e8a85cf114a2daa411379ea8dbcea6ae5f361997132fb4d773fed8adeec4c04ffb4e615a470cefeb794d8a39c94c0a
|
||||
DIST kitty-0.24.3.tar.xz.sig 566 BLAKE2B 1b1f99fef62a12863d7bda33f24e2273385b71653e90641b6ee1b3fd9543fe46fab5962751f30553dacf5b35e23334abbddb22ba1924fff6a878164f94bc9102 SHA512 1658bac350f92e9cdefe16ed1bffd61b5ba5e3ced82982ebfde34365095bf381fe5b0732388209688b6082e27f0b61e85e6f962d894e842994b47fdd64552026
|
||||
|
||||
128
x11-terms/kitty/kitty-0.24.3.ebuild
Normal file
128
x11-terms/kitty/kitty-0.24.3.ebuild
Normal file
@@ -0,0 +1,128 @@
|
||||
# Copyright 1999-2022 Gentoo Authors
|
||||
# Distributed under the terms of the GNU General Public License v2
|
||||
|
||||
EAPI=8
|
||||
|
||||
PYTHON_COMPAT=( python3_{8..10} )
|
||||
inherit optfeature python-single-r1 toolchain-funcs xdg
|
||||
|
||||
if [[ ${PV} == 9999 ]] ; then
|
||||
inherit git-r3
|
||||
EGIT_REPO_URI="https://github.com/kovidgoyal/kitty.git"
|
||||
else
|
||||
inherit verify-sig
|
||||
SRC_URI="
|
||||
https://github.com/kovidgoyal/kitty/releases/download/v${PV}/${P}.tar.xz
|
||||
verify-sig? ( https://github.com/kovidgoyal/kitty/releases/download/v${PV}/${P}.tar.xz.sig )"
|
||||
VERIFY_SIG_OPENPGP_KEY_PATH="${BROOT}/usr/share/openpgp-keys/kovidgoyal.gpg"
|
||||
KEYWORDS="~amd64 ~ppc64 ~x86"
|
||||
fi
|
||||
|
||||
DESCRIPTION="Fast, feature-rich, GPU-based terminal"
|
||||
HOMEPAGE="https://sw.kovidgoyal.net/kitty/"
|
||||
|
||||
LICENSE="GPL-3"
|
||||
SLOT="0"
|
||||
IUSE="+X debug test transfer wayland"
|
||||
REQUIRED_USE="
|
||||
|| ( X wayland )
|
||||
${PYTHON_REQUIRED_USE}"
|
||||
RESTRICT="!X? ( test ) !test? ( test ) !transfer? ( test ) !wayland? ( test )"
|
||||
|
||||
RDEPEND="
|
||||
${PYTHON_DEPS}
|
||||
media-libs/fontconfig
|
||||
media-libs/freetype:2
|
||||
media-libs/harfbuzz:=
|
||||
media-libs/lcms:2
|
||||
media-libs/libglvnd[X?]
|
||||
media-libs/libpng:=
|
||||
sys-apps/dbus
|
||||
sys-libs/zlib:=
|
||||
x11-libs/libxkbcommon[X?]
|
||||
x11-misc/xkeyboard-config
|
||||
~x11-terms/kitty-shell-integration-${PV}
|
||||
~x11-terms/kitty-terminfo-${PV}
|
||||
X? ( x11-libs/libX11 )
|
||||
transfer? ( net-libs/librsync:= )
|
||||
wayland? ( dev-libs/wayland )"
|
||||
DEPEND="
|
||||
${RDEPEND}
|
||||
X? (
|
||||
x11-base/xorg-proto
|
||||
x11-libs/libXcursor
|
||||
x11-libs/libXi
|
||||
x11-libs/libXinerama
|
||||
x11-libs/libXrandr
|
||||
)
|
||||
wayland? ( dev-libs/wayland-protocols )"
|
||||
BDEPEND="
|
||||
${PYTHON_DEPS}
|
||||
sys-libs/ncurses
|
||||
virtual/pkgconfig
|
||||
test? ( $(python_gen_cond_dep 'dev-python/pillow[${PYTHON_USEDEP}]') )
|
||||
wayland? ( dev-util/wayland-scanner )"
|
||||
[[ ${PV} == 9999 ]] || BDEPEND+=" verify-sig? ( sec-keys/openpgp-keys-kovidgoyal )"
|
||||
|
||||
PATCHES=(
|
||||
"${FILESDIR}"/${PN}-0.23.1-flags.patch
|
||||
)
|
||||
|
||||
src_prepare() {
|
||||
default
|
||||
|
||||
sed -i "s/'x11 wayland'/'$(usev X x11) $(usev wayland)'/" setup.py || die
|
||||
|
||||
if use !transfer; then
|
||||
sed -i 's/rs_cflag =/& []#/;/files.*rsync/d' setup.py || die
|
||||
rm -r kittens/transfer || die
|
||||
fi
|
||||
|
||||
# test relies on 'who' command which doesn't detect users with pid-sandbox
|
||||
rm kitty_tests/utmp.py || die
|
||||
|
||||
# skip docs for live version
|
||||
[[ ${PV} != 9999 ]] || sed -i '/exists.*_build/,/docs(ddir)/d' setup.py || die
|
||||
}
|
||||
|
||||
src_compile() {
|
||||
tc-export CC
|
||||
export PKGCONFIG_EXE=$(tc-getPKG_CONFIG)
|
||||
|
||||
local setup=(
|
||||
${EPYTHON} setup.py linux-package
|
||||
--disable-link-time-optimization
|
||||
--ignore-compiler-warnings
|
||||
--libdir-name=$(get_libdir)
|
||||
--shell-integration="enabled no-rc"
|
||||
--update-check-interval=0
|
||||
--verbose
|
||||
$(usev debug --debug)
|
||||
)
|
||||
|
||||
echo "${setup[*]}"
|
||||
"${setup[@]}" || die "setup.py failed to compile ${PN}"
|
||||
|
||||
[[ ${PV} == 9999 ]] || mv linux-package/share/doc/{${PN},${PF}} || die
|
||||
rm -r linux-package/share/terminfo || die
|
||||
}
|
||||
|
||||
src_test() {
|
||||
PATH=linux-package/bin:${PATH} KITTY_CONFIG_DIRECTORY=${T} \
|
||||
${EPYTHON} test.py || die
|
||||
}
|
||||
|
||||
src_install() {
|
||||
insinto /usr
|
||||
doins -r linux-package/.
|
||||
|
||||
fperms +x /usr/bin/kitty
|
||||
}
|
||||
|
||||
pkg_postinst() {
|
||||
xdg_icon_cache_update
|
||||
|
||||
optfeature "in-terminal image display with kitty icat" media-gfx/imagemagick
|
||||
optfeature "audio-based terminal bell support" media-libs/libcanberra
|
||||
optfeature "opening links from the terminal" x11-misc/xdg-utils
|
||||
}
|
||||
Reference in New Issue
Block a user