dev-python/h5py: Bump to 3.6.0

Signed-off-by: Michał Górny <mgorny@gentoo.org>

dev-python/h5py/Manifest

@@ -1 +1,2 @@
 DIST h5py-3.3.0.tar.gz 380221 BLAKE2B 0fd44e780304f0d56e8fd8fd0f42142c80935fa7cc3e6c53ff68860f32755d3d5e576fc283bb9b21e9d7dfb905bdeed6656eeaa33e48cefd34de86fde3efa49d SHA512 f1ce944375da3db65829e8a9d667ee7ffa2f863e408aa4ccac0de9d999e0710ebcb1e116537616649fcfd05731cad3cbd968c9593f0ba0fd4348ee06c74d9dae
+DIST h5py-3.6.0.tar.gz 384160 BLAKE2B 354764bb002cd342623aa962de88a24ee45156c0a2d61088508017980e407e90f85e65da9d3e29a6745dbca754ba1708700fbea4f4123a10a620bc758cbaa3ae SHA512 f3a108d16578ced552fcac4fceb7f3180ee71a3c8f6caa8702fd9989728d8284afb9d85f1239648e10d14f3532c772f46d05f8306bb8b305d98b162d7604683b

dev-python/h5py/h5py-3.6.0.ebuild

@@ -0,0 +1,70 @@
+# Copyright 1999-2022 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_USE_PEP517=setuptools
+PYTHON_COMPAT=( python3_{8..10} )
+
+inherit distutils-r1
+
+DESCRIPTION="Simple Python interface to HDF5 files"
+HOMEPAGE="
+	https://www.h5py.org/
+	https://github.com/h5py/h5py/
+	https://pypi.org/project/h5py/
+"
+SRC_URI="mirror://pypi/${PN:0:1}/${PN}/${P}.tar.gz"
+
+LICENSE="BSD"
+SLOT="0"
+KEYWORDS="~amd64 ~x86 ~amd64-linux ~x86-linux"
+# disable mpi until mpi4py gets python3_8
+#IUSE="examples mpi"
+IUSE="examples"
+
+#RDEPEND="sci-libs/hdf5:=[mpi=,hl(+)]
+DEPEND="
+	sci-libs/hdf5:=[hl(+)]
+"
+RDEPEND="
+	${DEPEND}
+	>=dev-python/numpy-1.14.5[${PYTHON_USEDEP}]
+"
+
+BDEPEND="
+	dev-python/cython[${PYTHON_USEDEP}]
+	>=dev-python/numpy-1.14.5[${PYTHON_USEDEP}]
+	dev-python/pkgconfig[${PYTHON_USEDEP}]
+	test? (
+		dev-python/QtPy[testlib,${PYTHON_USEDEP}]
+	)
+"
+#	mpi? ( virtual/mpi )
+#	mpi? ( dev-python/mpi4py[${PYTHON_USEDEP}] )
+
+distutils_enable_tests pytest
+distutils_enable_sphinx docs \
+	dev-python/alabaster
+
+#pkg_setup() {
+#	use mpi && export CC=mpicc
+#}
+
+python_prepare_all() {
+	# avoid pytest-mpi dep, we do not use mpi anyway
+	sed -i -e 's:pytest-mpi::' pytest.ini || die
+	distutils-r1_python_prepare_all
+
+	export H5PY_SETUP_REQUIRES=0
+}
+
+python_test() {
+	cd "${BUILD_DIR}/install$(python_get_sitedir)" || die
+	epytest -m "not mpi"
+}
+
+python_install_all() {
+	use examples && dodoc -r examples
+	distutils-r1_python_install_all
+}