mirror of
https://github.com/gentoo-mirror/gentoo.git
synced 2026-09-24 04:59:14 -07:00
net-fs/samba: Bump to version 4.11.7
Package-Manager: Portage-2.3.93, Repoman-2.3.20 Signed-off-by: Lars Wendler <polynomial-c@gentoo.org>
This commit is contained in:
Lars Wendler
@@ -3,6 +3,7 @@ DIST samba-4.10.13.tar.gz 18350580 BLAKE2B ab97d46284bee60762543ed1c27846e22dd98
|
||||
DIST samba-4.10.2.tar.gz 18280710 BLAKE2B f15b117d1159dfa6cd279c5011629d688fcfba94a2ca8184a827d0787a31f76a38f46b355454b916f2e62c0a88109b86664f6bb16fc0e23d0f61d09908e587cd SHA512 3d146ea12567ebb02a7babcad779b82339ffbfb19f6f2be5cac33eb18af2c9b546dc1cd910072a5c9e152ba9c4a632ed6870c48a8f6ad9d04304b130f240a4bf
|
||||
DIST samba-4.11.4.tar.gz 18530105 BLAKE2B 39e0cc6965681f3d64e861edebe2b77e558b68d9a3f4d7fa52e6ccfe704f2294fb3fb1a619d07d2130f36b1bf572300c733a273ccf78d554807e0f5897dcbcff SHA512 18ae1cb8b092c441a3fd4c6ecc9f35841dc51e3061f435107f7d2579b5e8ca6f8c96a947627dbd401b81c7de2293ff2587c30be694e160bf8a10c6d15aa73880
|
||||
DIST samba-4.11.6.tar.gz 18541566 BLAKE2B 2b4a40be7cec8a9706cbc344796885f59403aa11ca3d8a7dc40b3d287ec222c11d7395fd193c4b66c4116f1bffd869caf444a950d508f5a9a596db32553e1461 SHA512 3815080a1693c596a126371a5ea4e8534317a7266803c7de13a7e5b3ee9757dfbf13c0de20d498a6683d3aaf56941ed42f289e3c24f88713529a5f047a691af2
|
||||
DIST samba-4.11.7.tar.gz 18541292 BLAKE2B 083ee2ebade2dd6267f8c53234bd98cc3325d28cf0a03fce2f45accfd36acfaaa9cdc82f326e913cfdbd585b0d705c71a95685ec37901e7d8a4d17cd2a04d3f2 SHA512 c728adbc9fd86f9b745f62d2f435d0fd5e8d1381725a657f8d14ec246d5c758c9eb92bd82c25b0c3f40ce4d10eaf5ce7792363b8a8c4df2e6c78c1458fef4f95
|
||||
DIST samba-4.12.0.tar.gz 18156651 BLAKE2B a02a5cdce9551743bfa88fe9e42ab2f2b6fc3ec96e933bcb92f994681b8dbbeef675f718e723f131c95252a51d964d141f5dda98529dc7779ba372fc6d0080c5 SHA512 d50be899675b8e3504311e73bb75fbb8264e918e0d1765239ecb5b14e15c0917565f8a9ce1877fb604151bf4f23dfc4c2f7f30a53c872681e3d2571d3ed5ef82
|
||||
DIST samba-4.5.11-disable-python-patches.tar.xz 6292 BLAKE2B c2a32a1059a02bc1c87ce5f604cbc5878c654b8f693c8486b5ba63b37513444915a7b6389fe82b7e31ab2f9577dd8462eddba60b4f4f756b4ed1145ce7bd90ae SHA512 f0e3076e3e1ecaae3f06b3ef30efc81719fb3f63a1041dcbdae4b62ca4cf693732f9eb16f047d046d4930136fed82194e82b455ea888e12cf845b3e6a122d57d
|
||||
DIST samba-4.5.16.tar.gz 21024396 BLAKE2B e737559fb748044076608fa233700eb54c7e1c56bc234763f062b6341a179cc78a4a8cdf9f3d6f4d7f3cf8a79f846852ddd5cc753a468c3adb3a0451e1809ed9 SHA512 de8a41013cfb5ef3adcb290efd97a78a5de876d90ad05764d631f14e663a1849bb53e4ac394b46c906f1109be5748fee9316407a659c57007d36851ae8adcd7f
|
||||
|
||||
314
net-fs/samba/samba-4.11.7.ebuild
Normal file
314
net-fs/samba/samba-4.11.7.ebuild
Normal file
@@ -0,0 +1,314 @@
|
||||
# Copyright 1999-2020 Gentoo Authors
|
||||
# Distributed under the terms of the GNU General Public License v2
|
||||
|
||||
EAPI=6
|
||||
|
||||
PYTHON_COMPAT=( python3_{6,7,8} )
|
||||
PYTHON_REQ_USE='threads(+),xml(+)'
|
||||
inherit python-single-r1 waf-utils multilib-minimal linux-info systemd pam
|
||||
|
||||
MY_PV="${PV/_rc/rc}"
|
||||
MY_P="${PN}-${MY_PV}"
|
||||
|
||||
SRC_PATH="stable"
|
||||
[[ ${PV} = *_rc* ]] && SRC_PATH="rc"
|
||||
|
||||
SRC_URI="mirror://samba/${SRC_PATH}/${MY_P}.tar.gz"
|
||||
[[ ${PV} = *_rc* ]] || \
|
||||
KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~ia64 ~ppc ~ppc64 ~sparc ~x86"
|
||||
|
||||
DESCRIPTION="Samba Suite Version 4"
|
||||
HOMEPAGE="https://www.samba.org/"
|
||||
LICENSE="GPL-3"
|
||||
|
||||
SLOT="0"
|
||||
|
||||
IUSE="acl addc addns ads ceph client cluster cups debug dmapi fam gpg iprint
|
||||
json ldap pam profiling-data python quota selinux syslog system-heimdal
|
||||
+system-mitkrb5 systemd test winbind zeroconf"
|
||||
|
||||
MULTILIB_WRAPPED_HEADERS=(
|
||||
/usr/include/samba-4.0/policy.h
|
||||
/usr/include/samba-4.0/dcerpc_server.h
|
||||
/usr/include/samba-4.0/ctdb.h
|
||||
/usr/include/samba-4.0/ctdb_client.h
|
||||
/usr/include/samba-4.0/ctdb_protocol.h
|
||||
/usr/include/samba-4.0/ctdb_private.h
|
||||
/usr/include/samba-4.0/ctdb_typesafe_cb.h
|
||||
/usr/include/samba-4.0/ctdb_version.h
|
||||
)
|
||||
|
||||
CDEPEND="
|
||||
>=app-arch/libarchive-3.1.2[${MULTILIB_USEDEP}]
|
||||
dev-lang/perl:=
|
||||
dev-libs/libbsd[${MULTILIB_USEDEP}]
|
||||
dev-libs/libtasn1[${MULTILIB_USEDEP}]
|
||||
dev-libs/popt[${MULTILIB_USEDEP}]
|
||||
>=net-libs/gnutls-3.2.0[${MULTILIB_USEDEP}]
|
||||
net-libs/libnsl:=[${MULTILIB_USEDEP}]
|
||||
sys-apps/dbus[${MULTILIB_USEDEP}]
|
||||
sys-libs/e2fsprogs-libs[${MULTILIB_USEDEP}]
|
||||
>=sys-libs/ldb-2.0.9[ldap(+)?,python?,${PYTHON_SINGLE_USEDEP},${MULTILIB_USEDEP}]
|
||||
<sys-libs/ldb-2.1.0[ldap(+)?,python?,${PYTHON_SINGLE_USEDEP},${MULTILIB_USEDEP}]
|
||||
sys-libs/libcap
|
||||
sys-libs/ncurses:0=
|
||||
sys-libs/readline:0=
|
||||
>=sys-libs/talloc-2.2.0[python?,${PYTHON_SINGLE_USEDEP},${MULTILIB_USEDEP}]
|
||||
>=sys-libs/tdb-1.4.2[python?,${PYTHON_SINGLE_USEDEP},${MULTILIB_USEDEP}]
|
||||
>=sys-libs/tevent-0.10.0[python?,${PYTHON_SINGLE_USEDEP},${MULTILIB_USEDEP}]
|
||||
sys-libs/zlib[${MULTILIB_USEDEP}]
|
||||
virtual/libiconv
|
||||
pam? ( sys-libs/pam )
|
||||
acl? ( virtual/acl )
|
||||
$(python_gen_cond_dep "
|
||||
dev-python/subunit[\${PYTHON_MULTI_USEDEP},${MULTILIB_USEDEP}]
|
||||
addns? (
|
||||
net-dns/bind-tools[gssapi]
|
||||
dev-python/dnspython:=[\${PYTHON_MULTI_USEDEP}]
|
||||
)
|
||||
")
|
||||
ceph? ( sys-cluster/ceph )
|
||||
cluster? (
|
||||
net-libs/rpcsvc-proto
|
||||
!dev-db/ctdb
|
||||
)
|
||||
cups? ( net-print/cups )
|
||||
debug? ( dev-util/lttng-ust )
|
||||
dmapi? ( sys-apps/dmapi )
|
||||
fam? ( virtual/fam )
|
||||
gpg? ( app-crypt/gpgme )
|
||||
json? ( dev-libs/jansson )
|
||||
ldap? ( net-nds/openldap[${MULTILIB_USEDEP}] )
|
||||
system-heimdal? ( >=app-crypt/heimdal-1.5[-ssl,${MULTILIB_USEDEP}] )
|
||||
system-mitkrb5? ( >=app-crypt/mit-krb5-1.15.1[${MULTILIB_USEDEP}] )
|
||||
systemd? ( sys-apps/systemd:0= )
|
||||
zeroconf? ( net-dns/avahi )
|
||||
"
|
||||
DEPEND="${CDEPEND}
|
||||
${PYTHON_DEPS}
|
||||
app-text/docbook-xsl-stylesheets
|
||||
dev-libs/libxslt
|
||||
>=dev-util/cmocka-1.1.1[${MULTILIB_USEDEP}]
|
||||
net-libs/libtirpc[${MULTILIB_USEDEP}]
|
||||
virtual/pkgconfig
|
||||
|| (
|
||||
net-libs/rpcsvc-proto
|
||||
<sys-libs/glibc-2.26[rpc(+)]
|
||||
)
|
||||
test? (
|
||||
!system-mitkrb5? (
|
||||
>=sys-libs/nss_wrapper-1.1.3
|
||||
>=net-dns/resolv_wrapper-1.1.4
|
||||
>=net-libs/socket_wrapper-1.1.9
|
||||
>=sys-libs/uid_wrapper-1.2.1
|
||||
)
|
||||
)"
|
||||
RDEPEND="${CDEPEND}
|
||||
python? ( ${PYTHON_DEPS} )
|
||||
client? ( net-fs/cifs-utils[ads?] )
|
||||
selinux? ( sec-policy/selinux-samba )
|
||||
!dev-perl/Parse-Yapp
|
||||
"
|
||||
|
||||
REQUIRED_USE="
|
||||
addc? ( python json winbind )
|
||||
addns? ( python )
|
||||
ads? ( acl ldap winbind )
|
||||
cluster? ( ads )
|
||||
gpg? ( addc )
|
||||
test? ( python )
|
||||
?? ( system-heimdal system-mitkrb5 )
|
||||
${PYTHON_REQUIRED_USE}
|
||||
"
|
||||
|
||||
# the test suite is messed, it uses system-installed samba
|
||||
# bits instead of what was built, tests things disabled via use
|
||||
# flags, and generally just fails to work in a way ebuilds could
|
||||
# rely on in its current state
|
||||
RESTRICT="test"
|
||||
|
||||
S="${WORKDIR}/${MY_P}"
|
||||
|
||||
PATCHES=(
|
||||
"${FILESDIR}/${PN}-4.4.0-pam.patch"
|
||||
"${FILESDIR}/${PN}-4.9.2-timespec.patch"
|
||||
)
|
||||
|
||||
#CONFDIR="${FILESDIR}/$(get_version_component_range 1-2)"
|
||||
CONFDIR="${FILESDIR}/4.4"
|
||||
|
||||
WAF_BINARY="${S}/buildtools/bin/waf"
|
||||
|
||||
SHAREDMODS=""
|
||||
|
||||
pkg_setup() {
|
||||
python-single-r1_pkg_setup
|
||||
if use cluster ; then
|
||||
SHAREDMODS="idmap_rid,idmap_tdb2,idmap_ad"
|
||||
elif use ads ; then
|
||||
SHAREDMODS="idmap_ad"
|
||||
fi
|
||||
}
|
||||
|
||||
src_prepare() {
|
||||
default
|
||||
|
||||
# un-bundle dnspython
|
||||
sed -i -e '/"dns.resolver":/d' "${S}"/third_party/wscript || die
|
||||
|
||||
# unbundle iso8601 unless tests are enabled
|
||||
if ! use test ; then
|
||||
sed -i -e '/"iso8601":/d' "${S}"/third_party/wscript || die
|
||||
fi
|
||||
|
||||
## ugly hackaround for bug #592502
|
||||
#cp /usr/include/tevent_internal.h "${S}"/lib/tevent/ || die
|
||||
|
||||
sed -e 's:<gpgme\.h>:<gpgme/gpgme.h>:' \
|
||||
-i source4/dsdb/samdb/ldb_modules/password_hash.c \
|
||||
|| die
|
||||
|
||||
# Friggin' WAF shit
|
||||
multilib_copy_sources
|
||||
}
|
||||
|
||||
multilib_src_configure() {
|
||||
# when specifying libs for samba build you must append NONE to the end to
|
||||
# stop it automatically including things
|
||||
local bundled_libs="NONE"
|
||||
if ! use system-heimdal && ! use system-mitkrb5 ; then
|
||||
bundled_libs="heimbase,heimntlm,hdb,kdc,krb5,wind,gssapi,hcrypto,hx509,roken,asn1,com_err,NONE"
|
||||
fi
|
||||
|
||||
local myconf=(
|
||||
--enable-fhs
|
||||
--sysconfdir="${EPREFIX}/etc"
|
||||
--localstatedir="${EPREFIX}/var"
|
||||
--with-modulesdir="${EPREFIX}/usr/$(get_libdir)/samba"
|
||||
--with-piddir="${EPREFIX}/run/${PN}"
|
||||
--bundled-libraries="${bundled_libs}"
|
||||
--builtin-libraries=NONE
|
||||
--disable-rpath
|
||||
--disable-rpath-install
|
||||
--nopyc
|
||||
--nopyo
|
||||
$(multilib_native_use_with acl acl-support)
|
||||
$(multilib_native_usex addc '' '--without-ad-dc')
|
||||
$(multilib_native_use_with addns dnsupdate)
|
||||
$(multilib_native_use_with ads)
|
||||
$(multilib_native_use_enable ceph cephfs)
|
||||
$(multilib_native_use_with cluster cluster-support)
|
||||
$(multilib_native_use_enable cups)
|
||||
$(multilib_native_use_with dmapi)
|
||||
$(multilib_native_use_with fam)
|
||||
$(multilib_native_use_with gpg gpgme)
|
||||
$(multilib_native_use_with json)
|
||||
$(multilib_native_use_enable iprint)
|
||||
$(multilib_native_use_with pam)
|
||||
$(multilib_native_usex pam "--with-pammodulesdir=${EPREFIX}/$(get_libdir)/security" '')
|
||||
$(multilib_native_use_with quota quotas)
|
||||
$(multilib_native_use_with syslog)
|
||||
$(multilib_native_use_with systemd)
|
||||
--systemd-install-services
|
||||
--with-systemddir="$(systemd_get_systemunitdir)"
|
||||
$(multilib_native_use_with winbind)
|
||||
$(multilib_native_usex python '' '--disable-python')
|
||||
$(multilib_native_use_enable zeroconf avahi)
|
||||
$(multilib_native_usex test '--enable-selftest' '')
|
||||
$(usex system-mitkrb5 "--with-system-mitkrb5 $(multilib_native_usex addc --with-experimental-mit-ad-dc '')" '')
|
||||
$(use_with debug lttng)
|
||||
$(use_with ldap)
|
||||
$(use_with profiling-data)
|
||||
# bug #683148
|
||||
--jobs 1
|
||||
)
|
||||
|
||||
multilib_is_native_abi && myconf+=( --with-shared-modules=${SHAREDMODS} )
|
||||
|
||||
CPPFLAGS="-I${SYSROOT}${EPREFIX}/usr/include/et ${CPPFLAGS}" \
|
||||
waf-utils_src_configure ${myconf[@]}
|
||||
}
|
||||
|
||||
multilib_src_compile() {
|
||||
waf-utils_src_compile
|
||||
}
|
||||
|
||||
multilib_src_install() {
|
||||
waf-utils_src_install
|
||||
|
||||
# Make all .so files executable
|
||||
find "${ED}" -type f -name "*.so" -exec chmod +x {} + || die
|
||||
|
||||
if multilib_is_native_abi ; then
|
||||
# install ldap schema for server (bug #491002)
|
||||
if use ldap ; then
|
||||
insinto /etc/openldap/schema
|
||||
doins examples/LDAP/samba.schema
|
||||
fi
|
||||
|
||||
# create symlink for cups (bug #552310)
|
||||
if use cups ; then
|
||||
dosym ../../../bin/smbspool /usr/libexec/cups/backend/smb
|
||||
fi
|
||||
|
||||
# install example config file
|
||||
insinto /etc/samba
|
||||
doins examples/smb.conf.default
|
||||
|
||||
# Fix paths in example file (#603964)
|
||||
sed \
|
||||
-e '/log file =/s@/usr/local/samba/var/@/var/log/samba/@' \
|
||||
-e '/include =/s@/usr/local/samba/lib/@/etc/samba/@' \
|
||||
-e '/path =/s@/usr/local/samba/lib/@/var/lib/samba/@' \
|
||||
-e '/path =/s@/usr/local/samba/@/var/lib/samba/@' \
|
||||
-e '/path =/s@/usr/spool/samba@/var/spool/samba@' \
|
||||
-i "${ED%/}"/etc/samba/smb.conf.default || die
|
||||
|
||||
# Install init script and conf.d file
|
||||
newinitd "${CONFDIR}/samba4.initd-r1" samba
|
||||
newconfd "${CONFDIR}/samba4.confd" samba
|
||||
|
||||
systemd_dotmpfilesd "${FILESDIR}"/samba.conf
|
||||
use addc || rm "${D}/$(systemd_get_systemunitdir)/samba.service" || die
|
||||
|
||||
# Preserve functionality for old gentoo-specific unit names
|
||||
dosym nmb.service "$(systemd_get_systemunitdir)/nmbd.service"
|
||||
dosym smb.service "$(systemd_get_systemunitdir)/smbd.service"
|
||||
dosym winbind.service "$(systemd_get_systemunitdir)/winbindd.service"
|
||||
fi
|
||||
|
||||
if use pam && use winbind ; then
|
||||
newpamd "${CONFDIR}/system-auth-winbind.pam" system-auth-winbind
|
||||
# bugs #376853 and #590374
|
||||
insinto /etc/security
|
||||
doins examples/pam_winbind/pam_winbind.conf
|
||||
fi
|
||||
|
||||
keepdir /var/cache/samba
|
||||
keepdir /var/lib/ctdb
|
||||
keepdir /var/lib/samba/{bind-dns,private}
|
||||
keepdir /var/log/samba
|
||||
}
|
||||
|
||||
multilib_src_install_all() {
|
||||
# Attempt to fix bug #673168
|
||||
find "${ED}" -type d -name "Yapp" -print0 \
|
||||
| xargs -0 --no-run-if-empty rm -r || die
|
||||
}
|
||||
|
||||
multilib_src_test() {
|
||||
if multilib_is_native_abi ; then
|
||||
"${WAF_BINARY}" test || die "test failed"
|
||||
fi
|
||||
}
|
||||
|
||||
pkg_postinst() {
|
||||
ewarn "Be aware the this release contains the best of all of Samba's"
|
||||
ewarn "technology parts, both a file server (that you can reasonably expect"
|
||||
ewarn "to upgrade existing Samba 3.x releases to) and the AD domain"
|
||||
ewarn "controller work previously known as 'samba4'."
|
||||
|
||||
elog "For further information and migration steps make sure to read "
|
||||
elog "https://samba.org/samba/history/${P}.html "
|
||||
elog "https://wiki.samba.org/index.php/Samba4/HOWTO "
|
||||
}
|
||||
Reference in New Issue
Block a user