dev-python/notebook: bump to 6.2.0

Package-Manager: Portage-3.0.12, Repoman-3.0.2
Signed-off-by: Sam James <sam@gentoo.org>

dev-python/notebook/Manifest

@@ -1,3 +1,4 @@
 DIST notebook-6.1.3.tar.gz 13806042 BLAKE2B da63fdabd1a71e4247a9e340539e688410a84c58d94049dfb7e8e3fcdc53686a55eb855687df34ff48f599a0c5aececbd9a8e1aa1d2ff7baa2a6da1b4e1bcf24 SHA512 67a8feb01dfb665bb24f3ce1b28212e9bad5a188e8cef1d168c4edaf207cbc16d516f6024ca905f75f1c27ba4890da858c5278a3ee84a4c4ac1bdbf225afa351
 DIST notebook-6.1.5.tar.gz 13925632 BLAKE2B ce9d0ee110a158ba0ee3f3199a7cc1c8d53ecb72e8f77f43d2b1e5552b4a0378edca9a987634e12d8429c70595ec4cc226784248d196501b3a04c67e4ba88c85 SHA512 4b0893c805a0494c369b363b7d1c606a1b124869e601eafce1eb4c93ad1436b757c6149bc76c489aa26171412280d69e894b44d7d19141341fb1194a8e2f447b
 DIST notebook-6.1.6.tar.gz 13926673 BLAKE2B 944f92d468ade0f0d3fbe01d46cb2893866fca067b48c6a6cefe653b9941bbde0802c7d9ee17b493bcf6391d1b0a77e710f5b5c8f1d58ec692b40753ac0692e9 SHA512 d1271273ae9cc098d5937a3ac91dc8035b033bb8da799f31c5d71abe48b17579f2fadc8b0ff7134dedda72ac49cc29c5adafaa4ef6f347cc4f6698ab46d83040
+DIST notebook-6.2.0.tar.gz 13927515 BLAKE2B ca752f0cb316b46b71d8451c59c196c324008c296dfc7fbc4ee426ba5b3c1035e90170e46720547a9e3f2cf381ab5e0294185ee1a814d31ffbe6ecf546f229d6 SHA512 217392000ca2d0266137f937fc4d2a1b81ed19217fdbf6550b07453eede8b9a6e15c8fbb1c94f559a7f44ac73dfadcefeae815c186e56bb1e9a30120fe070f3a

dev-python/notebook/notebook-6.2.0.ebuild

@@ -0,0 +1,85 @@
+# Copyright 1999-2021 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+DISTUTILS_USE_SETUPTOOLS=rdepend
+PYTHON_COMPAT=( python3_{7..9} )
+PYTHON_REQ_USE="threads(+)"
+
+inherit distutils-r1
+
+DESCRIPTION="Jupyter Interactive Notebook"
+HOMEPAGE="https://jupyter.org"
+SRC_URI="mirror://pypi/${PN:0:1}/${PN}/${P}.tar.gz"
+
+LICENSE="BSD"
+SLOT="0"
+KEYWORDS="~amd64 ~arm64 ~x86"
+
+RDEPEND="
+	>=dev-libs/mathjax-2.4
+	dev-python/argon2-cffi[${PYTHON_USEDEP}]
+	dev-python/jinja[${PYTHON_USEDEP}]
+	>=dev-python/terminado-0.8.3[${PYTHON_USEDEP}]
+	>=www-servers/tornado-6.0[${PYTHON_USEDEP}]
+	dev-python/ipython_genutils[${PYTHON_USEDEP}]
+	>=dev-python/traitlets-4.2.1[${PYTHON_USEDEP}]
+	>=dev-python/jupyter_core-4.6.1[${PYTHON_USEDEP}]
+	>=dev-python/pyzmq-17[${PYTHON_USEDEP}]
+	>=dev-python/jupyter_client-5.3.4[${PYTHON_USEDEP}]
+	dev-python/nbformat[${PYTHON_USEDEP}]
+	>=dev-python/nbconvert-4.2.0[${PYTHON_USEDEP}]
+	dev-python/ipykernel[${PYTHON_USEDEP}]
+	dev-python/send2trash[${PYTHON_USEDEP}]
+	dev-python/prometheus_client[${PYTHON_USEDEP}]"
+
+# sphinx 2+ seems to have a problem with its github plugin. temporarily adding
+# a version constraint.
+BDEPEND="
+	test? (
+		dev-python/requests[${PYTHON_USEDEP}]
+		dev-python/requests-unixsocket[${PYTHON_USEDEP}]
+	)
+"
+
+PATCHES=(
+	"${FILESDIR}/${PN}"-5.7.0-no-mathjax.patch
+)
+
+distutils_enable_tests --install pytest
+
+python_prepare_all() {
+	# disable bundled mathjax
+	sed -i 's/^.*MathJax.*$//' bower.json || die
+
+	# require geckodriver
+	rm -r notebook/tests/selenium || die
+	# trash doesn't seem to work for us
+	sed -e 's:test_delete:_&:' \
+		-i notebook/services/contents/tests/test_manager.py || die
+	sed -e 's:test_checkpoints_follow_file:_&:' \
+		-e 's:test_delete:_&:' \
+		-i notebook/services/contents/tests/test_contents_api.py || die
+	# network-sandbox?
+	sed -e 's:test_connections:_&:' \
+		-e 's:test_culling:_&:' \
+		-i notebook/services/kernels/tests/test_kernels_api.py || die
+
+	sed -i -e "/'bdist_egg':/d" setup.py || die
+
+	distutils-r1_python_prepare_all
+}
+
+python_install() {
+	distutils-r1_python_install
+
+	ln -sf \
+		"${EPREFIX}/usr/share/mathjax" \
+		"${D}$(python_get_sitedir)/notebook/static/components/MathJax" || die
+}
+
+pkg_preinst() {
+	# remove old mathjax folder if present
+	rm -rf "${EROOT}"/usr/lib*/python*/site-packages/notebook/static/components/MathJax || die
+}