media-gfx/eom: Bump to 1.24.2

Bug: https://bugs.gentoo.org/778857
Package-Manager: Portage-3.0.18, Repoman-3.0.3
Signed-off-by: Adam Feldman <NP-Hardass@gentoo.org>

media-gfx/eom/Manifest

@@ -1 +1,2 @@
 DIST eom-1.24.1.tar.xz 2408284 BLAKE2B 70d660896dff42d5a91ea651697b50d4c90ced92023d5df48dfbed374c3777676f1f2dc99a0cb071a4eaa13353f31b11346136b963cf723397632cceafa64301 SHA512 70654b99f474d1b214cbbf8e799f82f3c38f47938df34cb5c8227c116b412364c568ae989b96d7082fb0d2fa319b3dba9b8dd499d19140a4d421bd09a46bffc0
+DIST eom-1.24.2.tar.xz 2428972 BLAKE2B 871cb98c4a308dbc4821e67bae41522dbebae446e64777d764d30ded2f0637bae33cb9090e813fd7e43206ba1a436f7795684c4c5e850a242e9db96804b08e81 SHA512 38497dc5fc42340ca1b356f40eab8c14c21b1467f82ec64024d633cfb7ebfc598020b35c02eedce4f73f7a5ecb9050b0f0af4ea00279a1a5e7a627e542f34951

media-gfx/eom/eom-1.24.2.ebuild

@@ -0,0 +1,74 @@
+# Copyright 1999-2021 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=6
+
+inherit mate
+
+if [[ ${PV} != 9999 ]]; then
+	KEYWORDS="~amd64 ~arm ~arm64 ~x86"
+fi
+
+DESCRIPTION="The MATE image viewer"
+LICENSE="FDL-1.1+ GPL-2+ IJG LGPL-2+"
+SLOT="0"
+
+IUSE="X debug exif imagemagick +introspection jpeg lcms svg tiff xmp"
+
+COMMON_DEPEND="
+	dev-libs/atk
+	>=dev-libs/glib-2.52:2
+	>=dev-libs/libpeas-1.8.0[gtk]
+	>=dev-libs/libxml2-2:2
+	gnome-base/dconf
+	>=mate-base/mate-desktop-1.17.0
+	sys-libs/zlib
+	x11-libs/cairo
+	>=x11-libs/gdk-pixbuf-2.36.5:2[introspection?,jpeg?,tiff?]
+	>=x11-libs/gtk+-3.22:3[introspection?]
+	x11-libs/libX11
+	>=x11-misc/shared-mime-info-0.20
+	exif? (
+		>=media-libs/libexif-0.6.14
+		virtual/jpeg:0
+	)
+	imagemagick? ( >=media-gfx/imagemagick-6.2.6 )
+	introspection? ( >=dev-libs/gobject-introspection-0.9.3:= )
+	jpeg? ( virtual/jpeg:0 )
+	lcms? ( media-libs/lcms:2 )
+	svg? ( >=gnome-base/librsvg-2.36.2:2 )
+	xmp? ( >=media-libs/exempi-1.99.5:2 )
+"
+
+RDEPEND="${COMMON_DEPEND}
+	virtual/libintl
+	!!media-gfx/mate-image-viewer
+"
+
+DEPEND="${COMMON_DEPEND}
+	app-text/yelp-tools
+	dev-util/glib-utils
+	dev-util/gtk-doc
+	dev-util/gtk-doc-am
+	>=sys-devel/gettext-0.19.8
+	virtual/pkgconfig
+"
+
+PATCHES=( "${FILESDIR}/eom-1.24.0-add-gdk-includes.patch" )
+
+src_configure() {
+	mate_src_configure \
+		--enable-thumbnailer \
+		$(use_enable debug) \
+		$(use_enable introspection) \
+		$(use_with X x) \
+		$(use_with exif libexif) \
+		$(usex imagemagick \
+			--without-gdk-pixbuf-thumbnailer \
+			--with-gdk-pixbuf-thumbnailer \
+		) \
+		$(use_with jpeg libjpeg) \
+		$(use_with lcms cms) \
+		$(use_with svg librsvg) \
+		$(use_with xmp)
+}