net-im/gajim: add 1.9.3

Signed-off-by: Jonas Stein <jstein@gentoo.org>

net-im/gajim/Manifest

@@ -2,3 +2,4 @@ DIST gajim-1.7.3.tar.gz 3753831 BLAKE2B c7b8b1dc47b1faf9f1c0803e7931cb00bfbf3107
 DIST gajim-1.8.0.tar.gz 3835799 BLAKE2B 030293fc8114877c6d060cd0feae0fecdcecbb26aac8817e1db7db59aee3ee79973efc94584434641ccd39adcf809e0c7a86a017ab46c9695666d898fb7b7905 SHA512 724290de6d438aacd929a9759d7a712068c303caf9002a1a70ddc0e9aa16387054d3e4efacf84eced28f49ef79749c764d5fe67fcb23c3baef3a2b7714df218e
 DIST gajim-1.8.1.tar.gz 3844796 BLAKE2B b7bbd751a051cd2a46e814a9b3ebc08f10a6570dc071752838a2463019cdf6ea4198f2a349f3935c33d988cd6908cf31dba572bac31f9363675433328e6d679b SHA512 b417d76a4225f16730441dee7befacd6db5be782c9271b789d5f9c10232e342f2d46930eef79a58839c13b2887926591d953a87a7544e32c7bf80d2c65390e31
 DIST gajim-1.8.4.tar.gz 3710470 BLAKE2B e23eafe707bc482a050fcef44df9e68af552444cce173c506538ebe01557a894dc0ba8b9afe18f195fd0b00b717b1268531a960b1c8b868c22081135d14e3079 SHA512 1a5b028c0e308eb15417c8c11584bc0e8b0218fead5155093ede4bc3961b6bee2b47bc3510f751dc70194634d6ca94d4a675f6891c8f050859fb4729020e52cb
+DIST gajim-1.9.3.tar.gz 3803265 BLAKE2B 44c6985728871b82fd86aa8a5e066123cd10a0f990dffcbdc6099333caec95af4f78eecdf49af062aa5bad293d819ea7e0811e2cd1906eb81630b9fd94f0c3f7 SHA512 d7815ad77afb3ea1e7b1cdf6baa4ed1acaaed857da4a0ca1db57200dc3fc7103e4110ee8b7e2918838f86c9250226a6c8b98be6cd0915ea29eaf5e1a2830688a

net-im/gajim/gajim-1.9.3.ebuild

@@ -0,0 +1,107 @@
+# Copyright 1999-2024 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+PYTHON_COMPAT=( python3_{10..12} )
+PYTHON_REQ_USE="sqlite,xml(+)"
+DISTUTILS_USE_PEP517=standalone
+DISTUTILS_SINGLE_IMPL=1
+
+inherit distutils-r1 xdg-utils
+
+DESCRIPTION="XMPP client written in PyGTK"
+HOMEPAGE="https://gajim.org/"
+SRC_URI="https://gajim.org/downloads/$(ver_cut 1-2)/${P/_p/-}.tar.gz"
+
+LICENSE="GPL-3"
+SLOT="0"
+
+# Rekeyword for ~long, ~x86 and ~riscv, when https://bugs.gentoo.org/937582 is fixed.
+# KEYWORDS="~amd64 ~arm64 ~loong ~riscv ~x86"
+KEYWORDS="~amd64 ~arm64"
+IUSE="+crypt geolocation jingle remote rst +spell upnp +webp"
+
+COMMON_DEPEND="
+	dev-libs/gobject-introspection[cairo(+)]
+	>=x11-libs/gtk+-3.24.30:3[introspection]
+	x11-libs/gtksourceview:4[introspection]"
+DEPEND="${COMMON_DEPEND}
+	app-arch/unzip
+	virtual/pkgconfig
+	>=x11-libs/pango-1.50.0
+	>=sys-devel/gettext-0.17-r1"
+RDEPEND="${COMMON_DEPEND}
+	$(python_gen_cond_dep '
+		dev-python/idna[${PYTHON_USEDEP}]
+		>=dev-python/nbxmpp-5.0.1[${PYTHON_USEDEP}]
+		dev-python/precis-i18n[${PYTHON_USEDEP}]
+		dev-python/pyasn1[${PYTHON_USEDEP}]
+		dev-python/pycairo[${PYTHON_USEDEP}]
+		dev-python/pycurl[${PYTHON_USEDEP}]
+		dev-python/pygobject:3[cairo,${PYTHON_USEDEP}]
+		x11-libs/libXScrnSaver
+		app-crypt/libsecret[crypt,introspection]
+		dev-python/keyring[${PYTHON_USEDEP}]
+		>=dev-python/secretstorage-3.1.1[${PYTHON_USEDEP}]
+		dev-python/css-parser[${PYTHON_USEDEP}]
+		dev-python/packaging[${PYTHON_USEDEP}]
+		net-libs/libsoup:3.0[introspection]
+		media-libs/gsound[introspection]
+		dev-python/pillow[${PYTHON_USEDEP}]
+		dev-python/jaraco-classes[${PYTHON_USEDEP}]
+		dev-python/python-axolotl[${PYTHON_USEDEP}]
+		dev-python/sqlalchemy[${PYTHON_USEDEP}]
+		dev-python/emoji[${PYTHON_USEDEP}]
+		dev-python/qrcode[${PYTHON_USEDEP}]
+		dev-python/cryptography[${PYTHON_USEDEP}]
+		dev-python/omemo-dr[${PYTHON_USEDEP}]
+		crypt? (
+			dev-python/pycryptodome[${PYTHON_USEDEP}]
+			>=dev-python/python-gnupg-0.4.0[${PYTHON_USEDEP}] )
+		geolocation? ( app-misc/geoclue[introspection] )
+		jingle? (
+			net-libs/farstream:0.2[introspection]
+			media-libs/gstreamer:1.0[introspection]
+			media-libs/gst-plugins-base:1.0[introspection]
+			media-libs/gst-plugins-ugly:1.0
+			media-plugins/gst-plugins-gtk
+		)
+		remote? (
+			>=dev-python/dbus-python-1.2.0[${PYTHON_USEDEP}]
+			sys-apps/dbus[X]
+		)
+		rst? ( dev-python/docutils[${PYTHON_USEDEP}] )
+		spell? (
+			app-text/gspell[introspection]
+			app-text/hunspell
+		)
+		upnp? ( net-libs/gupnp-igd:0[introspection] )
+	')"
+
+python_compile() {
+	distutils-r1_python_compile
+	./pep517build/build_metadata.py -o dist/metadata
+}
+
+python_install() {
+	distutils-r1_python_install
+	./pep517build/install_metadata.py dist/metadata --prefix="${D}/usr"
+
+	gzip -d "${ED}"/usr/share/man/man1/*.gz || die
+}
+
+pkg_postinst() {
+	ewarn "The chat database format changes when upgrading from 1.8.x to 1.9.x."
+	ewarn "The first time the user starts Gajim, an automatic migration is performed."
+	xdg_icon_cache_update
+	xdg_desktop_database_update
+}
+
+pkg_postrm() {
+	xdg_icon_cache_update
+	xdg_desktop_database_update
+}
+
+# Tests are unfortunately regularly broken
+RESTRICT="test"