mirror of
https://github.com/gentoo-mirror/gentoo.git
synced 2026-11-21 10:37:22 -08:00
dev-cpp/wangle: add 2025.04.14.00
RDEPEND fixed via qa-vdb. Bug: https://bugs.gentoo.org/946922 Signed-off-by: sin-ack <sin-ack@protonmail.com> Signed-off-by: Sam James <sam@gentoo.org>
This commit is contained in:
@@ -1 +1,2 @@
|
||||
DIST wangle-2024.11.04.00.gh.tar.gz 372838 BLAKE2B 5d6636aa9cbea7f1438269a8c935b93dd5e3c6abef0cc6c668088d883a9b9326f44409649d809c80c08e79c2fa0527fd26a4db7ceed616f27aea2a3921c5ae75 SHA512 d44f3553b04f378935c2a6cf072d6b4a911be3bb71f3480ccdbb269f83c0f62dce4451bcb2edb365d9b398f719c7162269690d07aab07054dafaa55b5b38e0ad
|
||||
DIST wangle-2025.04.14.00.gh.tar.gz 368600 BLAKE2B 092e7fcc97016158aeefa64018a0ef4e5e91542d11677d7b20adcda128817f85a7155aee71618add311dcab2dde88d54a19a04da950da4cb05393ca1905e1bd6 SHA512 d3aa8dc6ef184356f520341b858d9064f18a413cccec52d541cb4fc7895f700c1cbbf00ede7ee8ac52d6cc7c0779e68c6078a475ace25f24854c706bbe462798
|
||||
|
||||
@@ -0,0 +1,69 @@
|
||||
# Copyright 2022-2025 Gentoo Authors
|
||||
# Distributed under the terms of the GNU General Public License v2
|
||||
|
||||
EAPI=8
|
||||
|
||||
# These must be bumped together:
|
||||
# dev-cpp/edencommon
|
||||
# dev-cpp/fb303
|
||||
# dev-cpp/fbthrift
|
||||
# dev-cpp/fizz
|
||||
# dev-cpp/folly
|
||||
# dev-cpp/mvfst
|
||||
# dev-cpp/wangle
|
||||
# dev-util/watchman
|
||||
|
||||
CMAKE_USE_DIR="${S}/wangle"
|
||||
|
||||
inherit cmake
|
||||
|
||||
DESCRIPTION="A framework providing common abstractions for building services"
|
||||
HOMEPAGE="https://github.com/facebook/wangle"
|
||||
SRC_URI="https://github.com/facebook/wangle/archive/refs/tags/v${PV}.tar.gz -> ${P}.gh.tar.gz"
|
||||
|
||||
LICENSE="Apache-2.0"
|
||||
SLOT="0/${PV}"
|
||||
KEYWORDS="~amd64 ~arm64"
|
||||
IUSE="test"
|
||||
|
||||
RESTRICT="!test? ( test )"
|
||||
|
||||
RDEPEND="
|
||||
~dev-cpp/fizz-${PV}:=
|
||||
~dev-cpp/folly-${PV}:=
|
||||
dev-cpp/gflags:=
|
||||
dev-cpp/glog:=[gflags]
|
||||
dev-libs/double-conversion:=
|
||||
dev-libs/libfmt:=
|
||||
dev-libs/openssl:=
|
||||
"
|
||||
DEPEND="
|
||||
${RDEPEND}
|
||||
test? ( dev-cpp/gtest )
|
||||
"
|
||||
|
||||
src_configure() {
|
||||
local mycmakeargs=(
|
||||
-DCMAKE_INSTALL_DIR="$(get_libdir)/cmake/${PN}"
|
||||
-DLIB_INSTALL_DIR="$(get_libdir)"
|
||||
-DBUILD_TESTS="$(usex test ON OFF)"
|
||||
)
|
||||
|
||||
cmake_src_configure
|
||||
}
|
||||
|
||||
src_test() {
|
||||
CMAKE_SKIP_TESTS=(
|
||||
# These tests expect test certificates to be present in /usr/include/folly/io/async/test/certs/, which folly
|
||||
# doesn't install.
|
||||
SSLContextManagerTest
|
||||
)
|
||||
|
||||
if use arm64; then
|
||||
# This test fails on arm64.
|
||||
# https://github.com/facebook/wangle/issues/241
|
||||
CMAKE_SKIP_TESTS+=(TLSInMemoryTicketProcessorTest)
|
||||
fi
|
||||
|
||||
cmake_src_test
|
||||
}
|
||||
Reference in New Issue
Block a user