gnome-base/gnome-desktop: Version bump to 40.2

Signed-off-by: Matt Turner <mattst88@gentoo.org>
2026-11-06 17:47:07 -08:00 · 2021-06-09 15:44:40 -07:00
parent a5da849d92
commit bbdbbebfa7
2 changed files with 73 additions and 0 deletions
@@ -1 +1,2 @@
 DIST gnome-desktop-40.1.tar.xz 721416 BLAKE2B de1432a9ee61fa0545ce09c1228a133555d732ea58b9550a1f218726342d4c4e1c9d30f402b62a6a370cd281302c47f820f8bccbd69f8b8651f77e4b0e8d4f66 SHA512 ff9da5d0c805a7d42339a9174b907dd0cc4845c8eeb5a004a13f001dbe449f28a6360ed9dc1951376be4a48271908990052ca0e8d6e4339214cafcb80d204b57
+DIST gnome-desktop-40.2.tar.xz 721852 BLAKE2B a7258d0465b17c5c9c78a066acd72571c002054f196d847e07b10055b1d72900d6efc80ac623f118ff11a87a4d5042ac9902f7f3f9d5a181ad3d80429cf9f904 SHA512 2fd3ba5eb0263aecc43978d84070619c16af4de998b344bc2aaac16aa0e734d93235aa218c2684ad993b471136434b97dffae52f183798daaa4ec47574cc51b3
@@ -0,0 +1,72 @@
+# Copyright 1999-2021 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+inherit gnome.org gnome2-utils meson xdg
+
+DESCRIPTION="Library with common API for various GNOME modules"
+HOMEPAGE="https://gitlab.gnome.org/GNOME/gnome-desktop/"
+
+LICENSE="GPL-2+ LGPL-2+ FDL-1.1+"
+SLOT="3/19" # subslot = libgnome-desktop-3 soname version
+IUSE="debug gtk-doc +introspection seccomp systemd udev"
+KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~ia64 ~ppc ~ppc64 ~sparc ~x86 ~amd64-linux ~x86-linux ~x86-solaris"
+
+COMMON_DEPEND="
+	>=x11-libs/gdk-pixbuf-2.36.5:2[introspection?]
+	>=x11-libs/gtk+-3.3.6:3[X,introspection?]
+	>=dev-libs/glib-2.53.0:2
+	>=gnome-base/gsettings-desktop-schemas-3.27.0[introspection?]
+	x11-misc/xkeyboard-config
+	x11-libs/libxkbcommon
+	app-text/iso-codes
+	systemd? ( sys-apps/systemd:= )
+	udev? (
+		sys-apps/hwids
+		virtual/libudev:= )
+	seccomp? ( sys-libs/libseccomp )
+
+	x11-libs/cairo:=
+	introspection? ( >=dev-libs/gobject-introspection-1.54:= )
+"
+DEPEND="${COMMON_DEPEND}
+	media-libs/fontconfig
+"
+RDEPEND="${COMMON_DEPEND}
+	seccomp? ( sys-apps/bubblewrap )
+"
+BDEPEND="
+	app-text/docbook-xml-dtd:4.1.2
+	dev-util/gdbus-codegen
+	gtk-doc? ( >=dev-util/gtk-doc-1.14 )
+	dev-util/itstool
+	>=sys-devel/gettext-0.19.8
+	x11-base/xorg-proto
+	virtual/pkgconfig
+"
+# Includes X11/Xatom.h in libgnome-desktop/gnome-bg.c which comes from xorg-proto
+
+PATCHES=(
+	"${FILESDIR}"/3.32.2-optional-introspection.patch # add introspection meson option
+)
+
+src_prepare() {
+	# Don't build manual test programs that will never get run
+	sed -i -e "/'test-.*'/d" libgnome-desktop/meson.build || die
+	xdg_src_prepare
+}
+
+src_configure() {
+	local emesonargs=(
+		-Dgnome_distributor=Gentoo
+		-Ddate_in_gnome_version=true
+		-Ddesktop_docs=true
+		$(meson_use debug debug_tools)
+		$(meson_use introspection)
+		$(meson_feature udev)
+		$(meson_feature systemd)
+		$(meson_use gtk-doc gtk_doc)
+		-Dinstalled_tests=false
+	)
+	meson_src_configure
+}