Merge updates from master

2026-08-24 06:48:18 -07:00 · 2026-07-14 15:15:56 +00:00
parent 84b2c8ad50 379c51a000
commit bb437ed66f
3 changed files with 195 additions and 1 deletions
--- a/dev-java/jackcess/jackcess-4.0.10.ebuild
+++ b/dev-java/jackcess/jackcess-4.0.10.ebuild
@@ -15,7 +15,7 @@ S="${WORKDIR}/${PN}-${P}"

 LICENSE="Apache-2.0"
 SLOT="0"
-KEYWORDS="amd64 arm64 ~ppc64"
+KEYWORDS="amd64 arm64 ppc64"

 CP_DEPEND="
 	>=dev-java/poi-5.5.1:0
--- a/net-misc/freerdp/Manifest
+++ b/net-misc/freerdp/Manifest
@@ -1,2 +1,4 @@
 DIST freerdp-3.27.1.tar.gz 11452205 BLAKE2B ee08cfc2e4d203e6a2796bc52fa5b2285d6359d38482c5a4ffcc8dd3bd11c2593ab21a5772bdc13acaf810a8f229d669324f8d6d573d5c7ee9bec20dcfd46c4e SHA512 8d564dd8552abf3ecd592a106c43434f62895caeebb425fa2b259456d6670e64d513d6174ffc31a26aac57697e954156e0f8bb9900524d6f96efd3d8d4f3afe5
 DIST freerdp-3.27.1.tar.gz.asc 228 BLAKE2B 5d0d86bd3e1643b8c325d6197295c74e8ccaa38d2cabb497fbe98ee285f9ab73ffc6f28f1ee4428bab57d7a54952d9ee6daef68761109dc25a3cfd7d5768471b SHA512 32f052e66ecec48315288e2f675853ab823309f20e090596e38a00177e6fecdb69df77d6021564bc4ea6f2c5b914504de105639f1b29ce810fb07d9511910242
+DIST freerdp-3.29.0.tar.gz 11067925 BLAKE2B 2202eae9cca1275b366b6b87935760ec438b10ef0e15222241ee8126b74614938dc47586d51c28e68e1597fc46a0a02130238af7dff5db4fc850d6604e516548 SHA512 daa1dc6d561c5ffa65a422ffbd218a6244dd3eff400759a456f33ead3618461302d13543ae32a41aa188b2e3590f15b143cf158b13f38b235fe992c38c9916f9
+DIST freerdp-3.29.0.tar.gz.asc 228 BLAKE2B 5df8af1b75bfe5eb0be2526908c39d6324c9bbd04219528b84b467e9db875ed4b406e550d8e2a4ca4ee528d405063183d551f98aa405a1361fdc28307a0b3453 SHA512 46373f21988db91fa9179364290e0daf3a8b2d58cc084a6c1fbd5870994b011bebab01b8e9ee32e7df266350fb0a647defaab37aa5d10246f8922b196460d1ff
--- a/net-misc/freerdp/freerdp-3.29.0.ebuild
+++ b/net-misc/freerdp/freerdp-3.29.0.ebuild
@@ -0,0 +1,192 @@
+# Copyright 2011-2026 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+inherit cmake flag-o-matic
+
+if [[ ${PV} == *9999 ]]; then
+	inherit git-r3
+	EGIT_REPO_URI="https://github.com/FreeRDP/FreeRDP.git"
+	case ${PV} in
+		2.*) EGIT_BRANCH="stable-2.0";;
+	esac
+else
+	inherit verify-sig
+	MY_P=${P/_/-}
+	S="${WORKDIR}/${MY_P}"
+	SRC_URI="https://pub.freerdp.com/releases/${MY_P}.tar.gz
+		verify-sig? ( https://pub.freerdp.com/releases/${MY_P}.tar.gz.asc )"
+	KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~loong ~ppc ~ppc64 ~riscv ~x86"
+	BDEPEND="verify-sig? ( sec-keys/openpgp-keys-akallabeth )"
+	VERIFY_SIG_OPENPGP_KEY_PATH="/usr/share/openpgp-keys/akallabeth.asc"
+fi
+
+DESCRIPTION="Free implementation of the Remote Desktop Protocol"
+HOMEPAGE="https://www.freerdp.com/"
+
+LICENSE="Apache-2.0"
+SLOT="3"
+IUSE="aad alsa camera cpu_flags_arm_neon +client cups debug +ffmpeg +fuse gstreamer +icu jpeg kerberos openh264 pulseaudio sdl server smartcard systemd test usb valgrind wayland X xinerama xv"
+RESTRICT="!test? ( test )"
+
+BDEPEND+="
+	virtual/pkgconfig
+	app-text/docbook-xsl-stylesheets
+	dev-libs/libxslt
+"
+COMMON_DEPEND="
+	dev-libs/openssl:0=
+	virtual/zlib:=
+	aad? ( dev-libs/cJSON )
+	alsa? ( media-libs/alsa-lib )
+	cups? ( net-print/cups )
+	usb? (
+		virtual/libudev:0=
+		sys-apps/util-linux:0=
+		dev-libs/dbus-glib:0=
+		virtual/libusb:1=
+	)
+	X? (
+		x11-libs/libXcursor
+		x11-libs/libXext
+		x11-libs/libXi
+		x11-libs/libXrender
+		xinerama? ( x11-libs/libXinerama )
+		xv? ( x11-libs/libXv )
+	)
+	ffmpeg? ( media-video/ffmpeg:0= )
+	!ffmpeg? (
+		x11-libs/cairo:0=
+	)
+	fuse? ( sys-fs/fuse:3= )
+	gstreamer? (
+		media-libs/gstreamer:1.0
+		media-libs/gst-plugins-base:1.0
+		X? ( x11-libs/libXrandr )
+	)
+	icu? ( dev-libs/icu:0= )
+	jpeg? ( media-libs/libjpeg-turbo:0= )
+	kerberos? ( virtual/krb5 )
+	openh264? ( media-libs/openh264:0= )
+	pulseaudio? ( media-libs/libpulse )
+	server? (
+		X? (
+			x11-libs/libXcursor
+			x11-libs/libXdamage
+			x11-libs/libXext
+			x11-libs/libXfixes
+			x11-libs/libXrandr
+			x11-libs/libXtst
+			xinerama? ( x11-libs/libXinerama )
+		)
+	)
+	smartcard? ( sys-apps/pcsc-lite )
+	systemd? ( sys-apps/systemd:0= )
+	client? (
+		camera? ( media-libs/libv4l )
+		sdl? (
+			media-libs/libsdl3
+			media-libs/sdl3-ttf
+		)
+		wayland? (
+			dev-libs/wayland
+			x11-libs/libxkbcommon
+		)
+	)
+	X? (
+		x11-libs/libX11
+		x11-libs/libxkbfile
+	)
+"
+DEPEND="${COMMON_DEPEND}
+	test? (
+		ffmpeg? ( media-video/ffmpeg:0[x264(-)] )
+	)
+	valgrind? ( dev-debug/valgrind )
+"
+RDEPEND="${COMMON_DEPEND}
+	!net-misc/freerdp:0
+	client? ( !net-misc/freerdp:2[client] )
+	server? ( !net-misc/freerdp:2[server] )
+	smartcard? ( app-crypt/p11-kit )
+"
+
+option() {
+	usex "$1" ON OFF
+}
+
+option_client() {
+	if use client; then
+		option "$1"
+	else
+		echo OFF
+	fi
+}
+
+src_configure() {
+	use debug || append-cppflags -DNDEBUG
+	local mycmakeargs=(
+		-Wno-dev
+
+		-DBUILD_TESTING=$(option test)
+
+		# https://bugs.gentoo.org/927037
+		-DCMAKE_INTERPROCEDURAL_OPTIMIZATION=OFF
+
+		-DCHANNEL_URBDRC=$(option usb)
+		-DCHANNEL_RDPECAM_CLIENT=$(option_client camera)
+		-DWITH_AAD=$(option aad)
+		-DWITH_ALSA=$(option alsa)
+		-DWITH_CCACHE=OFF
+		-DWITH_CLIENT=$(option client)
+		-DWITH_CLIENT_SDL2=OFF
+		-DWITH_CLIENT_SDL3=$(option_client sdl)
+		-DWITH_SAMPLE=OFF
+		-DWITH_CUPS=$(option cups)
+		-DWITH_DEBUG_ALL=$(option debug)
+		-DWITH_VERBOSE_WINPR_ASSERT=$(option debug)
+		-DWITH_MANPAGES=ON
+		-DWITH_FFMPEG=$(option ffmpeg)
+		-DWITH_FREERDP_DEPRECATED_COMMANDLINE=ON
+		-DWITH_SWSCALE=$(option ffmpeg)
+		-DWITH_CAIRO=$(option !ffmpeg)
+		-DWITH_DSP_FFMPEG=$(option ffmpeg)
+		-DWITH_FUSE=$(option fuse)
+		-DWITH_GSTREAMER_1_0=$(option gstreamer)
+		-DWITH_JPEG=$(option jpeg)
+		-DWITH_KRB5=$(option kerberos)
+		-DWITH_NEON=$(option cpu_flags_arm_neon)
+		-DWITH_OPENH264=$(option openh264)
+		-DWITH_OSS=OFF
+		-DWITH_PCSC=$(option smartcard)
+		-DWITH_PKCS11=$(option smartcard)
+		-DWITH_PULSE=$(option pulseaudio)
+		-DWITH_SERVER=$(option server)
+		-DWITH_LIBSYSTEMD=$(option systemd)
+		-DWITH_UNICODE_BUILTIN=$(option !icu)
+		-DWITH_VALGRIND_MEMCHECK=$(option valgrind)
+		-DWITH_X11=$(option X)
+		-DWITH_XINERAMA=$(option xinerama)
+		-DWITH_XV=$(option xv)
+		-DWITH_WAYLAND=$(option_client wayland)
+		-DWITH_WEBVIEW=OFF
+		-DWITH_WINPR_TOOLS=$(option server)
+	)
+	cmake_src_configure
+}
+
+src_test() {
+	# TestBacktrace: bug 930636
+	# TestSynchCritical, TestSynchMultipleThreads: bug 951301
+	local CMAKE_SKIP_TESTS=( TestBacktrace TestSynchCritical TestSynchMultipleThreads )
+	if has network-sandbox ${FEATURES}; then
+		CMAKE_SKIP_TESTS+=( TestConnect )
+	fi
+	cmake_src_test
+}
+
+src_install() {
+	cmake_src_install
+	mv "${ED}"/usr/share/man/man7/wlog{,3}.7 || die
+}