mirror of
https://github.com/gentoo-mirror/gentoo.git
synced 2026-11-20 22:27:17 -08:00
dev-libs/intel-compute-runtime: add 23.13.26032.17
Closes: https://bugs.gentoo.org/904678 Signed-off-by: Conrad Kostecki <conikost@gentoo.org>
This commit is contained in:
@@ -1,3 +1,4 @@
|
||||
DIST intel-compute-runtime-23.05.25593.18.tar.gz 6182150 BLAKE2B 81dcceb6d13e3dfbf5fb811faf406617dba7f83d908b94806b76df115b70a3906d8786ea8aaa1b92e963a0c97e843d13e10d7c4fd66885d309ce910c7ed18d56 SHA512 f249e51f78faee84e3bd253f1ea39fe06337939f54612f0f645e0e57319abe8449e1822291dbf1760e3805a60bdaad36c59df523859a5d879d39024138bc0907
|
||||
DIST intel-compute-runtime-23.09.25812.14.tar.gz 6264026 BLAKE2B a346ee4b12a774532bb1e716159e8256001ef933b7e5943752d3eccc046a3a95b84b1b6679d81771653cab7182f51bf64cb9443da8a0cb38fea2cfd3d7ab620a SHA512 4e42b1ae8ee2f7b21e35d37d15339d18dc871f27ca759c97104f7987688193a62eabd07107cf337679a28341eb71119c5e3edc40ec48a1997a2ddbd213ba02ea
|
||||
DIST intel-compute-runtime-23.13.26032.17.tar.gz 6443585 BLAKE2B 6ca496ce19555a472ccdf6b775ab3eef8fb60a98103bc7b73f69aaec0eb3666aca0014323caa2a48b7877d550c0cb821d999575291bf2e027d4c4a7532b41048 SHA512 f1ee428626554bc029ff3e35092cf37aa184a5db8c09f4873fe39dcfccbc8e96143ec8a06415e4e0f241b3d1e6164104abebabe41297318934ba2f2f6ecfe335
|
||||
DIST intel-compute-runtime-23.13.26032.8.tar.gz 6441876 BLAKE2B e795542080edb21feab1272c4227e88096741051a879301548ed9c3d74fa8453a8738763e07a77b21b1f0ab1ed9f549235c1a5c398f8733c53f34545233128de SHA512 c3e0644c3e90c0bc4c023a0213ac8d25dcacc08dde7f6e3ec677c80e1c5b9d017f495a2192b9c89f5fbadb5de538cb8e460f66956b59e60351ca2162b69357d3
|
||||
|
||||
@@ -0,0 +1,82 @@
|
||||
# Copyright 1999-2023 Gentoo Authors
|
||||
# Distributed under the terms of the GNU General Public License v2
|
||||
|
||||
EAPI=8
|
||||
|
||||
CMAKE_BUILD_TYPE="Release"
|
||||
MY_PN="${PN/intel-/}"
|
||||
MY_P="${MY_PN}-${PV}"
|
||||
|
||||
inherit cmake flag-o-matic
|
||||
|
||||
DESCRIPTION="Intel Graphics Compute Runtime for oneAPI Level Zero and OpenCL Driver"
|
||||
HOMEPAGE="https://github.com/intel/compute-runtime"
|
||||
SRC_URI="https://github.com/intel/${MY_PN}/archive/${PV}.tar.gz -> ${P}.tar.gz"
|
||||
S="${WORKDIR}/${MY_P}"
|
||||
|
||||
LICENSE="MIT"
|
||||
SLOT="0"
|
||||
KEYWORDS="~amd64"
|
||||
IUSE="+l0 +vaapi"
|
||||
|
||||
RDEPEND=">=media-libs/gmmlib-22.3.5:="
|
||||
|
||||
DEPEND="
|
||||
${DEPEND}
|
||||
dev-libs/intel-metrics-discovery:=
|
||||
dev-libs/intel-metrics-library:=
|
||||
dev-libs/libnl:3
|
||||
dev-libs/libxml2:2
|
||||
>=dev-util/intel-graphics-compiler-1.0.13860.4
|
||||
>=dev-util/intel-graphics-system-controller-0.8.7:=
|
||||
media-libs/mesa
|
||||
>=virtual/opencl-3
|
||||
l0? ( >=dev-libs/level-zero-1.10.0:= )
|
||||
vaapi? (
|
||||
x11-libs/libdrm[video_cards_intel]
|
||||
media-libs/libva
|
||||
)
|
||||
"
|
||||
|
||||
BDEPEND="virtual/pkgconfig"
|
||||
|
||||
DOCS=( "README.md" "FAQ.md" )
|
||||
|
||||
PATCHES=(
|
||||
"${FILESDIR}/${PN}-22.24.23453-remove-fortify-sources.patch"
|
||||
)
|
||||
|
||||
src_prepare() {
|
||||
# Remove '-Werror' from default
|
||||
sed -e '/Werror/d' -i CMakeLists.txt || die
|
||||
|
||||
cmake_src_prepare
|
||||
}
|
||||
|
||||
src_configure() {
|
||||
# See https://github.com/intel/compute-runtime/issues/531
|
||||
filter-lto
|
||||
|
||||
local mycmakeargs=(
|
||||
-DCCACHE_ALLOWED="OFF"
|
||||
-DCMAKE_INSTALL_PREFIX="${EPREFIX}/usr"
|
||||
-DCMAKE_INSTALL_LIBDIR="$(get_libdir)"
|
||||
-DBUILD_WITH_L0="$(usex l0)"
|
||||
-DDISABLE_LIBVA="$(usex !vaapi)"
|
||||
-DNEO__METRICS_LIBRARY_INCLUDE_DIR="${ESYSROOT}/usr/include"
|
||||
-DKHRONOS_GL_HEADERS_DIR="${ESYSROOT}/usr/include"
|
||||
-DOCL_ICD_VENDORDIR="${EPREFIX}/etc/OpenCL/vendors"
|
||||
-DSUPPORT_DG1="ON"
|
||||
-Wno-dev
|
||||
|
||||
# See https://github.com/intel/intel-graphics-compiler/issues/204
|
||||
# -DNEO_DISABLE_BUILTINS_COMPILATION="ON"
|
||||
|
||||
# If enabled, tests are automatically run during
|
||||
# the compile phase and we cannot run them because
|
||||
# they require permissions to access the hardware.
|
||||
-DSKIP_UNIT_TESTS="1"
|
||||
)
|
||||
|
||||
cmake_src_configure
|
||||
}
|
||||
Reference in New Issue
Block a user