x11-misc/zim: 0.74.1 bump

Package-Manager: Portage-3.0.24, Repoman-3.0.3
Signed-off-by: Bernard Cafarelli <voyageur@gentoo.org>

x11-misc/zim/Manifest

@@ -1,2 +1,3 @@
 DIST zim-0.73.5.tar.gz 2702734 BLAKE2B 494dbe8ac0cbb46c15655cdf56bc25010591bd00faec94608ccd9fa7cec01385c6756480e5a3f37b50f44984ed69d30f33570ca913dab7ede2b89a4bf0cc4016 SHA512 f2c335d4697e7d0535b2abb200af45b7d753f2964e94a35c2ec8d4fb8deae0842aef086e09430a50d4ff5ecee89eb1f6f881a0b430877209e4a8d83ee046c4f9
 DIST zim-0.74.0.tar.gz 2917916 BLAKE2B 32b1086395142d07b46425264e3ee6d6782d62f138fb661c0bc392b09054f0664e7a2d8b75f409a843b1e85c93a11e41e041019f69ef657e11d311253ba804ae SHA512 39e3849c14bc474b90583a708c8ead287b27a8eb5f714ad63f168f205fb6584c4ff2f9df45755aa3e3b012639891587c7153ae4e0fef71276241ddce6e32c01f
+DIST zim-0.74.1.tar.gz 2994036 BLAKE2B 9de89ce74bc08ec0b60f34d693ffdb3b8220efe6f03e3d77686c9d3db135713d7eb5e0beed35eb6f979e489f12b9d65b9b66e0e7449c45b955711684154ae6b8 SHA512 f78bf1ee6082488efe2e581984c85ffbddbfb7e5adfdf491232e93a8376580275f329e2d02c482afd70bbc70f62ca6f0b3bce636cff58b0a1d592dd4b8194e3a

x11-misc/zim/zim-0.74.1.ebuild

@@ -0,0 +1,73 @@
+# Copyright 1999-2021 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+PYTHON_COMPAT=( python3_{8,9} )
+PYTHON_REQ_USE="sqlite"
+DISTUTILS_SINGLE_IMPL=1
+DISTUTILS_USE_SETUPTOOLS=no
+inherit distutils-r1 virtualx xdg
+
+DESCRIPTION="A desktop wiki"
+HOMEPAGE="
+	https://zim-wiki.org/
+	https://github.com/zim-desktop-wiki/zim-desktop-wiki
+"
+SRC_URI="https://github.com/${PN}-desktop-wiki/${PN}-desktop-wiki/archive/${PV/_/-}.tar.gz -> ${P}.tar.gz"
+
+LICENSE="BSD GPL-2+"
+SLOT="0"
+KEYWORDS="~amd64 ~arm ~x86"
+RESTRICT="test"
+
+RDEPEND="
+	$(python_gen_cond_dep '
+		dev-python/pygobject:3[${PYTHON_USEDEP}]
+		dev-python/pyxdg[${PYTHON_USEDEP}]
+	')
+	x11-libs/gtk+:3[introspection]
+	x11-misc/xdg-utils
+"
+DEPEND="
+	${RDEPEND}
+"
+DOCS=( CHANGELOG.md CONTRIBUTING.md PLUGIN_WRITING.md README.md )
+PATCHES=( "${FILESDIR}"/${PN}-0.60-remove-ubuntu-theme.patch )
+S=${WORKDIR}/${PN}-desktop-wiki-${PV/_/-}
+
+python_prepare_all() {
+	sed -i -e "s/'USER'/'LOGNAME'/g" zim/__init__.py zim/fs.py || die
+
+	if [[ ${LINGUAS} ]]; then
+		local lingua
+		for lingua in translations/*.po; do
+			lingua=${lingua/.po}
+			lingua=${lingua/translations\/}
+			has ${lingua} ${LINGUAS} || \
+				{ rm translations/${lingua}.po || die; }
+		done
+	fi
+
+	distutils-r1_python_prepare_all
+	export XDG_RUNTIME_DIR=fakethis
+}
+
+python_install() {
+	distutils-r1_python_install
+}
+
+pkg_postinst() {
+	xdg_pkg_postinst
+	if ! has_version ${CATEGORY}/${PN}; then
+		elog "Please install these packages for additional functionality"
+		elog "    dev-lang/R"
+		elog "    dev-python/gtkspell-python"
+		elog "    dev-vcs/bzr"
+		elog "    media-gfx/graphviz"
+		elog "    media-gfx/imagemagick"
+		elog "    media-gfx/scrot"
+		elog "    media-sound/lilypond"
+		elog "    sci-visualization/gnuplot"
+		elog "    virtual/latex-base app-text/dvipng"
+	fi
+}