net-analyzer/ospd-openvas: drop 22.8.2-r1

Signed-off-by: Giuseppe Foti <foti.giuseppe@gmail.com>
Part-of: https://codeberg.org/gentoo/gentoo/pulls/519
Signed-off-by: Sam James <sam@gentoo.org>

net-analyzer/ospd-openvas/Manifest

@@ -1,3 +1,2 @@
 DIST ospd-openvas-22.10.1.tar.gz 256447 BLAKE2B e1d695440bea8386ec823d3091a1612e4158f590d78adeed8651a1701724ddff6362ac185302f7fd3f3e1436b23c8306ed03148da6d195d8e3ec0a5a5dae15ab SHA512 4764b7939d85333250d44b5a7c93228866865281b73e6e3317486ea5d483c607428e28449e9d56f787a91e9b0bf331dd0520989c2c785c63f7afbfe6929876b3
-DIST ospd-openvas-22.8.2.tar.gz 250151 BLAKE2B 444ce2e73c32367530c14d1b698e5b7563ddb6f7775e517064185713edb8348c6d8f4ee3c3fa1f8edbcb3ff4c2d6720d7fc29d6fa5f6889b486e0d40f0c5972d SHA512 72d868f41f575d0ef20b665afaf32113bf40f37f1f3a0626ec432f5e1e2f0ebade283c13c2a8c9dc8eab185997bcd9d890a9be0bc5964e7c65f32ba8b24ee070
 DIST ospd-openvas-22.9.0.tar.gz 250165 BLAKE2B 4e82df9902dcd10bcfa0cf6024875025ad78d8811da25b1b25d5d188b1b2e69243e7e5141199d82f845da70f7544bf2f87166d1e0fdefe91055c0bf3e5c037cf SHA512 5bbfadd1b5a75a0b0a44c1382d730cea824f66bfe22d33cc263328ff633f4ac1d39c1dc1416ecab5d06a5c8b47fa8241debac48baff98a4c2a305e0942d9b07f

net-analyzer/ospd-openvas/ospd-openvas-22.8.2-r1.ebuild

@@ -1,86 +0,0 @@
-# Copyright 2020-2025 Gentoo Authors
-# Distributed under the terms of the GNU General Public License v2
-
-EAPI=8
-
-PYTHON_COMPAT=( python3_{11..14} pypy3_11 )
-DISTUTILS_USE_PEP517=poetry
-inherit distutils-r1 systemd
-
-DESCRIPTION="This is an OSP server implementation to allow GVM to remotely control OpenVAS"
-HOMEPAGE="https://www.greenbone.net https://github.com/greenbone/ospd-openvas"
-SRC_URI="https://github.com/greenbone/ospd-openvas/archive/v${PV}.tar.gz -> ${P}.tar.gz"
-
-LICENSE="AGPL-3+ GPL-2+"
-SLOT="0"
-KEYWORDS="amd64"
-IUSE="doc +notus"
-
-DEPEND="
-	acct-user/gvm
-	>=dev-python/defusedxml-0.6[${PYTHON_USEDEP}]
-	>=dev-python/deprecated-1.2.10[${PYTHON_USEDEP}]
-	>=dev-python/lxml-4.5.2[${PYTHON_USEDEP}]
-	<dev-python/lxml-7.0.0[${PYTHON_USEDEP}]
-	dev-python/packaging[${PYTHON_USEDEP}]
-	>=dev-python/psutil-5.5.1[${PYTHON_USEDEP}]
-	<dev-python/psutil-8.0.0[${PYTHON_USEDEP}]
-	>=dev-python/redis-4.5.0[${PYTHON_USEDEP}]
-	>=dev-python/python-gnupg-0.4.8[${PYTHON_USEDEP}]
-	<dev-python/python-gnupg-0.6.0[${PYTHON_USEDEP}]
-	>=dev-python/paho-mqtt-1.6[${PYTHON_USEDEP}]
-	<dev-python/paho-mqtt-3[${PYTHON_USEDEP}]
-	net-libs/paho-mqtt-c
-	app-misc/mosquitto
-"
-RDEPEND="
-	${DEPEND}
-	app-admin/sudo
-	>=net-analyzer/openvas-scanner-22.4
-	notus? ( >=net-analyzer/notus-scanner-22.4 )
-"
-
-distutils_enable_tests unittest
-
-python_compile() {
-	if use doc; then
-		bash "${S}"/docs/generate || die
-		HTML_DOCS=( "${S}"/docs/. )
-	fi
-	distutils-r1_python_compile
-}
-
-python_install() {
-	distutils-r1_python_install
-
-	insinto /etc/gvm
-	doins config/${PN}.conf
-	if ! use prefix; then
-		fowners -R gvm:gvm /etc/gvm
-	fi
-
-	newinitd "${FILESDIR}/${PN}-22.initd" "${PN}"
-	newconfd "${FILESDIR}/${PN}-22.confd" "${PN}"
-
-	systemd_dounit config/${PN}.service
-
-	if use notus; then
-		systemd_install_serviced "${FILESDIR}/ospd-openvas.service_notus.conf" \
-			${PN}.service
-	else
-		systemd_install_serviced "${FILESDIR}/ospd-openvas.service.conf" \
-			${PN}.service
-	fi
-
-	insinto /etc/logrotate.d
-	newins "${FILESDIR}/ospd-openvas.logrotate" ospd-openvas
-
-	# OSPD OpenVAS attempts to call openvas via sudo as network security
-	# scanning often requires priviliged operations.
-	insinto /etc/sudoers.d
-	newins - openvas <<-EOF
-	gvm  ALL = NOPASSWD: /usr/bin/openvas
-EOF
-	fperms 0750 /etc/sudoers.d
-	fperms 0440 /etc/sudoers.d/openvas
-}