gentoo-mirror/gentoo
1
0
Fork 0
mirror of https://github.com/gentoo-mirror/gentoo.git synced 2026-09-24 04:59:14 -07:00
Code Issues Projects Releases Wiki Activity

dev-python/httpcore: Bump to 0.13.1

Browse Source 
Signed-off-by: Michał Górny <mgorny@gentoo.org>
This commit is contained in:
Michał Górny
2021-04-29 09:11:57 +02:00
parent 0ebd6f69df
commit bd4f65ada1
2 changed files with 64 additions and 0 deletions
Download Patch File Download Diff File Expand all files Collapse all files

1
dev-python/httpcore/Manifest
View File

@@ -1,2 +1,3 @@
DIST httpcore-0.12.3.tar.gz 57587 BLAKE2B 3c0e7a210b21e54564c4c6077fadf66344b887662c71b05a1ad4a2c0224a4d703eccdf576d4443341176edee03b6776bfd49aaef2ea2f29f02614677e1dfad85 SHA512 b31535231dc2b6a5f1c9c0c538628f75360f04b4747b447ab0a7168ed32d0eabd463335c2f7fa782dcabb4cbc32891a2839ae50e0999d5a791c01b02533d38f0
DIST httpcore-0.13.0.tar.gz 58310 BLAKE2B 29ed4ad768088c6226ece27cb82e2a1d8df32eba4cf446015b43360c330ec65b433f571ac8e13e4b8f8994ff6e097ce5bf79ae1b9561d940298172c66d539153 SHA512 28ed65d3b3b30a62e3f198d98ae77a3cc26bd80250f10a506851433b5572a6fdcab38bf0d670caea94dec43d5b61de21a3ea967a445041536cad68eb98cc12bc
DIST httpcore-0.13.1.tar.gz 58538 BLAKE2B 4c0b681f96fd64d17bc1974bdb74486fd336f84b27eda450d7de630c9f5dc2012ca91d10c4d0bcdaa06ff0e60d524993ab784721e4ffb55ff2848d68ea9ebb29 SHA512 ba410bf61e820016b061a8cd5a30b227bb75a78e90465459b2ff67dd76b9de9120d3b2474f6d8bb54698f627bb8801f2da5b3d85a4a41a0c5330d6bba8e10a49

63
dev-python/httpcore/httpcore-0.13.1.ebuild Normal file
View File

@@ -0,0 +1,63 @@
# Copyright 1999-2021 Gentoo Authors
# Distributed under the terms of the GNU General Public License v2
EAPI=7
PYTHON_COMPAT=( python3_{7..9} )
inherit distutils-r1
DESCRIPTION="A minimal low-level HTTP client"
HOMEPAGE="https://www.encode.io/httpcore/"
SRC_URI="https://github.com/encode/${PN}/archive/${PV}.tar.gz -> ${P}.tar.gz"
LICENSE="BSD"
SLOT="0"
KEYWORDS="~amd64 ~x86"
RDEPEND="
=dev-python/h11-0*[${PYTHON_USEDEP}]
=dev-python/sniffio-1*[${PYTHON_USEDEP}]
"
BDEPEND="
test? (
dev-python/pytest-asyncio[${PYTHON_USEDEP}]
dev-python/trustme[${PYTHON_USEDEP}]
)
"
distutils_enable_tests pytest
python_prepare_all() {
# anyio and trio are not in the tree
sed -i 's/^@pytest.mark.\(anyio\|trio\)/@pytest.mark.skip/' \
tests/async_tests/test_*.py || die
sed -i '/^import trio/d' tests/utils.py || die
# pproxy is not in the tree, the associated fixture
# must be disabled to prevent errors during test setup
sed -i 's/def proxy_server().*/&\n pytest.skip()/' \
tests/conftest.py || die
distutils-r1_python_prepare_all
}
python_test() {
local skipped_tests=(
# Require Internet access or hypercorn (not in the tree)
tests/test_threadsafety.py::test_threadsafe_basic
tests/sync_tests/test_interfaces.py::test_http_request
tests/sync_tests/test_interfaces.py::test_https_request
tests/sync_tests/test_interfaces.py::test_http2_request
tests/sync_tests/test_interfaces.py::test_closing_http_request
tests/sync_tests/test_interfaces.py::test_connection_pool_get_connection_info
tests/sync_tests/test_interfaces.py::test_max_keepalive_connections_handled_correctly
tests/sync_tests/test_interfaces.py::test_explicit_backend_name
tests/sync_tests/test_interfaces.py::test_connection_timeout_tcp
tests/sync_tests/test_interfaces.py::test_broken_socket_detection_many_open_files
tests/sync_tests/test_retries.py::test_no_retries
tests/sync_tests/test_retries.py::test_retries_exceeded
tests/sync_tests/test_retries.py::test_retries_enabled
# Require hypercorn
tests/sync_tests/test_interfaces.py::test_connection_timeout_uds
)
epytest ${skipped_tests[@]/#/--deselect }
}