dev-python/requests-cache: Remove old

Signed-off-by: Michał Górny <mgorny@gentoo.org>
2026-09-24 04:59:14 -07:00 · 2024-07-06 08:31:27 +02:00
parent 81704092cf
commit c1d94ef996
2 changed files with 0 additions and 93 deletions
--- a/dev-python/requests-cache/Manifest
+++ b/dev-python/requests-cache/Manifest
@@ -1,2 +1 @@
-DIST requests-cache-1.2.0.gh.tar.gz 3057187 BLAKE2B 135d39d8fac1e123c71b07b30002b980b5fdcdb586cafb310f8f72e865cdc97f62b699cd981068207c6f020deef595469801d440cf5034566e9618385d569437 SHA512 b198d282cfd656c432d3a63f4d615191ac1ff97c9563e9bd6945e7a78444601108beb47a0f4a79740c7bd6942c3753f025cd52457e87ece7964229799bbb8fa1
 DIST requests-cache-1.2.1.gh.tar.gz 3056882 BLAKE2B e1e5f971490f865ac2771d1dd87802ba138940adbfa0183ed5978b92794795fb26a30219de5560a925642ca08de1b8854d759408f86b30e6150e1c948ec8dcfe SHA512 f8977b1afc005ddd73019d2a0e39da368f376602110602c0b24c317b548f31a3489e686502ecd48ae3583e471fdd70671913e529c73dacdcaecadb1cd1e6c126
--- a/dev-python/requests-cache/requests-cache-1.2.0.ebuild
+++ b/dev-python/requests-cache/requests-cache-1.2.0.ebuild
@@ -1,92 +0,0 @@
-# Copyright 1999-2024 Gentoo Authors
-# Distributed under the terms of the GNU General Public License v2
-
-EAPI=8
-
-DISTUTILS_USE_PEP517=poetry
-PYTHON_COMPAT=( pypy3 python3_{10..12} )
-PYTHON_REQ_USE="sqlite"
-
-inherit distutils-r1 optfeature
-
-DESCRIPTION="Persistent cache for requests library"
-HOMEPAGE="
-	https://pypi.org/project/requests-cache/
-	https://github.com/requests-cache/requests-cache/
-"
-SRC_URI="
-	https://github.com/requests-cache/requests-cache/archive/v${PV}.tar.gz
-		-> ${P}.gh.tar.gz
-"
-
-LICENSE="BSD"
-SLOT="0"
-KEYWORDS="amd64 arm arm64 ~loong ppc64 ~riscv x86"
-
-RDEPEND="
-	dev-python/attrs[${PYTHON_USEDEP}]
-	>=dev-python/cattrs-22.2[${PYTHON_USEDEP}]
-	>=dev-python/platformdirs-2.5[${PYTHON_USEDEP}]
-	>=dev-python/requests-2.0.0[${PYTHON_USEDEP}]
-	dev-python/urllib3[${PYTHON_USEDEP}]
-	>=dev-python/url-normalize-1.4[${PYTHON_USEDEP}]
-"
-BDEPEND="
-	test? (
-		dev-python/itsdangerous[${PYTHON_USEDEP}]
-		dev-python/pytest-httpbin[${PYTHON_USEDEP}]
-		dev-python/requests-mock[${PYTHON_USEDEP}]
-		dev-python/responses[${PYTHON_USEDEP}]
-		>=dev-python/rich-10.0[${PYTHON_USEDEP}]
-		dev-python/timeout-decorator[${PYTHON_USEDEP}]
-		>=dev-python/ujson-5.4[${PYTHON_USEDEP}]
-		$(python_gen_cond_dep '
-			dev-python/time-machine[${PYTHON_USEDEP}]
-		' 'python*')
-	)
-"
-
-distutils_enable_tests pytest
-
-python_test() {
-	local EPYTEST_IGNORE=(
-		# These require extra servers running
-		tests/integration/test_dynamodb.py
-		tests/integration/test_gridfs.py
-		tests/integration/test_mongodb.py
-		tests/integration/test_redis.py
-	)
-	local EPYTEST_DESELECT=(
-		# Requires Internet access
-		tests/integration/test_upgrade.py::test_version_upgrade
-	)
-
-	case ${EPYTHON} in
-		pypy3)
-			EPYTEST_DESELECT+=(
-				# "database is locked", upstream probably relies on GC
-				# too much
-				tests/integration/test_sqlite.py
-			)
-			;;
-		python3.12)
-			# https://github.com/requests-cache/requests-cache/issues/845
-			EPYTEST_DESELECT+=(
-				tests/integration/test_memory.py::TestMemoryCache::test_response_no_duplicate_read
-				tests/integration/test_sqlite.py::TestSQLiteCache::test_concurrency
-			)
-			;;
-	esac
-
-	local -x USE_PYTEST_HTTPBIN=true
-	epytest
-}
-
-pkg_postinst() {
-	optfeature "redis backend" "dev-python/redis"
-	optfeature "MongoDB backend" "dev-python/pymongo"
-
-	optfeature "JSON serialization" "dev-python/ujson"
-	optfeature "YAML serialization" "dev-python/pyyaml"
-	optfeature "signing serialized data" "dev-python/itsdangerous"
-}