dev-libs/libinput: Bump to version 1.15.3

Package-Manager: Portage-2.3.92, Repoman-2.3.20
Signed-off-by: Lars Wendler <polynomial-c@gentoo.org>

dev-libs/libinput/Manifest

@@ -1,3 +1,4 @@
 DIST libinput-1.14.3.tar.xz 567560 BLAKE2B 76d38b795a5e721a73062e9c37b23bf6739291549cadc66401ef47b1a9afd5766f1d0ed855fc66912e4257fae4b1b813946c67246adb8d8566d5ad9478079636 SHA512 f01d1bd1b25b8060519575644597d35f0c89de5386d298441f440128ceee3e57549921a058adec31adc8b33dbdedf4c0bd12c76905a69f752859d3136e26336d
 DIST libinput-1.15.1.tar.xz 579236 BLAKE2B 0b0b8cd6643ef33c1fc52461caea332d98cee38b79eee3947fc3d853e6a9402ffc9ba2ac5588430c28c73b6444fa06f6743b0c932077ef29e97d0b1384e20fca SHA512 634810359bc4d86f2c4c75f472bee5eaed04ed93af3c91c4bc46a596402323941f9cc90173e278bfa7e5cbda6b7a20adc59bd09520dd4152fc961302b7e57904
 DIST libinput-1.15.2.tar.xz 580624 BLAKE2B a13bf121b12c58d904f3505fe2fa60ea32eee78a057ac1fe9e64d3017fa840bb92af053f472d2b163d46a958f2a3a5039154efbb9558eddabda3b2422cafb2ca SHA512 f6b50dbdf6ee6b65f88e020c4292c94c3178125d58629f27c2e52f92b658ccd67e0c5604fbf0b303621ff0386637ce1e291daaa991761d4145e8bcda4dd128a2
+DIST libinput-1.15.3.tar.xz 580408 BLAKE2B d5d462f81303e408f295fbc958609363ec9e3f4eb20494aa8fa977a458283619f321309f88167c70069ac7bd07dc782d948e9a75583ae6e930524f63dad5cafe SHA512 6636fd618e2b9cfa5ee44701207dc98f2639adc53eb3ef135509d936fb19b2cedf5184eab58e887798d9cf8ee65f35bc9062f7e3630080bcbe45a90a8b631ef2

dev-libs/libinput/libinput-1.15.3.ebuild

@@ -0,0 +1,79 @@
+# Copyright 2014-2020 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+PYTHON_COMPAT=( python3_{6,7} )
+
+inherit meson python-any-r1 udev
+
+DESCRIPTION="Library to handle input devices in Wayland"
+HOMEPAGE="https://www.freedesktop.org/wiki/Software/libinput/ https://gitlab.freedesktop.org/libinput/libinput"
+SRC_URI="https://www.freedesktop.org/software/${PN}/${P}.tar.xz"
+
+LICENSE="MIT"
+SLOT="0/10"
+[[ "$(ver_cut 3)" -gt 900 ]] || \
+KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~ia64 ~ppc ~ppc64 ~s390 ~sparc ~x86"
+IUSE="doc input_devices_wacom"
+# Tests require write access to udev rules directory which is a no-no for live system.
+# Other tests are just about logs, exported symbols and autotest of the test library.
+RESTRICT="test"
+
+BDEPEND="
+	virtual/pkgconfig
+	doc? (
+		$(python_gen_any_dep '
+			dev-python/commonmark[${PYTHON_USEDEP}]
+			dev-python/recommonmark[${PYTHON_USEDEP}]
+			dev-python/sphinx[${PYTHON_USEDEP}]
+			>=dev-python/sphinx_rtd_theme-0.2.4[${PYTHON_USEDEP}]
+		')
+		>=app-doc/doxygen-1.8.3
+		>=media-gfx/graphviz-2.38.0
+	)
+"
+#	test? ( dev-util/valgrind )
+RDEPEND="
+	input_devices_wacom? ( >=dev-libs/libwacom-0.20 )
+	>=dev-libs/libevdev-1.3
+	>=sys-libs/mtdev-1.1
+	virtual/libudev:=
+	virtual/udev
+"
+DEPEND="${RDEPEND}"
+#	test? ( >=dev-libs/check-0.9.10 )
+
+python_check_deps() {
+	has_version "dev-python/commonmark[${PYTHON_USEDEP}]" && \
+	has_version "dev-python/recommonmark[${PYTHON_USEDEP}]" && \
+	has_version "dev-python/sphinx[${PYTHON_USEDEP}]" && \
+	has_version ">=dev-python/sphinx_rtd_theme-0.2.4[${PYTHON_USEDEP}]"
+}
+
+pkg_setup() {
+	use doc && python-any-r1_pkg_setup
+}
+
+src_configure() {
+	# gui can be built but will not be installed
+	local emesonargs=(
+		-Ddebug-gui=false
+		$(meson_use doc documentation)
+		$(meson_use input_devices_wacom libwacom)
+		-Dtests=false # tests are restricted
+		-Dudev-dir="${EPREFIX}$(get_udevdir)"
+	)
+	meson_src_configure
+}
+
+src_install() {
+	meson_src_install
+	if use doc ; then
+		docinto html
+		dodoc -r "${BUILD_DIR}"/Documentation/.
+	fi
+}
+
+pkg_postinst() {
+	udevadm hwdb --update --root="${ROOT}"
+}