dev-libs/libwacom: Version bump to 2.13.0

Signed-off-by: Matt Turner <mattst88@gentoo.org>

dev-libs/libwacom/Manifest

@@ -1 +1,2 @@
 DIST libwacom-2.12.2.tar.xz 153600 BLAKE2B f2a965d1990e8d2aa248d9d81f31f50e2602c66e3cbc41dd0638994c955b30a5e4be445041e8ac5240b336611f6fb3217779142e95fc3c5265860ebc4f918c41 SHA512 34f80f6c5bdb62938874978b2761d71a1da4629969550ac87b08eb132e88bfb67b56a4f5fcd687e4607a18ef8b34262ba9c4cfc0fcf6a1a6bb98c1a05ded0b08
+DIST libwacom-2.13.0.tar.xz 154512 BLAKE2B 3b63231af2e92052fce3eed87aad7d465cf827dca82f034c7d3577036656b8b71de3b00a35e4f447ae653d01f498de2d960c87cfda4a5b9fa9cb0f79cfd22271 SHA512 c5d6a506b459d97d6865c478baa2a7d278c8fdab902b78a0447eb7a059272e89a669d9f2fa42d4efc9b724cb730a975081a1f8bbb8421b81632869c342fdeb5f

dev-libs/libwacom/libwacom-2.13.0.ebuild

@@ -0,0 +1,61 @@
+# Copyright 1999-2024 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+PYTHON_COMPAT=( python3_{10..13} )
+inherit meson python-any-r1 udev
+
+DESCRIPTION="Library for identifying Wacom tablets and their model-specific features"
+HOMEPAGE="https://github.com/linuxwacom/libwacom"
+SRC_URI="https://github.com/linuxwacom/${PN}/releases/download/${P}/${P}.tar.xz"
+
+LICENSE="MIT"
+SLOT="0/9" # libwacom SONAME
+KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~ppc ~ppc64 ~riscv ~x86"
+IUSE="doc test"
+RESTRICT="!test? ( test )"
+
+RDEPEND="
+	dev-libs/glib:2
+	dev-libs/libevdev
+	dev-libs/libgudev:=
+"
+DEPEND="${RDEPEND}"
+BDEPEND="
+	${PYTHON_DEPS}
+	virtual/pkgconfig
+	doc? ( app-text/doxygen )
+	test? (
+		$(python_gen_any_dep '
+			dev-python/libevdev[${PYTHON_USEDEP}]
+			dev-python/pyudev[${PYTHON_USEDEP}]
+			dev-python/pytest[${PYTHON_USEDEP}]
+		')
+	)
+"
+
+python_check_deps() {
+	use test || return 0
+	python_has_version \
+		"dev-python/libevdev[${PYTHON_USEDEP}]" \
+		"dev-python/pyudev[${PYTHON_USEDEP}]" \
+		"dev-python/pytest[${PYTHON_USEDEP}]"
+}
+
+src_configure() {
+	local emesonargs=(
+		$(meson_feature doc documentation)
+		$(meson_feature test tests)
+		-Dudev-dir=$(get_udevdir)
+	)
+	meson_src_configure
+}
+
+pkg_postinst() {
+	udev_reload
+}
+
+pkg_postrm() {
+	udev_reload
+}