mirror of
https://github.com/gentoo-mirror/gentoo.git
synced 2026-11-21 10:37:22 -08:00
dev-python/urllib3: Bump to 1.26.14
Signed-off-by: Michał Górny <mgorny@gentoo.org>
This commit is contained in:
@@ -1 +1,2 @@
|
||||
DIST urllib3-1.26.13.tar.gz 300476 BLAKE2B 495b6077d8a18347d731dcc69989688c2fed325a5ff89a7faa6eb1c17255d5748c54036292080e0e86842536f0d518da011a5bd64bd7f1064702d34985621af6 SHA512 022cbd10d91aa95d21293743dc1c36d4ed2dd3f95e60cab53b0aa3c1be489c7eafbc90c4cc7f6b67011ef4752fedb18c33d64a063542fdc525888b39e127b775
|
||||
DIST urllib3-1.26.14.tar.gz 300665 BLAKE2B d9373c6f88eae86bd74cbc1c20b352064135a5e3686cf594a3fc2375afa881696751a4e318970ce15adb8fadb60e334117e4d4e431eaa591ce7b13b7ce2ab606 SHA512 0a2dffcb4d3b199e1d82c2bb0d8f4e6b57466bdc43e31dbed62b392ef32e021f6d31cb53ebedef9e1a62b1113f7a370e9f0baa36e3fba942a2543473e4df0828
|
||||
|
||||
@@ -0,0 +1,78 @@
|
||||
# Copyright 1999-2023 Gentoo Authors
|
||||
# Distributed under the terms of the GNU General Public License v2
|
||||
|
||||
# please keep this ebuild at EAPI 7 -- sys-apps/portage dep
|
||||
EAPI=7
|
||||
|
||||
DISTUTILS_USE_PEP517=setuptools
|
||||
PYTHON_COMPAT=( python3_{8..11} pypy3 )
|
||||
PYTHON_REQ_USE="ssl(+)"
|
||||
|
||||
inherit distutils-r1
|
||||
|
||||
DESCRIPTION="HTTP library with thread-safe connection pooling, file post, and more"
|
||||
HOMEPAGE="
|
||||
https://github.com/urllib3/urllib3/
|
||||
https://pypi.org/project/urllib3/
|
||||
"
|
||||
SRC_URI="mirror://pypi/${PN:0:1}/${PN}/${P}.tar.gz"
|
||||
|
||||
LICENSE="MIT"
|
||||
SLOT="0"
|
||||
KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~ia64 ~loong ~m68k ~mips ~ppc ~ppc64 ~riscv ~s390 ~sparc ~x86 ~x64-cygwin ~amd64-linux ~ppc-macos ~x64-macos ~sparc-solaris ~sparc64-solaris ~x64-solaris ~x86-solaris"
|
||||
IUSE="brotli test"
|
||||
RESTRICT="!test? ( test )"
|
||||
|
||||
# dev-python/{pyopenssl,cryptography,idna,certifi} are optional runtime
|
||||
# dependencies. Do not add them to RDEPEND. They should be unnecessary with
|
||||
# modern versions of python (>= 3.2).
|
||||
RDEPEND="
|
||||
>=dev-python/PySocks-1.5.8[${PYTHON_USEDEP}]
|
||||
<dev-python/PySocks-2.0[${PYTHON_USEDEP}]
|
||||
dev-python/six[${PYTHON_USEDEP}]
|
||||
brotli? ( dev-python/brotlicffi[${PYTHON_USEDEP}] )
|
||||
"
|
||||
BDEPEND="
|
||||
test? (
|
||||
$(python_gen_cond_dep "
|
||||
${RDEPEND}
|
||||
dev-python/brotlicffi[\${PYTHON_USEDEP}]
|
||||
dev-python/mock[\${PYTHON_USEDEP}]
|
||||
dev-python/pytest[\${PYTHON_USEDEP}]
|
||||
dev-python/pytest-freezegun[\${PYTHON_USEDEP}]
|
||||
>=dev-python/tornado-4.2.1[\${PYTHON_USEDEP}]
|
||||
>=dev-python/trustme-0.5.3[\${PYTHON_USEDEP}]
|
||||
" python3_{8..11})
|
||||
)
|
||||
"
|
||||
|
||||
src_prepare() {
|
||||
distutils-r1_src_prepare
|
||||
|
||||
# unbundle urllib3
|
||||
rm src/urllib3/packages/six.py || die
|
||||
find -name '*.py' -exec sed -i \
|
||||
-e 's:\([.]*\|urllib3\.\)\?packages\.six:six:g' \
|
||||
-e 's:from \([.]*\|urllib3\.\)\?packages import six:import six:g' \
|
||||
{} + || die
|
||||
}
|
||||
|
||||
python_test() {
|
||||
local -x CI=1
|
||||
# FIXME: get tornado ported
|
||||
# please keep in sync with BDEPEND!
|
||||
if ! has "${EPYTHON}" python3.{8..11}; then
|
||||
einfo "Skipping tests on ${EPYTHON}"
|
||||
return
|
||||
fi
|
||||
|
||||
local EPYTEST_DESELECT=(
|
||||
# unstable (relies on warning count)
|
||||
test/with_dummyserver/test_proxy_poolmanager.py::TestHTTPProxyManager::test_proxy_verified_warning
|
||||
)
|
||||
has "${EPYTHON}" python3.{8..10} && EPYTEST_DESELECT+=(
|
||||
test/contrib/test_pyopenssl.py::TestPyOpenSSLHelpers::test_get_subj_alt_name
|
||||
)
|
||||
|
||||
epytest
|
||||
}
|
||||
Reference in New Issue
Block a user