dev-python/trio: add version 0.20.0

Package-Manager: Portage-3.0.30, Repoman-3.0.3
Signed-off-by: Andrew Ammerlaan <andrewammerlaan@gentoo.org>

dev-python/trio/Manifest

@@ -1 +1,2 @@
 DIST trio-0.19.0.tar.gz 486036 BLAKE2B 052cadb8d251960b20349659b92f4d26c5b65128cbbfafee21a4a4b90463e43d9c9db6b35f3659d2b062c7d0b8b8914b31b38d2faed6c9d948c0ccbe85a0a250 SHA512 5297a3f48b786eac05b686f1e8bb0603a9c0133d6c4872a307cdc8f1e37aedb57d668b61c2568c82b7d1058b6604a22d2c5c2298f13d13f0daf8e9259aa76d7c
+DIST trio-0.20.0.tar.gz 491254 BLAKE2B 354e8019d1ba8ac35bbb00477806ab87d62de0e9a94b1ff3a4d63c024af8cd40261c46a2c9449f38550e809938f3c6ee620a47e866bc31203c3c4a4984446fa5 SHA512 9aa431d0bc28737dd48a7358446acaffbf34860dc467ac121166f7241ebf4a4ed8bcdc8dc0277034e3c3fd70f1f8a57d790e98bdda7a1141f2c53c6b85a97a3c

dev-python/trio/trio-0.20.0.ebuild

@@ -0,0 +1,62 @@
+# Copyright 1999-2022 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+PYTHON_COMPAT=( python3_{8..10} )
+DISTUTILS_USE_PEP517=setuptools
+inherit distutils-r1
+
+DESCRIPTION="Python library for async concurrency and I/O"
+HOMEPAGE="
+	https://github.com/python-trio/trio
+	https://pypi.org/project/trio
+"
+SRC_URI="https://github.com/python-trio/${PN}/archive/v${PV}.tar.gz -> ${P}.tar.gz"
+
+LICENSE="|| ( Apache-2.0 MIT )"
+SLOT="0"
+KEYWORDS="~amd64 ~arm ~arm64 ~hppa ~ia64 ~ppc ~ppc64 ~riscv ~sparc ~x86"
+
+RDEPEND="
+	>=dev-python/async_generator-1.9[${PYTHON_USEDEP}]
+	>=dev-python/attrs-19.2.0[${PYTHON_USEDEP}]
+	dev-python/idna[${PYTHON_USEDEP}]
+	dev-python/outcome[${PYTHON_USEDEP}]
+	dev-python/sniffio[${PYTHON_USEDEP}]
+	dev-python/sortedcontainers[${PYTHON_USEDEP}]
+"
+# NB: we're ignoring tests that require trustme+pyopenssl
+BDEPEND="
+	test? (
+		>=dev-python/astor-0.8.0[${PYTHON_USEDEP}]
+		>=dev-python/immutables-0.6[${PYTHON_USEDEP}]
+		dev-python/ipython[${PYTHON_USEDEP}]
+		>=dev-python/jedi-0.18.0[${PYTHON_USEDEP}]
+		dev-python/pylint[${PYTHON_USEDEP}]
+	)
+"
+
+EPYTEST_DESELECT=(
+	# Times out on slower arches (ia64 in this case)
+	# https://github.com/python-trio/trio/issues/1753
+	trio/tests/test_unix_pipes.py::test_close_at_bad_time_for_send_all
+
+	# Fail with Python 3.10 on 'IPPROTO_MPTCP'
+	# Everything else passes and this is a simple check for exported symbols
+	# Let's try again with the next release (after 0.19.0).
+	trio/tests/test_exports.py::test_static_tool_sees_all_symbols
+)
+
+EPYTEST_IGNORE=(
+	# these tests require internet access
+	trio/tests/test_ssl.py
+	trio/tests/test_highlevel_ssl_helpers.py
+)
+
+distutils_enable_tests pytest
+distutils_enable_sphinx docs/source \
+					dev-python/immutables \
+					dev-python/sphinxcontrib-trio \
+					dev-python/sphinx_rtd_theme \
+					dev-python/towncrier