dev-debug/ltrace: add 0.8.1

Removed patch 0.7.91-test-glibc-2.33.patch - applied upstream in
commit 76475ef44698 ("testsuite: system_calls: recognize newfstatat")

Other patches appear to still be relevant and apply cleanly.

Closes: https://bugs.gentoo.org/964044
Signed-off-by: Brett A C Sheffield <bacs@librecast.net>
Signed-off-by: Sam James <sam@gentoo.org>

dev-debug/ltrace/Manifest

@@ -1 +1,2 @@
 DIST ltrace-0.7.91_pre20221216.tar.bz2 288077 BLAKE2B cadc2ac551a96dfa95aee0d0eb251d8f41a8631350ba3be3f67d0cb10774a3db6abbd42481d24febdfcb0d565107e66b4de0056a85a7954bb050adb8e8fa5b4a SHA512 993c247797551b4fbb202c04f9af08063c8641946825b17d1f32c4647c606ece803a6b049c4afa3046c798add161ab58f01d90106f3b6029a223af03bca27a99
+DIST ltrace-0.8.1.tar.bz2 296963 BLAKE2B 4fb938f3511668f836f7f9cd3d3ab88b9e46a749bce9f506609c1ebfced552c71f868272766be7d902c0151eba55061d6aa9f5c88b0f40cf040cc6f4a43d9ce6 SHA512 68fdf10abb3c9534987cb4fcf2531502f8376c56299d56908406ba903fa63af2e0a82c3b902ed0cd47e4985154155a4e9387a11ada066515de26486301dddbaf

dev-debug/ltrace/ltrace-0.8.1.ebuild

@@ -0,0 +1,58 @@
+# Copyright 1999-2026 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+inherit autotools
+
+DESCRIPTION="trace library calls made at runtime"
+HOMEPAGE="https://gitlab.com/cespedes/ltrace"
+SRC_URI="https://gitlab.com/cespedes/${PN}/-/archive/${PV}/${P}.tar.bz2"
+
+LICENSE="GPL-2"
+SLOT="0"
+KEYWORDS="~alpha ~amd64 ~arm ~mips ~ppc ~ppc64 ~sparc ~x86"
+IUSE="debug elfutils selinux test unwind"
+
+REQUIRED_USE="?? ( elfutils unwind )"
+
+RDEPEND="virtual/libelf:=
+	elfutils? ( dev-libs/elfutils )
+	selinux? ( sys-libs/libselinux )
+	unwind? ( sys-libs/libunwind:= )"
+DEPEND="${RDEPEND}
+	sys-libs/binutils-libs
+	test? ( dev-util/dejagnu )"
+
+# Effectively abandoned upstream. Extremely sensitive to the sandbox, versions
+# of core libraries, kernel security settings...
+RESTRICT="test"
+
+PATCHES=(
+	"${FILESDIR}"/${PN}-0.7.91-debian-patchset-6.4.patch
+	"${FILESDIR}"/${PN}-0.7.3-CXX-for-tests.patch
+	"${FILESDIR}"/${PN}-0.7.3-alpha-protos.patch
+	"${FILESDIR}"/${PN}-0.7.3-ia64.patch
+	"${FILESDIR}"/${PN}-0.7.3-ia64-pid_t.patch
+	"${FILESDIR}"/${PN}-0.7.3-musl-host.patch
+	"${FILESDIR}"/${PN}-0.7.3-print-test-pie.patch
+	"${FILESDIR}"/${PN}-0.7.91-pid_t.patch
+	"${FILESDIR}"/${PN}-0.7.91-tuple-tests.patch
+)
+
+src_prepare() {
+	default
+
+	sed -i '/^dist_doc_DATA/d' Makefile.am || die
+	eautoreconf
+}
+
+src_configure() {
+	ac_cv_header_selinux_selinux_h=$(usex selinux) \
+	ac_cv_lib_selinux_security_get_boolean_active=$(usex selinux) \
+	econf \
+		--disable-werror \
+		$(use_enable debug) \
+		$(use_with elfutils) \
+		$(use_with unwind libunwind)
+}