x11-apps/copyq: New package

initial ebuild written by keenblade and Paul Tobias

Gentoo-Bug: https://bugs.gentoo.org/show_bug.cgi?id=499350

Package-Manager: portage-2.2.21
Signed-off-by: Justin Lecher <jlec@gentoo.org>

x11-apps/copyq/Manifest

@@ -0,0 +1 @@
+DIST copyq-2.4.9.tar.gz 1415277 SHA256 0736602eef82bd8ddfb7edb2a4c49b898897f7d25ddc2ae249ed50fd4406a8f4 SHA512 e790b2d7531a3e4eb3b88af720074ba35aedae8ef530ee89c78d798720fcf5668b52f4c7f27ea22828dbfac33dbf22260f69294e3fff587c2d05a36844210421 WHIRLPOOL 0cf03d36a9a7b1f1f62453af30b2301929d0ffc022c7e6290346fe6a9af11cb0a1a7a8128daf10fd73166a9ba4f6c9f2c57899229b1fc404ffe6b81dedfa3b78

x11-apps/copyq/copyq-2.4.9.ebuild

@@ -0,0 +1,51 @@
+# Copyright 1999-2015 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Id$
+
+EAPI=5
+
+inherit cmake-utils multilib
+
+DESCRIPTION="Clipboard manager with advanced features"
+HOMEPAGE="https://github.com/hluk/CopyQ"
+SRC_URI="https://github.com/hluk/CopyQ/archive/v${PV}.tar.gz -> ${P}.tar.gz"
+
+SLOT="0"
+LICENSE="GPL-3"
+KEYWORDS="~amd64 ~x86 ~amd64-linux ~x86-linux"
+IUSE="qt4 +qt5 test webkit"
+
+REQUIRED_USE="|| ( qt4 qt5 )"
+
+RDEPEND="
+	x11-libs/libX11
+	x11-libs/libXfixes
+	x11-libs/libXtst
+	qt4? (
+		dev-qt/qtcore:4=
+		dev-qt/qtgui:4=
+		dev-qt/qtscript:4=
+		webkit? ( dev-qt/qtwebkit:4= )
+	)
+	qt5? (
+		dev-qt/qtcore:5=
+		dev-qt/qtgui:5=
+		dev-qt/qtnetwork:5=
+		dev-qt/qtscript:5=
+		dev-qt/qtwidgets:5=
+		webkit? ( dev-qt/qtwebkit:5= )
+	)
+"
+DEPEND="${RDEPEND}"
+
+S="${WORKDIR}"/CopyQ-${PV}
+
+src_configure() {
+	mycmakeargs=(
+		$(cmake-utils_use_with qt5)
+		$(cmake-utils_use_with webkit)
+		$(cmake-utils_use_with test TESTS)
+		-DPLUGIN_INSTALL_PREFIX=/usr/$(get_libdir)/${PN}/plugins/
+	)
+	cmake-utils_src_configure
+}

x11-apps/copyq/metadata.xml

@@ -0,0 +1,14 @@
+<?xml version="1.0" encoding="UTF-8"?>
+<!DOCTYPE pkgmetadata SYSTEM "http://www.gentoo.org/dtd/metadata.dtd">
+<pkgmetadata>
+	<maintainer>
+		<email>jlec@gentoo.org</email>
+		<name>Justin Lecher</name>
+	</maintainer>
+	<use>
+		<flag name="webkit">
+	enables the application to use advanced HTML rendering and fetching 
+	remote images and other data
+	</flag>
+	</use>
+</pkgmetadata>