dev-java/bcpg: add 1.72

Signed-off-by: Volkmar W. Pogatzki <gentoo@pogatzki.net>
Signed-off-by: Florian Schmaus <flow@gentoo.org>

dev-java/bcpg/Manifest

@@ -1 +1,2 @@
 DIST bc-java-r1rv71.tar.gz 117684695 BLAKE2B db0a1b2576a55592e0447aa8734e8ecb6fe8452d08dabf010070f3c6b5a3b4caa7a5929baaa52796fed0ef397e18fe58fdb91dfef6da75af8f28efb627d2b808 SHA512 c9a095a034863a46027e28754ae96d9750162120bc1af124fa700ad05d23716a606633b674e2e8490bda658d30d30e93f42ba00dcc1ac13596a24f8aa43a666d
+DIST bc-java-r1rv72.tar.gz 380374879 BLAKE2B 53c593c1d97e9ee56388479dce7386d254f74a8bab9612e802ebe963df84d1a397fe0c5a7a0d0db2ac2cd3252ae43e79c67b9d3ba1b5ffc20cc8727c7e1a6994 SHA512 dbfdd9e4f30ab713584830a0fd0d7e4f89904366bf4953a9e722656cc4cd92c9d29238649efa7b4cdab64e2c08f4b3b3c96667d1ade569ade5a5a2c9ad9d5b5c

dev-java/bcpg/bcpg-1.72.ebuild

@@ -0,0 +1,59 @@
+# Copyright 1999-2022 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+JAVA_PKG_IUSE="doc source test"
+MAVEN_ID="org.bouncycastle:bcpg-jdk18on:1.72"
+JAVA_TESTING_FRAMEWORKS="junit-4"
+
+inherit java-pkg-2 java-pkg-simple
+
+DESCRIPTION="Java cryptography APIs"
+HOMEPAGE="https://www.bouncycastle.org/java.html"
+SRC_URI="https://github.com/bcgit/bc-java/archive/r${PV/./rv}.tar.gz -> bc-java-r${PV/./rv}.tar.gz"
+
+LICENSE="BSD"
+SLOT="0"
+KEYWORDS="~amd64 ~arm64 ~ppc64 ~x86"
+
+CP_DEPEND="~dev-java/bcprov-${PV}:0"
+DEPEND="${CP_DEPEND}
+	>=virtual/jdk-11:*"
+RDEPEND="${CP_DEPEND}
+	>=virtual/jre-1.8:*"
+
+DOCS=( ../{README,SECURITY}.md )
+HTML_DOCS=( ../{CONTRIBUTORS,index}.html )
+
+S="${WORKDIR}/bc-java-r${PV/./rv}/pg"
+
+JAVA_SRC_DIR=(
+	"src/main/java"
+	"src/main/jdk1.9"
+)
+
+JAVA_TEST_GENTOO_CLASSPATH="junit-4"
+JAVA_TEST_RESOURCE_DIRS="src/test/resources"
+JAVA_TEST_SRC_DIR="src/test/java"
+
+src_prepare() {
+	default
+	java-pkg_clean ..
+}
+
+src_test() {
+	pushd src/test/java || die
+		local JAVA_TEST_RUN_ONLY=$(find * \
+			-name "AllTests.java" )
+	popd || die
+	JAVA_TEST_RUN_ONLY="${JAVA_TEST_RUN_ONLY//.java}"
+	JAVA_TEST_RUN_ONLY="${JAVA_TEST_RUN_ONLY//\//.}"
+	java-pkg-simple_src_test
+}
+
+src_install() {
+	docinto html
+	dodoc -r ../docs
+	java-pkg-simple_src_install
+}