games-util/joycond: New package

Signed-off-by: James Le Cuirot <chewi@gentoo.org>

games-util/joycond/Manifest

@@ -0,0 +1 @@
+DIST joycond-0.1.0_p20210730.tar.gz 29947 BLAKE2B d151e9a798a358e142c44722ce5d9892bc63a7c2992aa6b962a02ab971a8aec9bd343bd56cc26ae36e63d5977d1d0a99c52c35aeb779d352f1bbe2d15010e43c SHA512 1d0a82bd9e2aeecef3215232ffb6acb77008845fe0e8094e81d2b81627cca1e5d581986fad6631c5efd2b29514370fbac8a65d9996df762543d050628327a564

games-util/joycond/files/joycond.initd

@@ -0,0 +1,7 @@
+#!/sbin/openrc-run
+# Copyright 1999-2022 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+pidfile="/var/run/${RC_SVCNAME}.pid"
+command_background="true"
+command="joycond"

games-util/joycond/joycond-0.1.0_p20210730.ebuild

@@ -0,0 +1,39 @@
+# Copyright 1999-2022 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+inherit cmake linux-info
+
+COMMIT="f9a66914622514c13997c2bf7ec20fa98e9dfc1d"
+DESCRIPTION="Daemon that uses hid-nintendo evdev devices to implement joycon pairing"
+HOMEPAGE="https://github.com/DanielOgorchock/joycond"
+SRC_URI="https://github.com/DanielOgorchock/joycond/archive/${COMMIT}.tar.gz -> ${P}.tar.gz"
+
+LICENSE="GPL-3"
+SLOT="0"
+KEYWORDS="~amd64"
+
+DEPEND="
+	dev-libs/libevdev
+	virtual/udev
+"
+
+RDEPEND="
+	${DEPEND}
+"
+
+CONFIG_CHECK="
+	~HID
+	~HID_NINTENDO
+	~HIDRAW
+"
+
+S="${WORKDIR}/${PN}-${COMMIT}"
+
+src_install() {
+	cmake_src_install
+	rm -r "${ED}"/etc/modules-load.d/ || die
+	newinitd "${FILESDIR}"/${PN}.initd ${PN}
+	doman doc/${PN}.1
+}

games-util/joycond/metadata.xml

@@ -0,0 +1,11 @@
+<?xml version="1.0" encoding="UTF-8"?>
+<!DOCTYPE pkgmetadata SYSTEM "https://www.gentoo.org/dtd/metadata.dtd">
+<pkgmetadata>
+	<maintainer type="project">
+		<email>games@gentoo.org</email>
+		<name>Gentoo Games Project</name>
+	</maintainer>
+	<upstream>
+		<remote-id type="github">DanielOgorchock/joycond</remote-id>
+	</upstream>
+</pkgmetadata>