dev-python/trimesh: Bump to 4.6.12

Signed-off-by: Michał Górny <mgorny@gentoo.org>

dev-python/trimesh/Manifest

@@ -1,2 +1,3 @@
 DIST trimesh-4.6.10.gh.tar.gz 13636665 BLAKE2B 1362e7db082cd107d801314ece352f61beb704f3b53f0a33daf2b3ebb86cf670209769504e4dcc5f258d80fb7da3a6b20509589e2d7a8ff83b9f892c9ddc0193 SHA512 27e3bdc32a5ff9fe2c9a0b989487815817811db196d1be6d6356a25a23ae39cf13a069318146dfb2c722ac175beeb68b69a12dfcea3689b70f6e376f5ecfd608
 DIST trimesh-4.6.11.gh.tar.gz 13637301 BLAKE2B fc672641ec363794ff90aa1daaa4711838917395771de55376981af1a2bab1dcb58e8240fd23d9c6d17187ed952994927b4896792a0cf1d632eaf88d0ca3808c SHA512 7c1039a845a461b450d5dda54da287a7f35e8ffbe544ee4e920dcb7053a30791796f239d00337f1cb443c3df610bdc2faa6a93e7240c2c494ab6c6ef9d563b96
+DIST trimesh-4.6.12.gh.tar.gz 13637824 BLAKE2B f1dbc1c7963284d4560847872290d09096673cccefce62758bbea9d055c933aff15eced6a279fba88a8b0489a16df6c9e7211a7977488eb719696d465a6ca8f5 SHA512 01f4f0d3b8b1c7621dc19f2e541d68337298133d331b5950a786a0e07bf0fbbeb10777887ce6b49134c670e3d1bd56fcdbc1f08e7d1eb79527e91b6e9b5b01d9

dev-python/trimesh/trimesh-4.6.12.ebuild

@@ -0,0 +1,79 @@
+# Copyright 1999-2025 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_USE_PEP517=setuptools
+PYTHON_COMPAT=( python3_{11..13} )
+
+inherit distutils-r1 optfeature
+
+DESCRIPTION="Python library for loading and using triangular meshes"
+HOMEPAGE="
+	https://trimesh.org/
+	https://github.com/mikedh/trimesh/
+	https://pypi.org/project/trimesh/
+"
+SRC_URI="
+	https://github.com/mikedh/${PN}/archive/${PV}.tar.gz
+		-> ${P}.gh.tar.gz
+"
+
+LICENSE="MIT"
+SLOT="0"
+KEYWORDS="~amd64 ~arm64 ~x86"
+
+RDEPEND="
+	dev-python/charset-normalizer[${PYTHON_USEDEP}]
+	dev-python/colorlog[${PYTHON_USEDEP}]
+	dev-python/httpx[${PYTHON_USEDEP}]
+	dev-python/jsonschema[${PYTHON_USEDEP}]
+	dev-python/lxml[${PYTHON_USEDEP}]
+	dev-python/networkx[${PYTHON_USEDEP}]
+	>=dev-python/numpy-1.20[${PYTHON_USEDEP}]
+	dev-python/pillow[${PYTHON_USEDEP}]
+	dev-python/pycollada[${PYTHON_USEDEP}]
+	dev-python/pyglet[${PYTHON_USEDEP}]
+	dev-python/requests[${PYTHON_USEDEP}]
+	dev-python/scipy[${PYTHON_USEDEP}]
+	>=dev-python/shapely-1.8.2[${PYTHON_USEDEP}]
+	dev-python/svg-path[${PYTHON_USEDEP}]
+	dev-python/sympy[${PYTHON_USEDEP}]
+	dev-python/xxhash[${PYTHON_USEDEP}]
+	dev-python/rtree[${PYTHON_USEDEP}]
+"
+BDEPEND="
+	test? (
+		dev-python/mapbox-earcut[${PYTHON_USEDEP}]
+		dev-python/pillow[webp,${PYTHON_USEDEP}]
+	)
+"
+
+EPYTEST_TIMEOUT=1800
+EPYTEST_XDIST=1
+distutils_enable_tests pytest
+
+python_test() {
+	local EPYTEST_DESELECT=(
+		# requires manifold3d
+		tests/test_boolean.py::test_multiple_difference
+		# timing nonsense
+		tests/test_bounds.py::BoundsTest::test_obb_mesh_large
+	)
+	local EPYTEST_IGNORE=(
+		# require pyinstrument
+		tests/test_sweep.py
+	)
+
+	local -x PYTEST_DISABLE_PLUGIN_AUTOLOAD=1
+	epytest
+}
+
+pkg_postinst() {
+	optfeature_header "${PN} functionality can be extended by installing the following packages:"
+	optfeature "making GUI applications with 3D stuff" dev-python/glooey
+	optfeature "2D triangulations of polygons" dev-python/mapbox-earcut
+	optfeature "loading a number of additional mesh formats" dev-python/meshio
+	optfeature "figuring out how much memory we have" dev-python/psutil
+	optfeature "marching cubes and other nice stuff" dev-python/scikit-image
+}