xfce-base/xfdesktop: Add 4.19.2_p20240509 snapshot

Signed-off-by: Michał Górny <mgorny@gentoo.org>

xfce-base/xfdesktop/Manifest

@@ -1,3 +1,4 @@
+DIST xfdesktop-0a2a99eb0d0f4efdb47ccc732ca5bde537a94c8d.tar.bz2 1518912 BLAKE2B 662f6a53dbe042697935f85300e3053feb9c63687bf4c9465c6cc9f77b4ba45afe8e3c442909f6a83661bf303e1bc5607d0ab1d3b6b98432bf74d343454bec4f SHA512 8e84263d0cb76527adc485a5b1b8fcdb306e71ff7778be85eb55b7fb5fd505329ddd5525d95b34df47e8fc87a6d5912ee7d597e34854f4ad9af317ffb2056342
 DIST xfdesktop-4.18.1.tar.bz2 2133258 BLAKE2B 3d4f54b64a6adc5f52bf6b48862b1fbf9b9608113035fdce89a2cb08a674f773f42edc0e1d05a27e89de7df71f7d53f400b794a2a79888cf51570c3ab060db8b SHA512 cafb1e274bbabf1704a6452532fc79657af26eaf92a58374f87a70f31c35fbf213319c6658b3d18bfca2d555b69e07e46949407d1f80e5a37f48e76bbde9dc3e
 DIST xfdesktop-4.19.0.tar.bz2 2145725 BLAKE2B 18ed97b8bb9ee769de29490383fd089eb884081c95e662350c9e0c05aa9812a4f44e8911c5bb74e026aa1fea22840245a68e1514dd6e439af8dd553c82da562c SHA512 dd8d479b7a43733dc49f692bd88ad5a290d5fa4cdbddf42be293921c750d3017e9c6671cc56ba8888a0df8d3951b0993dffa88418032ad7c68f85d8756081e40
 DIST xfdesktop-4.19.2.tar.bz2 2530207 BLAKE2B 42816c6afe81204adfcd6b45e294d8f7ae1b1e9d1986dd12c2bd10742331638b68113d3bbde5873994004967f7efd461466b337648ba12c3f626a0ca50e13cb2 SHA512 101b82e026e026239305ce58f12863b08d47733073f92a22f68b50eb9e6c62525adc0a2482641464ef70f743fe14fabf8eeb66cf03e3cb18907a601f9a527ef6

xfce-base/xfdesktop/xfdesktop-4.19.2_p20240509.ebuild

@@ -0,0 +1,76 @@
+# Copyright 1999-2024 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+inherit autotools xdg-utils
+
+EGIT_COMMIT=0a2a99eb0d0f4efdb47ccc732ca5bde537a94c8d
+MY_P=xfdesktop-${EGIT_COMMIT}
+DESCRIPTION="Desktop manager for the Xfce desktop environment"
+HOMEPAGE="
+	https://docs.xfce.org/xfce/xfdesktop/start
+	https://gitlab.xfce.org/xfce/xfdesktop/
+"
+SRC_URI="
+	https://gitlab.xfce.org/xfce/xfdesktop/-/archive/${EGIT_COMMIT}/${MY_P}.tar.bz2
+"
+S=${WORKDIR}/${MY_P}
+
+LICENSE="GPL-2+"
+SLOT="0"
+KEYWORDS="~amd64 ~arm ~arm64 ~hppa ~ia64 ~loong ~ppc ~ppc64 ~riscv ~x86"
+IUSE="libnotify +thunar wayland X"
+REQUIRED_USE="|| ( wayland X )"
+
+DEPEND="
+	>=x11-libs/cairo-1.16
+	>=dev-libs/glib-2.66.0
+	>=x11-libs/gtk+-3.24.0:3[wayland?,X?]
+	>=xfce-base/exo-0.11:=
+	>=xfce-base/garcon-0.6:=
+	>=xfce-base/libxfce4ui-4.13:=
+	>=xfce-base/libxfce4util-4.13:=
+	>=xfce-base/libxfce4windowing-4.19.3:=[X?]
+	>=xfce-base/xfconf-4.18.0:=
+	libnotify? ( >=x11-libs/libnotify-0.7:= )
+	thunar? ( >=xfce-base/thunar-4.17.10:= )
+	wayland? ( >=gui-libs/gtk-layer-shell-0.7.0 )
+	X? ( >=x11-libs/libX11-1.6.7 )
+"
+RDEPEND="
+	${DEPEND}
+"
+BDEPEND="
+	dev-build/xfce4-dev-tools
+	dev-libs/glib
+	dev-util/gdbus-codegen
+	dev-util/glib-utils
+	>=sys-devel/gettext-0.19.8
+	virtual/pkgconfig
+"
+
+src_prepare() {
+	default
+	eautoreconf
+}
+
+src_configure() {
+	local myconf=(
+		$(use_enable wayland)
+		$(use_enable X x11)
+		$(use_enable thunar file-icons)
+		$(use_enable thunar thunarx)
+		$(use_enable libnotify notifications)
+	)
+
+	econf "${myconf[@]}"
+}
+
+pkg_postinst() {
+	xdg_icon_cache_update
+}
+
+pkg_postrm() {
+	xdg_icon_cache_update
+}