gentoo-mirror/gentoo
1
0
Fork 0
mirror of https://github.com/gentoo-mirror/gentoo.git synced 2026-09-16 14:29:05 -07:00
Code Issues Projects Releases Wiki Activity

dev-python/python-lsp-server: add version 1.2.0

Browse Source 
Package-Manager: Portage-3.0.20, Repoman-3.0.3
Signed-off-by: Andrew Ammerlaan <andrewammerlaan@gentoo.org>
This commit is contained in:
Andrew Ammerlaan
2021-08-02 09:54:39 +02:00
parent b9c4e4272b
commit ba76686e9e
2 changed files with 84 additions and 0 deletions
Download Patch File Download Diff File Expand all files Collapse all files

1
dev-python/python-lsp-server/Manifest
View File

@@ -1,2 +1,3 @@
DIST python-lsp-server-1.0.1.tar.gz 56835 BLAKE2B 430e215b7d65bff2008136783539c262ee201d651bf83750333d41353483882fe7a603208c2725c89530a34cef22e73fe1ef26ec80fe7fb42d2df79eae511528 SHA512 bf116d92bdebea41e4f6647673d390887d84be70d612b92b8c3973aa55db4b151c1188b06fb8e3b6dccb814fd22f938572e998f0b1329bf0b69d0e4750b8f5f6
DIST python-lsp-server-1.1.0.tar.gz 58194 BLAKE2B bc1d542e90a1295e7bddf68d366a738b371895a453e8fb7de5b0d688c49b45b9c3441d479c1f760291e32eedc6fd42cb5ee0966ed32a10ee7f883dee3559932f SHA512 fd9f1985bd55f93740671e83696b02567b12b9b77db14c495482494d23f0a73b2048d99fce9c1be0b7d7c847f213a681d379c342d128a95cf40bd3ffeca9766f
DIST python-lsp-server-1.2.0.tar.gz 61430 BLAKE2B 2fa893eb4318a1e80d14a63c2db1aff240cfefe431d934d0536d4d55b793d0365ba4b1cce820beb8a451a2a846024a08f576e54e2a503ef850fcd4334d38b770 SHA512 5d6266ceb12ad8fe0426f29353bf574705c929c30cf1adf439d5d3a2023d00b077e23ae21cafc46f7ac4c32c9362c545be6193a585d564cfdfc9c51785c8c805

83
dev-python/python-lsp-server/python-lsp-server-1.2.0.ebuild Normal file
View File

@@ -0,0 +1,83 @@
# Copyright 1999-2021 Gentoo Authors
# Distributed under the terms of the GNU General Public License v2
EAPI=7
PYTHON_COMPAT=( python3_{7..9} )
DISTUTILS_USE_SETUPTOOLS=rdepend
inherit distutils-r1 optfeature
DESCRIPTION="Python Language Server for the Language Server Protocol"
HOMEPAGE="https://github.com/python-lsp/python-lsp-server"
SRC_URI="mirror://pypi/${PN:0:1}/${PN}/${P}.tar.gz"
LICENSE="MIT"
SLOT="0"
KEYWORDS="~amd64 ~arm64 ~x86"
IUSE="all-plugins"
BDEPEND="
test? (
dev-python/autopep8[${PYTHON_USEDEP}]
dev-python/flaky[${PYTHON_USEDEP}]
>=dev-python/flake8-3.8.0[${PYTHON_USEDEP}]
dev-python/matplotlib[${PYTHON_USEDEP}]
>=dev-python/mccabe-0.6.0[${PYTHON_USEDEP}]
<dev-python/mccabe-0.7.0[${PYTHON_USEDEP}]
dev-python/numpy[${PYTHON_USEDEP}]
dev-python/pandas[${PYTHON_USEDEP}]
>=dev-python/pycodestyle-2.7.0[${PYTHON_USEDEP}]
>=dev-python/pydocstyle-2.0.0[${PYTHON_USEDEP}]
>=dev-python/pyflakes-2.3.0[${PYTHON_USEDEP}]
<dev-python/pyflakes-2.4.0[${PYTHON_USEDEP}]
>=dev-python/pylint-2.5.0[${PYTHON_USEDEP}]
dev-python/QtPy[gui,testlib,${PYTHON_USEDEP}]
>=dev-python/rope-0.10.5[${PYTHON_USEDEP}]
dev-python/yapf[${PYTHON_USEDEP}]
)"
RDEPEND="
>=dev-python/jedi-0.17.2[${PYTHON_USEDEP}]
<dev-python/jedi-0.19.0[${PYTHON_USEDEP}]
>=dev-python/python-lsp-jsonrpc-1.0.0[${PYTHON_USEDEP}]
dev-python/pluggy[${PYTHON_USEDEP}]
all-plugins? (
dev-python/autopep8[${PYTHON_USEDEP}]
>=dev-python/flake8-3.8.0[${PYTHON_USEDEP}]
>=dev-python/mccabe-0.6.0[${PYTHON_USEDEP}]
<dev-python/mccabe-0.7.0[${PYTHON_USEDEP}]
>=dev-python/pycodestyle-2.7.0[${PYTHON_USEDEP}]
>=dev-python/pydocstyle-2.0.0[${PYTHON_USEDEP}]
>=dev-python/pyflakes-2.3.0[${PYTHON_USEDEP}]
<dev-python/pyflakes-2.4.0[${PYTHON_USEDEP}]
>=dev-python/pylint-2.5.0[${PYTHON_USEDEP}]
>=dev-python/rope-0.10.5[${PYTHON_USEDEP}]
dev-python/yapf[${PYTHON_USEDEP}]
)
"
distutils_enable_tests pytest
python_prepare_all() {
# remove pytest-cov dep
sed -i -e '0,/addopts/I!d' setup.cfg || die
# This test is continuously breaking
sed -i -e 's/test_folding/_&/' test/plugins/test_folding.py || die
distutils-r1_python_prepare_all
}
pkg_postinst() {
optfeature "Automatically formats Python code to conform to the PEP 8 style guide" dev-python/autopep8
optfeature "A wrapper around PyFlakes, pep8 & mccabe" dev-python/flake8
optfeature "flake8 plugin: McCabe complexity checker" dev-python/mccabe
optfeature "Python style guide checker (fka pep8)" dev-python/pycodestyle
optfeature "Python docstring style checker" dev-python/pydocstyle
optfeature "Passive checker for Python programs" dev-python/pyflakes
optfeature "Python code static checker" dev-python/pylint
optfeature "Python refactoring library" dev-python/rope
optfeature "A formatter for Python files" dev-python/yapf
}