dev-util/geany-plugins: bump to 1.38 and EAPI 8

Closes: https://bugs.gentoo.org/822384
Package-Manager: Portage-3.0.20, Repoman-3.0.3
Signed-off-by: Chris Mayo <aklhfex@gmail.com>
Signed-off-by: Sam James <sam@gentoo.org>
This commit is contained in:
Chris Mayo
2021-11-12 01:34:18 +00:00
committed by Sam James
parent f31ce7ecbd
commit c0d3f00539
2 changed files with 123 additions and 0 deletions
+1
View File
@@ -1 +1,2 @@
DIST geany-plugins-1.37.tar.gz 4711239 BLAKE2B 7f4fd121f6f0784aecf2dcc04d208c89e502b23debcbc40889f93c1421e414c33c8634376cfe01e91c370f70818d33b373b88698f5cb0ee23dff5edee9d781cf SHA512 47f8d7170593114c773067a8132c724471cbf881582a0a739da578ca42533783d8ecbccb04e039f2990ceed440bbd2d94e4be4a28e336c7f74b8e11a15ba4ce9
DIST geany-plugins-1.38.tar.gz 4783970 BLAKE2B 386a05d7136183799059ef6d73b28a0d67d738939b0dc57649ac68f1049104568fe7c8453ebf2144277f60ee0834564b19bf4e756168864f1551962ba2411c14 SHA512 82d04331e23c5d81765b11e081a960a7a17172184cabe94efd2ddb37ac94668349b036e6083f77c867ac650fa7b251ba3970ae26b562b4568d6e313652763339
@@ -0,0 +1,122 @@
# Copyright 1999-2021 Gentoo Authors
# Distributed under the terms of the GNU General Public License v2
EAPI=8
LUA_COMPAT=( lua5-1 )
inherit lua-single
DESCRIPTION="A collection of different plugins for Geany"
HOMEPAGE="https://plugins.geany.org"
SRC_URI="https://plugins.geany.org/${PN}/${P}.tar.gz"
LICENSE="GPL-2"
SLOT="0"
KEYWORDS="~amd64 ~arm ~ppc ~ppc64 ~sparc ~x86"
IUSE="ctags debugger enchant git gpg gtkspell lua markdown nls pretty-printer scope soup workbench"
REQUIRED_USE="lua? ( ${LUA_REQUIRED_USE} )"
DEPEND="
dev-libs/glib:2
>=dev-util/geany-1.37[-gtk2(-)]
x11-libs/gtk+:3
ctags? ( dev-util/ctags )
debugger? ( x11-libs/vte:2.91 )
enchant? ( app-text/enchant:= )
git? ( dev-libs/libgit2:= )
gpg? ( app-crypt/gpgme:1= )
gtkspell? ( app-text/gtkspell:3= )
lua? ( ${LUA_DEPS} )
markdown? (
app-text/discount
net-libs/webkit-gtk:4
)
pretty-printer? ( dev-libs/libxml2:2 )
scope? ( x11-libs/vte:2.91 )
soup? ( net-libs/libsoup:2.4 )
workbench? ( dev-libs/libgit2:= )
"
RDEPEND="${DEPEND}
scope? ( sys-devel/gdb )
"
BDEPEND="virtual/pkgconfig
nls? ( sys-devel/gettext )
"
pkg_setup() {
use lua && lua-single_pkg_setup
}
src_configure() {
local myeconfargs=(
--disable-cppcheck
--disable-extra-c-warnings
$(use_enable nls)
--enable-utilslib
# Plugins
--enable-addons
--enable-autoclose
--enable-automark
--enable-codenav
--enable-commander
--enable-defineformat
--enable-geanyextrasel
--enable-geanyinsertnum
--enable-geanymacro
--enable-geanyminiscript
--enable-geanynumberedbookmarks
--enable-geanyprj
--enable-geanyvc $(use_enable gtkspell)
--enable-keyrecord
--enable-latex
--enable-lineoperations
--enable-lipsum
--enable-overview
--enable-pairtaghighlighter
--enable-pohelper
--enable-projectorganizer
--enable-sendmail
--enable-shiftcolumn
--enable-tableconvert
--enable-treebrowser
--enable-vimode
--enable-xmlsnippets
$(use_enable debugger)
$(use_enable ctags geanyctags)
$(use_enable lua geanylua)
$(use_enable gpg geanypg)
$(use_enable soup geniuspaste)
$(use_enable git gitchangebar)
$(use_enable markdown) --disable-peg-markdown # using app-text/discount instead
$(use_enable pretty-printer)
$(use_enable scope)
$(use_enable enchant spellcheck)
# Having updatechecker… when you’re using a package manager?
$(use_enable soup updatechecker)
$(use_enable workbench)
# GeanyGenDoc requires ctpl which isn’t yet in portage
--disable-geanygendoc
# Require obsolete and vulnerable webkit-gtk versions
--disable-devhelp
--disable-webhelper
# GTK 2 only
--disable-geanydoc
--disable-geanypy
--disable-multiterm
)
econf "${myeconfargs[@]}"
}
src_install() {
default
find "${D}" -name '*.la' -delete || die
# make installs all translations if LINGUAS is empty
if [[ -z "${LINGUAS-x}" ]]; then
rm -r "${ED}/usr/share/locale/" || die
fi
}