gentoo-mirror/gentoo
1
0
Fork 0
mirror of https://github.com/gentoo-mirror/gentoo.git synced 2026-09-24 04:59:14 -07:00
Code Issues Projects Releases Wiki Activity

dev-python/ipykernel: Bump to 6.20.2

Browse Source 
Signed-off-by: Michał Górny <mgorny@gentoo.org>
This commit is contained in:
Michał Górny
2023-01-17 05:34:11 +01:00
parent bb55c7a0b7
commit bbca6f4f00
2 changed files with 76 additions and 0 deletions
Download Patch File Download Diff File Expand all files Collapse all files

1
dev-python/ipykernel/Manifest
View File

@@ -2,3 +2,4 @@ DIST ipykernel-6.19.2.tar.gz 143367 BLAKE2B f6f38f5eed3a11951d303f49c58131d94730
DIST ipykernel-6.19.3.tar.gz 143840 BLAKE2B 9736d1ae2a2ef3c807bcea78aafc4ca2e3813693bddf9eac82425aed78382c36d736d5b4351989d9fdf3343335c503fef92f76ebff5a313e5af222aa78a04a04 SHA512 5c37e60ee353e469c0d7fce20a66d8e71dc57120ace6d518ed98816280c794ffafe8e8226545d978fc822760b5874371eafcb20cb7195328e505073eb70b4f06
DIST ipykernel-6.19.4.tar.gz 144072 BLAKE2B 25e2031a9198079488ef43b9c65e656be720ec8ac6648cb3eb65705be5c117d32c783776c0d8f5da466e745979ccb64573720146c0b41835ecb646bf25e7d4f8 SHA512 623a8cac7abfce0147a08fe55bf88772bfaf317431a608a99ae3e7058ebb120464d751a8b95633ccde5201b4cc2c1bde32dd823add96e5f2bb1ef20da19652dd
DIST ipykernel-6.20.1.tar.gz 149147 BLAKE2B 9d05f1f43aa1a77dd63fac60fdd44d56dd03cc8b5025a99b29e04e30ca90ec5e6d541ab86c9fa1490b97b198e829058d14273823ad55321b1f8fe1b028d1bc62 SHA512 7a9b2ac79255e3049ee5847f5b424d2dff0a325e9f294b416d905907753c98751c70ff69ba496831eb98430532f438e5bd7edcb2c12b8b5c56f5b5c79b30c3d1
DIST ipykernel-6.20.2.tar.gz 149263 BLAKE2B 38b3afdbe237ec2facb3af42311315a060f1dba845cb3f7ce10a3d5f68679804640b0dbda869395817a8612af2033f5936ff7f6f3b3b822f47ed512a3b8c0c4d SHA512 9c79c7fa175cd81a920e6b1f2159dda30ba9068437cb1d24b09d864ded36b439045e58f240daee1a46ae375f1990cf318cd8b2e2c02aa6d6e2004d90aff5225a

75
dev-python/ipykernel/ipykernel-6.20.2.ebuild Normal file
View File

@@ -0,0 +1,75 @@
# Copyright 1999-2023 Gentoo Authors
# Distributed under the terms of the GNU General Public License v2
EAPI=8
DISTUTILS_USE_PEP517=hatchling
PYTHON_COMPAT=( python3_{9..11} )
PYTHON_REQ_USE="threads(+)"
inherit distutils-r1 virtualx
DESCRIPTION="IPython Kernel for Jupyter"
HOMEPAGE="
https://github.com/ipython/ipykernel/
https://pypi.org/project/ipykernel/
"
SRC_URI="mirror://pypi/${PN:0:1}/${PN}/${P}.tar.gz"
LICENSE="BSD"
SLOT="0"
KEYWORDS="~amd64 ~arm ~arm64 ~hppa ~ia64 ~loong ~ppc ~ppc64 ~riscv ~s390 ~sparc ~x86"
RDEPEND="
>=dev-python/comm-0.1.1[${PYTHON_USEDEP}]
>=dev-python/debugpy-1.0[${PYTHON_USEDEP}]
>=dev-python/ipython-7.23.1[${PYTHON_USEDEP}]
>=dev-python/jupyter_client-6.1.12[${PYTHON_USEDEP}]
>=dev-python/matplotlib-inline-0.1[${PYTHON_USEDEP}]
dev-python/nest_asyncio[${PYTHON_USEDEP}]
dev-python/packaging[${PYTHON_USEDEP}]
dev-python/psutil[${PYTHON_USEDEP}]
>=dev-python/pyzmq-17[${PYTHON_USEDEP}]
>=dev-python/tornado-6.1[${PYTHON_USEDEP}]
>=dev-python/traitlets-5.4.0[${PYTHON_USEDEP}]
"
# RDEPEND seems specifically needed in BDEPEND, at least jupyter
# bug #816486
BDEPEND="
${RDEPEND}
test? (
dev-python/flaky[${PYTHON_USEDEP}]
dev-python/pytest-timeout[${PYTHON_USEDEP}]
dev-python/ipyparallel[${PYTHON_USEDEP}]
)
"
distutils_enable_tests pytest
src_prepare() {
sed -i -e 's:^TIMEOUT = .*:TIMEOUT = 120:' ipykernel/tests/*.py || die
distutils-r1_src_prepare
}
python_compile() {
distutils-r1_python_compile
# Use python3 in kernel.json configuration, bug #784764
sed -i -e '/python3.[0-9]\+/s//python3/' \
"${BUILD_DIR}/install${EPREFIX}/usr/share/jupyter/kernels/python3/kernel.json" || die
}
src_test() {
local EPYTEST_DESELECT=(
# TODO
ipykernel/tests/test_debugger.py::test_attach_debug
ipykernel/tests/test_debugger.py::test_breakpoint_in_cell_with_leading_empty_lines
ipykernel/tests/test_debugger.py::test_rich_inspect_at_breakpoint
ipykernel/tests/test_debugger.py::test_rich_inspect_not_at_breakpoint
ipykernel/tests/test_debugger.py::test_set_breakpoints
ipykernel/tests/test_debugger.py::test_stop_on_breakpoint
# hangs?
ipykernel/tests/test_eventloop.py::test_tk_loop
)
virtx distutils-r1_src_test
}