www-client/qutebrowser: bump 1.6.0

Signed-off-by: Justin Bronder <jsbronder@gentoo.org>
Package-Manager: Portage-2.3.51, Repoman-2.3.11

www-client/qutebrowser/Manifest

@@ -1 +1,2 @@
 DIST qutebrowser-1.5.2.tar.gz 3566709 BLAKE2B 4b317c87770cbc817e19808f7e1ce58c030bb8567aba21bf23c6d57f136ab13763ef6b6cdf0c078428b7b228ef32b1156eb1ab125df037a5073c110f83df806d SHA512 29c48d86b95bf2b40459ef06dab37fff7e30409f78d8c50c494ebafc9698a0c0123a63d160679b3a4778ecb15e5c339dc67357a60f493499ad4b6443f7dacc7a
+DIST qutebrowser-1.6.0.tar.gz 3638739 BLAKE2B 8ca5995b9126fa7e017e3f2924c07c01b2d90540e0521d74cdba4ce8f2f83d1c7e8f0dc412ff41936c3a36c17d53060c331ed069d8088ac11b772979a48c7b0d SHA512 54b275f0d00ef48fa88a0bc83f31efd0d1fe708d7223adcf83c9d1a5db60de8e9c77033b8bf4b2b9a526d11ce39941d5d9da8afe9f49f3ed06e6f6f7ef124c20

www-client/qutebrowser/qutebrowser-1.6.0.ebuild

@@ -0,0 +1,72 @@
+# Copyright 1999-2019 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=6
+PYTHON_COMPAT=( python{3_5,3_6} )
+
+inherit distutils-r1 eutils gnome2-utils xdg-utils
+
+if [[ ${PV} == "9999" ]] ; then
+	EGIT_REPO_URI="https://github.com/${PN}/${PN}.git"
+	inherit git-r3
+else
+	SRC_URI="https://github.com/${PN}/${PN}/releases/download/v${PV}/${P}.tar.gz"
+	KEYWORDS="~amd64 ~x86"
+fi
+
+DESCRIPTION="A keyboard-driven, vim-like browser based on PyQt5 and QtWebEngine"
+HOMEPAGE="https://www.qutebrowser.org/ https://github.com/qutebrowser/qutebrowser"
+
+LICENSE="GPL-3"
+SLOT="0"
+IUSE="test"
+
+COMMON_DEPEND="dev-python/setuptools[${PYTHON_USEDEP}]"
+DEPEND="${COMMON_DEPEND}
+	app-text/asciidoc
+	test? ( dev-python/pytest[${PYTHON_USEDEP}] )"
+RDEPEND="${COMMON_DEPEND}
+	dev-python/attrs[${PYTHON_USEDEP}]
+	>=dev-python/jinja-2.8[${PYTHON_USEDEP}]
+	>=dev-python/pygments-2.1.3[${PYTHON_USEDEP}]
+	>=dev-python/pypeg2-2.15.2[${PYTHON_USEDEP}]
+	>=dev-python/PyQt5-5.7.1[${PYTHON_USEDEP},declarative,multimedia,gui,network,opengl,printsupport,sql,webengine,widgets]
+	>=dev-python/pyyaml-3.12[${PYTHON_USEDEP},libyaml]
+"
+
+# Tests restricted as the deplist (misc/requirements/requirements-tests.txt)
+# isn't complete and X11 is required in order to start up qutebrowser.
+RESTRICT="test"
+
+python_compile_all() {
+	if [[ ${PV} == "9999" ]]; then
+		"${PYTHON}" scripts/asciidoc2html.py || die "Failed generating docs"
+	fi
+
+	a2x -f manpage doc/${PN}.1.asciidoc || die "Failed generating man page"
+}
+
+python_test() {
+	py.test tests || die "Tests failed with ${EPYTHON}"
+}
+
+python_install_all() {
+	doman doc/${PN}.1
+	domenu misc/${PN}.desktop
+	doicon -s scalable icons/${PN}.svg
+
+	distutils-r1_python_install_all
+}
+
+pkg_postinst() {
+	optfeature "PDF display support" www-plugins/pdfjs
+	xdg_desktop_database_update
+	xdg_mimeinfo_database_update
+	gnome2_icon_cache_update
+}
+
+pkg_postrm() {
+	xdg_desktop_database_update
+	xdg_mimeinfo_database_update
+	gnome2_icon_cache_update
+}