mirror of
https://github.com/gentoo-mirror/gentoo.git
synced 2026-11-21 22:47:14 -08:00
net-misc/streamlink: add 6.8.1
Signed-off-by: Sam James <sam@gentoo.org>
This commit is contained in:
@@ -1,2 +1,3 @@
|
||||
DIST streamlink-6.7.3.tar.gz 742832 BLAKE2B 5f03a036c3f2170d25e43618f36d7b937e8063f15a965f45d8cc6033b49899b15c19af23aa2a845f8aec74341932721b792dad6bff70400f0dea24a19f1415ed SHA512 0955faab177bcdd0f66500f837124bf0f426829cb5c847fa18bb85aa3fcd7c27a750bab13f3e247b5187e9561713330b582b10729d82984d98081856e976ae65
|
||||
DIST streamlink-6.7.4.tar.gz 744387 BLAKE2B bd8fb9af560fbe164a63fd1b698100765c716b44b6f3364e6ad072f69d0fdee9d22dd0fda6c297f249915c9a60f10e2089228a8c19244a7ef18b5809632bf96a SHA512 266c66626624814d708a228d4e2e62c443c3973fb139632a88086619c755fa80d97fad077a2a7383f9beb3e2f4464274beb0bb446b85f6f63d6704a88a9c2e29
|
||||
DIST streamlink-6.8.1.tar.gz 748765 BLAKE2B bf42375bc37432c66e8d2c9d8c3b31cfbda8c990bc4d7b83970198c4f60b5dc30d5ce3daf339bb842bc058955edff55df16da4f4cc0362410eaaff1bb6d74e28 SHA512 51cb03ca2414ec64f95704833568bb48aaae458e77f6ef3f4d858b564908cff4944c07a0b4d3bb648a0fe2bbb6a43a7964333878e31aef0b2a6ff3b9048b8e1d
|
||||
|
||||
@@ -0,0 +1,99 @@
|
||||
# Copyright 1999-2024 Gentoo Authors
|
||||
# Distributed under the terms of the GNU General Public License v2
|
||||
|
||||
EAPI=8
|
||||
|
||||
if [[ ${PV} = 9999* ]]; then
|
||||
EGIT_REPO_URI="https://github.com/streamlink/${PN}.git"
|
||||
inherit git-r3
|
||||
fi
|
||||
|
||||
DISTUTILS_SINGLE_IMPL=1
|
||||
# >= 6.2.1 uses a bunch of setuptools hooks instead of vanilla setuptools
|
||||
# https://github.com/streamlink/streamlink/commit/194d9bc193f5285bc1ba33af5fd89209a96ad3a7
|
||||
DISTUTILS_USE_PEP517=standalone
|
||||
PYTHON_COMPAT=( python3_{10..12} )
|
||||
PYTHON_REQ_USE='xml(+),threads(+)'
|
||||
inherit distutils-r1
|
||||
|
||||
DESCRIPTION="CLI for extracting streams from websites to a video player of your choice"
|
||||
HOMEPAGE="https://streamlink.github.io/"
|
||||
|
||||
if [[ ${PV} != 9999* ]]; then
|
||||
SRC_URI="https://github.com/streamlink/${PN}/releases/download/${PV}/${P}.tar.gz"
|
||||
fi
|
||||
|
||||
LICENSE="BSD-2 Apache-2.0"
|
||||
SLOT="0"
|
||||
if [[ ${PV} != 9999* ]]; then
|
||||
KEYWORDS="~amd64 ~arm ~arm64 ~x86"
|
||||
fi
|
||||
|
||||
# See https://github.com/streamlink/streamlink/commit/9d8156dd794ee0919297cd90d85bcc11b8a28358 for chardet/charset-normalizer dep
|
||||
RDEPEND="
|
||||
media-video/ffmpeg
|
||||
$(python_gen_cond_dep '
|
||||
dev-python/exceptiongroup[${PYTHON_USEDEP}]
|
||||
' 3.10)
|
||||
$(python_gen_cond_dep '
|
||||
dev-python/certifi[${PYTHON_USEDEP}]
|
||||
|| (
|
||||
dev-python/chardet[${PYTHON_USEDEP}]
|
||||
dev-python/charset-normalizer[${PYTHON_USEDEP}]
|
||||
)
|
||||
>=dev-python/requests-2.26.0[${PYTHON_USEDEP}]
|
||||
dev-python/isodate[${PYTHON_USEDEP}]
|
||||
>=dev-python/lxml-4.6.4[${PYTHON_USEDEP}]
|
||||
>=dev-python/websocket-client-1.2.1[${PYTHON_USEDEP}]
|
||||
dev-python/pycountry[${PYTHON_USEDEP}]
|
||||
>=dev-python/pycryptodome-3.4.3[${PYTHON_USEDEP}]
|
||||
>dev-python/PySocks-1.5.7[${PYTHON_USEDEP}]
|
||||
>=dev-python/trio-0.22.0[${PYTHON_USEDEP}]
|
||||
>=dev-python/trio-websocket-0.9.0[${PYTHON_USEDEP}]
|
||||
>=dev-python/urllib3-1.26.0[${PYTHON_USEDEP}]
|
||||
')
|
||||
"
|
||||
BDEPEND="
|
||||
$(python_gen_cond_dep '
|
||||
>=dev-python/setuptools-64[${PYTHON_USEDEP}]
|
||||
>=dev-python/versioningit-2.0.0[${PYTHON_USEDEP}]
|
||||
test? (
|
||||
>=dev-python/freezegun-1.0.0[${PYTHON_USEDEP}]
|
||||
dev-python/pytest-asyncio[${PYTHON_USEDEP}]
|
||||
dev-python/pytest-trio[${PYTHON_USEDEP}]
|
||||
dev-python/requests-mock[${PYTHON_USEDEP}]
|
||||
)
|
||||
')
|
||||
"
|
||||
|
||||
if [[ ${PV} == 9999* ]]; then
|
||||
RDEPEND+="
|
||||
$(python_gen_cond_dep '
|
||||
>=dev-python/versioningit-2.0.0[${PYTHON_USEDEP}]
|
||||
')
|
||||
"
|
||||
fi
|
||||
|
||||
distutils_enable_tests pytest
|
||||
|
||||
python_test() {
|
||||
# Skip tests requiring <dev-python/pytest-8.0.0
|
||||
# https://github.com/streamlink/streamlink/pull/5901
|
||||
EPYTEST_DESELECT+=(
|
||||
tests/webbrowser/cdp/test_client.py::TestEvaluate::test_exception
|
||||
tests/webbrowser/cdp/test_client.py::TestEvaluate::test_error
|
||||
tests/webbrowser/cdp/test_client.py::TestNavigate::test_detach
|
||||
tests/webbrowser/cdp/test_client.py::TestNavigate::test_error
|
||||
tests/webbrowser/cdp/test_connection.py::TestCreateConnection::test_failure
|
||||
tests/webbrowser/cdp/test_connection.py::TestReaderError::test_invalid_json
|
||||
tests/webbrowser/cdp/test_connection.py::TestReaderError::test_unknown_session_id
|
||||
'tests/webbrowser/cdp/test_connection.py::TestSend::test_timeout[Default timeout, response not in time]'
|
||||
'tests/webbrowser/cdp/test_connection.py::TestSend::test_timeout[Custom timeout, response not in time]'
|
||||
tests/webbrowser/cdp/test_connection.py::TestSend::test_bad_command
|
||||
tests/webbrowser/cdp/test_connection.py::TestSend::test_result_exception
|
||||
tests/webbrowser/cdp/test_connection.py::TestHandleCmdResponse::test_response_error
|
||||
tests/webbrowser/cdp/test_connection.py::TestHandleCmdResponse::test_response_no_result
|
||||
)
|
||||
|
||||
epytest
|
||||
}
|
||||
Reference in New Issue
Block a user