dev-libs/msgpack: version bump to 3.2.1

Signed-off-by: Tim Harder <radhermit@gentoo.org>

dev-libs/msgpack/Manifest

@@ -1,3 +1,4 @@
 DIST msgpack-1.1.0.tar.gz 493551 BLAKE2B 3ee162fcba5ae61c7c69945a567ac4d39526e7941f42cc2ed55bc5885b823af84eea212c4e75e8e8583e8ea8a5e12f75e969409193c5e7273430e2e02d33a02c SHA512 6823fab090c2146f871a45736c29b8f81434f0d72c597ebea2e947e4a9a17554e163bc88fbbc3dd0805b2ef0df029b10ca30c09dfbd1111252b9861a1e373901
 DIST msgpack-3.1.1.tar.gz 495858 BLAKE2B a99b7edb2a6de80e018d5c4084ea199518e34045a6293c622c8690147ae353abdb63856eb031962a02ce20903d4443ec2b01a3c033e756c339f8674ff801d4c3 SHA512 cc634ef38b3844bf994159024441fe72d99055c42b0a4d81245b0629fd1f3147587eb36537cfb85e4cae2edc1dc23d7fa400022efa5a10dca295f9a6acd38346
 DIST msgpack-3.2.0.tar.gz 499188 BLAKE2B 6e5fd59a96ca726d3429b173b3db4c74163eaf6d314b289845237b6ace6208478dbbbb60397c630d515f6f6eed344b74f76225d1a4ca143b91ebb9b3a1369c14 SHA512 f3d011adfaa71b3c5d5f3eb43f0addbd461ae82b8ac22f367ddba7ef762d3bea500477501cf394d1770f0c47809bc363fc1088819ecfdfa668e93529885f4b88
+DIST msgpack-3.2.1.tar.gz 1234733 BLAKE2B 97fb6cab5125463f10e7ad2c55ee478b2bf3dab5628a40ce1b0bcdd96cc002f5c99e495592c91f1342e6623d32b5594536de226b0bf80e1cb5290dae9b0566dc SHA512 68d06b05a1f00a3d9d7d39313a9e11f42828606c39d9d4c07673a48c9b88028a6316f2a964881cc8e4d185616a037711f02a7d3cd6029eadbacf52145603538b

dev-libs/msgpack/msgpack-3.2.1.ebuild

@@ -0,0 +1,75 @@
+# Copyright 1999-2020 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+inherit cmake-multilib
+
+if [[ ${PV} == 9999 ]]; then
+	inherit git-r3
+	EGIT_REPO_URI="https://github.com/${PN}/${PN}-c.git"
+else
+	SRC_URI="https://github.com/${PN}/${PN}-c/releases/download/cpp-${PV}/${P}.tar.gz"
+	KEYWORDS="~amd64 ~x86 ~amd64-linux ~x86-linux"
+fi
+
+DESCRIPTION="MessagePack is a binary-based efficient data interchange format"
+HOMEPAGE="https://msgpack.org/ https://github.com/msgpack/msgpack-c/"
+
+LICENSE="Boost-1.0"
+SLOT="0/2"
+IUSE="boost +cxx doc examples static-libs test"
+RESTRICT="!test? ( test )"
+
+RDEPEND="boost? ( dev-libs/boost[context,${MULTILIB_USEDEP}] )"
+DEPEND="${RDEPEND}
+	test? (
+		>=dev-cpp/gtest-1.6.0-r2[${MULTILIB_USEDEP}]
+		sys-libs/zlib[${MULTILIB_USEDEP}]
+	)
+	doc? ( app-doc/doxygen[dot] )
+"
+
+src_configure() {
+	local mycmakeargs=(
+		-DMSGPACK_BOOST="$(usex boost)"
+		-DMSGPACK_ENABLE_CXX="$(usex cxx)"
+		-DMSGPACK_ENABLE_STATIC="$(usex static-libs)"
+		-DMSGPACK_BUILD_TESTS="$(usex test)"
+		# don't build the examples
+		-DMSGPACK_BUILD_EXAMPLES=OFF
+		# enable C++11 by default
+		-DMSGPACK_CXX11=ON
+	)
+	cmake-multilib_src_configure
+}
+
+multilib_src_compile() {
+	cmake-utils_src_compile
+
+	if multilib_is_native_abi && use doc; then
+		cmake-utils_src_make doxygen
+	fi
+}
+
+multilib_src_install() {
+	if multilib_is_native_abi; then
+		if use doc; then
+			local HTML_DOCS=( "${BUILD_DIR}"/docs/. )
+
+			mkdir docs || die
+			mv doc_c/html docs/c || die
+
+			use cxx && mv doc_cpp/html docs/cpp || die
+		fi
+
+		if use examples; then
+			docinto examples
+
+			dodoc -r "${WORKDIR}/${P}/example/."
+
+			docompress -x /usr/share/doc/${PF}/examples
+		fi
+	fi
+
+	cmake-utils_src_install
+}