net-libs/libwebsockets: bump to 4.1.0

Package-Manager: Portage-3.0.4, Repoman-3.0.1
Signed-off-by: Jakov Smolic <jakov.smolic@sartura.hr>
Closes: https://github.com/gentoo/gentoo/pull/17451
Signed-off-by: Sam James <sam@gentoo.org>

net-libs/libwebsockets/Manifest

@@ -1,2 +1,3 @@
 DIST libwebsockets-3.2.1.tar.gz 9868342 BLAKE2B d822552c611f7cd0ee416bf9b9576c6052e196c1aa68b12c46a00865d3dcd131840218394317f191485fc61d8f3b7654d4a652a47f11d279a555522df84a2350 SHA512 a2d30a7a0416a26484743efdaa8635542480a74b0ef0f6e172dab5de4688486efb13457fc8a884d9916f76322cab0cbc9ab675f496558edd1dd9b833d087207d
 DIST libwebsockets-4.0.20.tar.gz 12342036 BLAKE2B 983190f7f63eb9db09b688ae056c6fdee32ac6d57f4afe3fb42cd662202c290c21a28e9c107d61cd3b2ddb25478f93b56008dc939ced28cd1c5abd6314fb1b32 SHA512 b2ab19623557b67abf157aed0317fb2305304e72c7e40c202c0bc855a499bbef64978e9187adcfdd2ef251497144db4a9fbaebaf37a320c7190720e9d194b67a
+DIST libwebsockets-4.1.0.tar.gz 12674490 BLAKE2B 243fdcdef0cd9c36ee8bcf3c75b7467200f4fa1e6178cdbb9cc78d20d1aca533e910c9892560bd5c50c3ff98d783665616ea6d283ee8faae3f569bc526a31f42 SHA512 7748021f8a26e26474ae200f50ec8b59f19e69fbc612bbb31bbca2524e4381b2a7dde605740ac355109c9e34593fb5aee523d581ac64d821a594ffaadc16b1cb

net-libs/libwebsockets/libwebsockets-4.1.0.ebuild

@@ -0,0 +1,83 @@
+# Copyright 1999-2020 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+inherit cmake
+
+DESCRIPTION="A flexible pure-C library for implementing network protocols"
+HOMEPAGE="https://libwebsockets.org/"
+SRC_URI="https://github.com/warmcat/libwebsockets/archive/v${PV}.tar.gz -> ${P}.tar.gz"
+
+LICENSE="MIT"
+SLOT="0/17" # libwebsockets.so.17
+KEYWORDS="~amd64 ~arm ~arm64 ~x86"
+IUSE="access-log caps cgi client dbus generic-sessions http-proxy http2 ipv6
+	+lejp libev libevent libressl libuv mbedtls peer-limits server-status smtp socks5
+	sqlite3 ssl static-libs threads zip"
+
+REQUIRED_USE="
+	access-log? ( http2 )
+	generic-sessions? ( smtp sqlite3 )
+	http-proxy? ( client )
+	smtp? ( libuv )
+	ssl? ( ?? ( libressl mbedtls ) )
+	mbedtls? ( ssl )
+	?? ( libev libevent )
+"
+
+RDEPEND="
+	sys-libs/zlib
+	caps? ( sys-libs/libcap )
+	dbus? ( sys-apps/dbus )
+	http-proxy? ( net-libs/libhubbub )
+	libev? ( dev-libs/libev )
+	libevent? ( dev-libs/libevent:= )
+	libuv? ( dev-libs/libuv:= )
+	sqlite3? ( dev-db/sqlite:= )
+	ssl? (
+		!libressl? (
+			!mbedtls? ( dev-libs/openssl:0= )
+			mbedtls? ( >net-libs/mbedtls-2.0.0 )
+		)
+	)
+"
+DEPEND="${RDEPEND}"
+BDEPEND="dev-lang/perl
+	virtual/pkgconfig"
+
+src_configure() {
+	local mycmakeargs=(
+		-DCMAKE_DISABLE_FIND_PACKAGE_Git=ON
+		-DDISABLE_WERROR=ON
+		-DLWS_HAVE_LIBCAP=$(usex caps)
+		-DLWS_IPV6=$(usex ipv6)
+		-DLWS_ROLE_DBUS=$(usex dbus)
+		-DLWS_WITHOUT_CLIENT=$(usex !client)
+		-DLWS_WITHOUT_TEST_CLIENT=$(usex !client)
+		-DLWS_WITH_ACCESS_LOG=$(usex access-log)
+		-DLWS_WITH_CGI=$(usex cgi)
+		-DLWS_WITH_GENERIC_SESSIONS=$(usex generic-sessions)
+		-DLWS_WITH_HTTP2=$(usex http2)
+		-DLWS_WITH_HTTP_PROXY=$(usex http-proxy)
+		-DLWS_WITH_HUBBUB=$(usex http-proxy)
+		-DLWS_WITH_LEJP=$(usex lejp)
+		-DLWS_WITH_LIBEV=$(usex libev)
+		-DLWS_WITH_LIBEVENT=$(usex libevent)
+		-DLWS_WITH_LIBUV=$(usex libuv)
+		-DLWS_WITH_MBEDTLS=$(usex mbedtls)
+		-DLWS_WITH_PEER_LIMITS=$(usex peer-limits)
+		-DLWS_WITH_SERVER_STATUS=$(usex server-status)
+		-DLWS_WITH_SMTP=$(usex smtp)
+		-DLWS_WITH_SOCKS5=$(usex socks5)
+		-DLWS_WITH_SQLITE3=$(usex sqlite3)
+		-DLWS_WITH_SSL=$(usex ssl)
+		-DLWS_WITH_STATIC=$(usex static-libs)
+		-DLWS_WITH_STRUCT_JSON=$(usex lejp)
+		-DLWS_WITH_THREADPOOL=$(usex threads)
+		-DLWS_WITH_ZIP_FOPS=$(usex zip)
+		-DLWS_WITHOUT_TESTAPPS=ON
+	)
+
+	cmake_src_configure
+}