media-libs/lilv: bump to 0.24.24

Signed-off-by: Miroslav Šulc <fordfrog@gentoo.org>

media-libs/lilv/Manifest

@@ -1 +1,2 @@
 DIST lilv-0.24.22.tar.xz 105504 BLAKE2B bd9df20d95ffa921615fb21deed4bc354158219aa51125fc00351aa5ca2f480f9d10d8c867003a373b47eea145c21bb8d0bfc86d53eb1d04d281e1df2fc4a0f2 SHA512 cd771db89919a11e258d12b43674d7174645a4369f5d3a5168b1217c0a87795926dd7db5304e81cb27eb30477198ac42e6e4931d40fcda833bf70ef75acc558f
+DIST lilv-0.24.24.tar.xz 105684 BLAKE2B 4228248e8dbee228cee193e259d95b2e66f9f2e3516702dfad0dc126273076230274538c32a857ae9ad8a58545bbf48e7791254441dd4d6e537715de9e5e5be6 SHA512 93a3842a5e000a9c59bf3493c2c10df35a803a7edf6cff09f43e155a7e83d0c7c81bc24a6243828dc141d30187c3f60ef9799f319f72e5b6c3e2d022de757185

media-libs/lilv/lilv-0.24.24.ebuild

@@ -0,0 +1,77 @@
+# Copyright 1999-2024 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+PYTHON_COMPAT=( python3_{9..12} )
+PYTHON_REQ_USE='threads(+)'
+
+inherit meson-multilib python-single-r1
+
+DESCRIPTION="Library to make the use of LV2 plugins as simple as possible for applications"
+HOMEPAGE="https://drobilla.net/software/lilv.html"
+SRC_URI="https://download.drobilla.net/${P}.tar.xz"
+
+LICENSE="ISC"
+SLOT="0"
+KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~ia64 ~loong ~mips ~ppc ~ppc64 ~riscv ~sparc ~x86"
+IUSE="doc python test tools"
+REQUIRED_USE="${PYTHON_REQUIRED_USE}"
+RESTRICT="!test? ( test )"
+
+BDEPEND="
+	virtual/pkgconfig
+	doc? (
+		app-text/doxygen
+		dev-python/sphinx
+		dev-python/sphinx-lv2-theme
+		dev-python/sphinxygen
+	)
+"
+# Take care on bumps to check minimum versions!
+RDEPEND="
+	${PYTHON_DEPS}
+	>=dev-libs/serd-0.30.10[${MULTILIB_USEDEP}]
+	>=dev-libs/sord-0.16.16[${MULTILIB_USEDEP}]
+	>=dev-libs/zix-0.4.0[${MULTILIB_USEDEP}]
+	media-libs/libsndfile
+	>=media-libs/lv2-1.18.2[${MULTILIB_USEDEP}]
+	>=media-libs/sratom-0.6.10[${MULTILIB_USEDEP}]
+"
+DEPEND="${RDEPEND}"
+
+pkg_setup() {
+	python_setup
+}
+
+src_prepare() {
+	default
+
+	# fix doc installation path
+	sed -iE "s/versioned_name/'${PF}'/g" doc/html/meson.build doc/singlehtml/meson.build || die
+}
+
+multilib_src_configure() {
+	local emesonargs=(
+		$(meson_native_use_feature doc docs)
+		$(meson_feature python bindings_py)
+		$(meson_feature test tests)
+		$(meson_feature tools)
+	)
+
+	meson_src_configure
+}
+
+multilib_src_install() {
+	meson_src_install
+	python_optimize
+}
+
+multilib_src_install_all() {
+	local DOCS=( AUTHORS NEWS README.md )
+	einstalldocs
+
+	newenvd - 60lv2 <<-EOF
+		LV2_PATH=${EPREFIX}/usr/$(get_libdir)/lv2
+	EOF
+}