sci-biology/clustalx: Install icon

Gentoo-Bug: https://bugs.gentoo.org/show_bug.cgi?id=608716

Package-Manager: Portage-2.3.3, Repoman-2.3.1
Signed-off-by: Justin Lecher <jlec@gentoo.org>

sci-biology/clustalx/Manifest

@@ -1 +1,2 @@
 DIST clustalx-2.1.tar.gz 341649 SHA256 e10adb728c320598a165ca529f1aa3d2560061de0236e0a0926eaca9554afa05 SHA512 e8cbad783722161de6999ab01a91d555fc10db609197a8d2878f91e9d7dc998784c02d2ccb54c4936ee27b41321db6f4f37021221662f483b8b6d945b6e1c026 WHIRLPOOL 6cbe8dcf2be3a535e8ac0ef0b9b476d4429a80bd94b394c0194f46ed039f9ac2b97b0ec2ed680838a0973b3187b2dbc90285733657975e03288b9840ba3d6b15
+DIST clustalx.png.xz 74808 SHA256 7d333fd7e96ebc5709ec061e6be4123aba764a6127133cc8df5452f62e0d1cf3 SHA512 0907710c944fc1b883c58501cd7bc2abbc5bf171495b58dbe9829d60d7c3530c210f89a5bfafc3cec03808ae50f5c9a78ce37b9175c2e37590494e115e8e343a WHIRLPOOL 7d48b4be3ec61d3bd3017a0c0dbf0c3d3970b338cc1050a9c4173d06d268996a733c4a19202fba13e2cd640b72f02ecc9013198a821791edd820f16b5371d234

sci-biology/clustalx/clustalx-2.1-r2.ebuild

@@ -0,0 +1,51 @@
+# Copyright 1999-2017 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Id$
+
+EAPI=6
+
+inherit eutils qmake-utils
+
+DESCRIPTION="Graphical interface for the ClustalW multiple alignment program"
+HOMEPAGE="http://www.ebi.ac.uk/tools/clustalw2/"
+SRC_URI="
+	http://www.clustal.org/download/current/${P}.tar.gz
+	https://dev.gentoo.org/~jlec/distfiles/${PN}.png.xz"
+
+LICENSE="GPL-3 LGPL-3"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+IUSE=""
+
+DEPEND="
+	dev-qt/qtcore:4
+	dev-qt/qtgui:4"
+RDEPEND="${DEPEND}
+	>=sci-biology/clustalw-${PV}"
+
+src_prepare() {
+	sed \
+		-e "s|colprot.xml|${EPREFIX}/usr/share/${PN}/colprot.xml|" \
+		-e "s|coldna.xml|${EPREFIX}/usr/share/${PN}/coldna.xml|" \
+		-e "s|colprint.xml|${EPREFIX}/usr/share/${PN}/colprint.xml|" \
+		-i ClustalQtParams.h || \
+		die "Failed to patch shared files location."
+	sed \
+		-e "s|clustalx.hlp|${EPREFIX}/usr/share/${PN}/clustalx.hlp|" \
+		-i HelpDisplayWidget.cpp || \
+		die "Failed to patch help file location."
+	rm -rf usr || die
+	default
+}
+
+src_configure() {
+	eqmake4
+}
+
+src_install() {
+	dobin clustalx
+	insinto /usr/share/${PN}
+	doins colprot.xml coldna.xml colprint.xml clustalx.hlp
+	make_desktop_entry ${PN} ClustalX
+	doicon "${WORKDIR}"/${PN}.png
+}