dev-python/trimesh: Bump to 3.18.1

Signed-off-by: Michał Górny <mgorny@gentoo.org>

dev-python/trimesh/Manifest

@@ -1,2 +1,3 @@
 DIST trimesh-3.17.1.gh.tar.gz 12653345 BLAKE2B df286132ca01e1a7e8c226b7c98ffa0682b9bf2e225c4114c88395611d1a65a02be4395940ad04b67ae3b6909664b46e18e9fd018d892c86f8f5a4fcfe532210 SHA512 8cbf0bedd21c0867c5aa307e9bb8b4e4caff2aabee89cfadfa11513293304caa4b6a5ecce21064b7fa157a2453b58d401eb6010d0ea32bbd5a99c3075f38b826
 DIST trimesh-3.18.0.gh.tar.gz 12656666 BLAKE2B e183ab1b5ff904b54a7801aaf9e6a3ac24a277107dae03dd37be7a37c56835ac99b617af1c12ea4119c39c3c064d8d1e783ce6effa51ebc0bc65103e688ad363 SHA512 309e1c5dd17a2d1875254a732d96708b98635cbd17ceea80c5386d6ea4675f943e1760f7a4383e9c24ec5711d30ea0732883a691952da1d1079a81a87fcca6cc
+DIST trimesh-3.18.1.gh.tar.gz 12657109 BLAKE2B 8e5370193e7d47f1dc2d7d43c356df1a56c2b4b8af6f47ac6aa889b04a3b950ec507b5cc0fe6f99f874cf66111aa72773025ba3821013466bb34baced3a361ca SHA512 72936c0fc6f89ffa35b80928dc5abac8ca4fac023f5be1d4adec6d020f3da6ee2c7a97efb0cecf58faad94ef6f33949533ac789affcecee07696ca0188fd47f0

dev-python/trimesh/trimesh-3.18.1.ebuild

@@ -0,0 +1,77 @@
+# Copyright 1999-2023 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_USE_PEP517=setuptools
+PYTHON_COMPAT=( python3_{9..10} )
+
+inherit distutils-r1 multiprocessing optfeature
+
+DESCRIPTION="Python library for loading and using triangular meshes"
+HOMEPAGE="
+	https://trimsh.org/
+	https://github.com/mikedh/trimesh/
+	https://pypi.org/project/trimesh/
+"
+SRC_URI="
+	https://github.com/mikedh/${PN}/archive/${PV}.tar.gz
+		-> ${P}.gh.tar.gz
+"
+
+LICENSE="MIT"
+SLOT="0"
+KEYWORDS="~amd64 ~arm64 ~x86"
+
+RDEPEND="
+	dev-python/chardet[${PYTHON_USEDEP}]
+	dev-python/colorlog[${PYTHON_USEDEP}]
+	dev-python/jsonschema[${PYTHON_USEDEP}]
+	dev-python/lxml[${PYTHON_USEDEP}]
+	dev-python/msgpack[${PYTHON_USEDEP}]
+	dev-python/networkx[${PYTHON_USEDEP}]
+	dev-python/numpy[${PYTHON_USEDEP}]
+	dev-python/pillow[${PYTHON_USEDEP}]
+	dev-python/pycollada[${PYTHON_USEDEP}]
+	<dev-python/pyglet-2[${PYTHON_USEDEP}]
+	dev-python/requests[${PYTHON_USEDEP}]
+	dev-python/scipy[${PYTHON_USEDEP}]
+	dev-python/setuptools[${PYTHON_USEDEP}]
+	>=dev-python/shapely-1.8.2[${PYTHON_USEDEP}]
+	dev-python/svg-path[${PYTHON_USEDEP}]
+	dev-python/sympy[${PYTHON_USEDEP}]
+	dev-python/xxhash[${PYTHON_USEDEP}]
+	sci-libs/rtree[${PYTHON_USEDEP}]
+"
+BDEPEND="
+	test? (
+		dev-python/pytest-xdist[${PYTHON_USEDEP}]
+		dev-python/mapbox_earcut[${PYTHON_USEDEP}]
+	)
+"
+
+distutils_enable_tests pytest
+
+src_prepare() {
+	# remove pyinstrument from tests, as only used for profiling
+	sed -e '/pyinstrument/d' -i tests/{regression,corpus,generic}.py || die
+
+	distutils-r1_src_prepare
+}
+
+python_test() {
+	local EPYTEST_DESELECT=(
+		# does profiling with pyinstrument
+		tests/test_scenegraph.py::GraphTests::test_shortest_path
+	)
+	epytest -n "$(makeopts_jobs)"
+}
+
+pkg_postinst() {
+	optfeature_header "${PN} functionality can be extended by installing the following packages:"
+	optfeature "making GUI applications with 3D stuff" dev-python/glooey
+	optfeature "2D triangulations of polygons" dev-python/mapbox_earcut
+	optfeature "loading a number of additional mesh formats" dev-python/meshio
+	optfeature "figuring out how much memory we have" dev-python/psutil
+	optfeature "marching cubes and other nice stuff" sci-libs/scikit-image
+}