sci-libs/ceres-solver: 1.14.0 version bump, EAPI-7 bump, cmake.eclass

fix doc install path python3_7 + python3_8 Closes: https://bugs.gentoo.org/700294 Package-Manager: Portage-2.3.94, Repoman-2.3.21 Signed-off-by: Andreas Sturmlechner <asturm@gentoo.org>
2026-09-24 04:59:14 -07:00 · 2020-03-19 14:01:24 +01:00
parent 3db3b24b75
commit bc28470c9c
2 changed files with 101 additions and 0 deletions
--- a/sci-libs/ceres-solver/Manifest
+++ b/sci-libs/ceres-solver/Manifest
@@ -1 +1,2 @@
 DIST ceres-solver-1.12.0.tar.gz 5008861 BLAKE2B 52b3954dde96386bd031543ab9d7370368f58f76f1dec9d24ef10803da787cc96f40a1c775626fde832b70ebd94cf4274c70a8fb4bd7e1bcf040e119cbec09f8 SHA512 485eece0471cf05d31b5dd7e133e23115a334a4ed557a3c1bd0b715a063f840738af8f507e935522a0dae90ce6851984c0002a25e9b445b90889792f68a05571
+DIST ceres-solver-1.14.0.tar.gz 5450130 BLAKE2B cfcfe07cecb267528081dfc6deb5283bc5a04b79d4595e45365960895b84a6dca2a3024b046868f06709fc81e8514730cbc409ab01cb0cbee488b5bad5b9f7cc SHA512 a2af9918d2730709361ec971431a2b22e6ca3ca440081be87fa52729ec43702020b021837bfe5a42a58db1ab89ea6aada11f2d1888da66bef614ec1f27ab30c6
--- a/sci-libs/ceres-solver/ceres-solver-1.14.0.ebuild
+++ b/sci-libs/ceres-solver/ceres-solver-1.14.0.ebuild
@@ -0,0 +1,100 @@
+# Copyright 1999-2020 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+CMAKE_ECLASS=cmake
+PYTHON_COMPAT=( python3_{6,7,8} )
+inherit cmake-multilib python-any-r1 toolchain-funcs
+
+DESCRIPTION="Nonlinear least-squares minimizer"
+HOMEPAGE="http://ceres-solver.org/"
+SRC_URI="http://ceres-solver.org/${P}.tar.gz"
+
+LICENSE="sparse? ( BSD ) !sparse? ( LGPL-2.1 ) cxsparse? ( BSD )"
+SLOT="0/1"
+KEYWORDS="~amd64 ~x86 ~amd64-linux ~x86-linux"
+IUSE="cxsparse c++11 doc examples gflags lapack openmp +schur sparse test"
+
+REQUIRED_USE="test? ( gflags ) sparse? ( lapack ) abi_x86_32? ( !sparse !lapack )"
+
+RESTRICT="!test? ( test )"
+
+BDEPEND="${PYTHON_DEPS}
+	>=dev-cpp/eigen-3.3.4:3
+	doc? (
+		dev-python/sphinx
+		dev-python/sphinx_rtd_theme
+	)
+	lapack? ( virtual/pkgconfig )
+"
+RDEPEND="
+	dev-cpp/glog[gflags?,${MULTILIB_USEDEP}]
+	cxsparse? ( sci-libs/cxsparse:0= )
+	lapack? ( virtual/lapack )
+	sparse? (
+		sci-libs/amd:0=
+		sci-libs/camd:0=
+		sci-libs/ccolamd:0=
+		sci-libs/cholmod:0=[metis]
+		sci-libs/colamd:0=
+		sci-libs/spqr:0=
+	)
+"
+DEPEND="${RDEPEND}"
+
+DOCS=( README.md VERSION )
+
+pkg_pretend() {
+	if [[ ${MERGE_TYPE} != binary ]] && use openmp; then
+		if [[ $(tc-getCXX) == *g++* ]] && ! tc-has-openmp; then
+			ewarn "OpenMP is not available in your current selected gcc"
+			die "need openmp capable gcc"
+		fi
+	fi
+}
+
+pkg_setup() {
+	use doc && python-any-r1_pkg_setup
+}
+
+src_prepare() {
+	cmake_src_prepare
+
+	# search paths work for prefix
+	sed -e "s:/usr:${EPREFIX}/usr:g" \
+		-i cmake/*.cmake || die
+
+	# remove Werror
+	sed -e 's/-Werror=(all|extra)//g' \
+		-i CMakeLists.txt || die
+}
+
+src_configure() {
+	# CUSTOM_BLAS=OFF EIGENSPARSE=OFF MINIGLOG=OFF CXX11=OFF
+	local mycmakeargs=(
+		-DBUILD_BENCHMARKS=OFF
+		-DBUILD_EXAMPLES=OFF
+		-DBUILD_TESTING=$(usex test)
+		-DCXX11=$(usex c++11)
+		-DBUILD_DOCUMENTATION=$(usex doc)
+		-DCERES_DOCS_INSTALL_DIR="${EPREFIX}"/usr/share/doc/${PF}
+		-DGFLAGS=$(usex gflags)
+		-DLAPACK=$(usex lapack)
+		-DOPENMP=$(usex openmp)
+		-DSCHUR_SPECIALIZATIONS=$(usex schur)
+		-DCXSPARSE=$(usex cxsparse)
+		-DSUITESPARSE=$(usex sparse)
+	)
+	use sparse || use cxsparse || mycmakeargs+=( -DEIGENSPARSE=ON )
+	cmake-multilib_src_configure
+}
+
+src_install() {
+	cmake-multilib_src_install
+
+	if use examples; then
+		docompress -x /usr/share/doc/${PF}/examples
+		dodoc -r examples data
+	fi
+}