media-libs/libavif: 0.8.2 version bump

Package-Manager: Portage-3.0.8, Repoman-3.0.1
Signed-off-by: Daniel Novomesky <dnovomesky@gmail.com>
Closes: https://github.com/gentoo/gentoo/pull/17933
Signed-off-by: Joonas Niilola <juippis@gentoo.org>

media-libs/libavif/Manifest

@@ -1 +1,2 @@
 DIST libavif-0.8.1.tar.gz 2915941 BLAKE2B 40030a5a002e68231adf48ecc6e8012f7ec53506770872fc79dfd73496fa3a214c10cf5fb5826f145fe1f881adf2a3ecca13c33989b2f048aa72e455ab6950e0 SHA512 03692fbba49fde08d76cebb847d0404a81113824e9e65edc6a0977f323d060c394d111e2a7647788fa3115f3ae80b0fc92d4fe5be53852e6734b96a8f1c1a078
+DIST libavif-0.8.2.tar.gz 2940396 BLAKE2B b22a6fdd0f3fd3bbe46e3d51164958e71551c68f47f5d2677e37f1d137c86bdf1fa035a507f13e6d561fb070e35a4e093af3500a9fca431e8752b2aefe9ce9a0 SHA512 51034084b5a508763653e16512298c3ad57c07022327cf42c9e12728ac30e102c69dc43d6569cb39ee4a63cb81a98947b72201373d3a909b3f1b2f6f59aaa433

media-libs/libavif/libavif-0.8.2.ebuild

@@ -0,0 +1,75 @@
+# Copyright 2020 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+inherit cmake gnome2-utils
+
+DESCRIPTION="Library for encoding and decoding .avif files"
+HOMEPAGE="https://github.com/AOMediaCodec/libavif"
+SRC_URI="https://github.com/AOMediaCodec/libavif/archive/v${PV}.tar.gz -> ${P}.tar.gz"
+
+LICENSE="BSD-2"
+SLOT="0"
+KEYWORDS="~amd64 ~arm ~arm64 ~ppc64 ~x86"
+IUSE="+aom dav1d examples extras gdk-pixbuf rav1e"
+
+DEPEND="media-libs/libpng
+	sys-libs/zlib
+	virtual/jpeg
+	aom? ( >=media-libs/libaom-2.0.0 )
+	dav1d? ( media-libs/dav1d )
+	gdk-pixbuf? ( x11-libs/gdk-pixbuf:2 )
+	rav1e? ( media-video/rav1e[capi] )"
+RDEPEND="${DEPEND}"
+BDEPEND="virtual/pkgconfig"
+
+REQUIRED_USE="|| ( aom dav1d )"
+
+src_configure() {
+	local mycmakeargs=(
+		-DBUILD_SHARED_LIBS=ON
+		-DAVIF_CODEC_AOM=$(usex aom ON OFF)
+		-DAVIF_CODEC_DAV1D=$(usex dav1d ON OFF)
+		-DAVIF_CODEC_LIBGAV1=OFF
+		-DAVIF_CODEC_RAV1E=$(usex rav1e ON OFF)
+
+		# Use system libraries.
+		-DAVIF_LOCAL_ZLIBPNG=OFF
+		-DAVIF_LOCAL_JPEG=OFF
+
+		-DAVIF_BUILD_EXAMPLES=$(usex examples ON OFF)
+		-DAVIF_BUILD_APPS=$(usex extras ON OFF)
+		-DAVIF_BUILD_TESTS=$(usex extras ON OFF)
+
+		-DAVIF_BUILD_GDK_PIXBUF=$(usex gdk-pixbuf ON OFF)
+
+		-DAVIF_ENABLE_WERROR=OFF
+	)
+
+	cmake_src_configure
+}
+
+pkg_preinst() {
+	if use gdk-pixbuf ; then
+		gnome2_gdk_pixbuf_savelist
+	fi
+}
+
+pkg_postinst() {
+	if ! use aom && ! use rav1e ; then
+		ewarn "aom and rav1e flags are not set,"
+		ewarn "libavif will work in read-only mode."
+		ewarn "Enable aom or rav1e flag if you want to save .AVIF files."
+	fi
+
+	if use gdk-pixbuf ; then
+		gnome2_gdk_pixbuf_update
+	fi
+}
+
+pkg_postrm() {
+	if use gdk-pixbuf ; then
+		gnome2_gdk_pixbuf_update
+	fi
+}