net-dialup/accel-ppp: drop 1.12.0_p20220830-r1

Bug: https://bugs.gentoo.org/833455
Signed-off-by: Brett A C Sheffield <bacs@librecast.net>
Part-of: https://codeberg.org/gentoo/gentoo/pulls/323
Signed-off-by: Sam James <sam@gentoo.org>
This commit is contained in:
Brett A C Sheffield
2026-03-19 13:30:09 +00:00
committed by Sam James
parent a9cd4bbb31
commit beab63fa1a
2 changed files with 0 additions and 117 deletions
-1
View File
@@ -1,3 +1,2 @@
DIST accel-ppp-1.12.0_p20220830.tar.bz2 1667889 BLAKE2B a6432e29953214202dc67822f358c12ade36eda3e1aaa24e8a2f427ac00ae8192216c76620f3c2946bcf88c95f6167ae9c27ce4a1895c36232110cd73c575a36 SHA512 f6e0baf7dcbf66d3d9eadffeb33216d73d6aa9eef461487d51a3811f042229b38bfec5f192742eb51cc7cfedd0a64ad02a3431bfac91ae37a9aab8c910fdcfa4
DIST accel-ppp-1.12.0_p20230609.tar.bz2 1679570 BLAKE2B 3af713135f755215dc6cd4484ca02f182a17c5240b0b6edf2627412391396ccc1de41dc0098b10e2359ea6d9737c6ff177dc753209a50bdc6989103332453d93 SHA512 c78b8accf74e0f047a9c07b1259f18c7cba3a4e5ecdc594bb4fde4bbbc7b33eeac28265da879bdb17f935628f58f0828eebac0e08ec8ca079ac95911e3851ac2
DIST accel-ppp-1.14.0.tar.gz 1925929 BLAKE2B 44cc701a534f2eaa7fa4c579fdde895c2df7389108959e9bd5b7dc4406fedc6bb3fbc148b817c4605e071a09571923a3a3b0d9a8ad11b01392b412810afe7059 SHA512 58c75ec94eb197540ea2d2c4b03befbbaf040af6df7c002588f092b6cebfe40299e503875d669f2f1cff5ba14f3357fe3205fa56f4aee3337eb3dc85ae7e8e98
@@ -1,116 +0,0 @@
# Copyright 1999-2024 Gentoo Authors
# Distributed under the terms of the GNU General Public License v2
EAPI=8
LUA_COMPAT=( lua5-1 )
inherit cmake flag-o-matic linux-info linux-mod lua-single
DESCRIPTION="High performance PPTP, PPPoE and L2TP server"
HOMEPAGE="https://sourceforge.net/projects/accel-ppp/"
SRC_URI="https://dev.gentoo.org/~pinkbyte/distfiles/snapshots/${P}.tar.bz2"
LICENSE="GPL-2"
SLOT="0"
KEYWORDS="~amd64 ~x86"
IUSE="debug doc ipoe libtomcrypt lua postgres radius shaper snmp valgrind"
RDEPEND="!libtomcrypt? ( dev-libs/openssl:0= )
libtomcrypt? ( dev-libs/libtomcrypt:0= )
lua? ( ${LUA_DEPS} )
postgres? ( dev-db/postgresql:* )
snmp? ( net-analyzer/net-snmp )
dev-libs/libpcre"
DEPEND="${RDEPEND}
valgrind? ( dev-debug/valgrind )"
PDEPEND="net-dialup/ppp-scripts"
DOCS=( README )
CONFIG_CHECK="~L2TP ~PPPOE ~PPTP"
REQUIRED_USE="lua? ( ${LUA_REQUIRED_USE} )
valgrind? ( debug )"
PATCHES=(
"${FILESDIR}/${PN}-1.11.1-socklen.patch"
)
S="${WORKDIR}"
pkg_setup() {
if use ipoe; then
linux-mod_pkg_setup
set_arch_to_kernel
else
linux-info_pkg_setup
fi
use lua && lua-single_pkg_setup
}
src_prepare() {
sed -i -e "/mkdir/d" \
-e "s: RENAME accel-ppp.conf.dist::" accel-pppd/CMakeLists.txt || die 'sed on accel-pppd/CMakeLists.txt failed'
# Do not install kernel modules like that - breaks sandbox!
sed -i -e '/modules_install/d' \
drivers/ipoe/CMakeLists.txt \
drivers/vlan_mon/CMakeLists.txt || die
# Fix version
sed -i -e "s/1.11/${PV}/" drivers/ipoe/ipoe.c || die
sed -i -e "s/1.11/${PV}/" drivers/vlan_mon/vlan_mon.c || die
# Bug #549918
append-ldflags -Wl,-z,lazy
cmake_src_prepare
}
src_configure() {
local libdir="$(get_libdir)"
local mycmakeargs=(
-DCMAKE_INSTALL_SYSCONFDIR="${EPREFIX}/etc"
-DCMAKE_INSTALL_LOCALSTATEDIR="${EPREFIX}/var"
-DLIB_SUFFIX="${libdir#lib}"
-DBUILD_IPOE_DRIVER="$(usex ipoe)"
-DBUILD_PPTP_DRIVER=no
-DBUILD_VLAN_MON_DRIVER="$(usex ipoe)"
-DCRYPTO="$(usex libtomcrypt TOMCRYPT OPENSSL)"
-DLOG_PGSQL="$(usex postgres)"
-DLUA="$(usex lua TRUE FALSE)"
-DMEMDEBUG="$(usex debug)"
-DNETSNMP="$(usex snmp)"
-DRADIUS="$(usex radius)"
-DSHAPER="$(usex shaper)"
$(use debug && echo "-DVALGRIND=$(usex valgrind)")
)
cmake_src_configure
}
src_compile() {
cmake_src_compile
}
src_install() {
if use ipoe; then
local MODULE_NAMES="ipoe(accel-ppp:${BUILD_DIR}/drivers/ipoe/driver) vlan_mon(accel-ppp:${BUILD_DIR}/drivers/vlan_mon/driver)"
linux-mod_src_install
fi
cmake_src_install
use doc && dodoc -r rfc
if use snmp; then
insinto /usr/share/snmp/mibs
doins accel-pppd/extra/net-snmp/ACCEL-PPP-MIB.txt
fi
newinitd "${FILESDIR}"/${PN}.initd ${PN}d
newconfd "${FILESDIR}"/${PN}.confd ${PN}d
keepdir /var/lib/accel-ppp
keepdir /var/log/accel-ppp
}