sys-block/fio: bump

Package-Manager: Portage-2.3.16, Repoman-2.3.6
This commit is contained in:
Robin H. Johnson
2017-11-30 10:47:42 -08:00
parent fb3c1fe9a4
commit b9fa0ed7c2
2 changed files with 111 additions and 2 deletions
+3 -2
View File
@@ -1,2 +1,3 @@
DIST fio-2.15.tar.bz2 545809 SHA256 60044f92cfbd2f656162864aae309ab88ff5983c2e49f4b9f8271c445852f5bd SHA512 fa3380031e6e0a597eb34e597af91efbc824a3d5753793fdb00cb10e693943e0358afaad9624eb4333e81182c94424a56fbd1d434eeff098dbf2fc4e19167db0 WHIRLPOOL 32215d63a373c88041d90c6d07d87f9b4e6d4070d1b263676a817dc9ddd8cb175cbbc25e8359cec956ea26a39f40c1cb501ba897475f628ce4f6a5502939239e
DIST fio-2.16.tar.bz2 558662 SHA256 7d8dd6897a5fa181b4b707ffb7b87306c23a5a99a3aefa1d6f510150302cb6ec SHA512 f71c8ab8423e82ceae160bae8c17ac1222c1b2dde2ccb1b2aedb2288e0eb60485f8e9f3908640d4f6cebf166a148f4ad64026c035381c5db5141bf3059349d75 WHIRLPOOL cdd11fd09dce3fec04b12f82fef6d53c8ae70623b35a39cbfe50039bf9be5d80e00715c58e9fa6dee67a471327bf6da7f741add880bfefa9eb26f432b265e9ac
DIST fio-2.15.tar.bz2 545809 BLAKE2B 163530097a6ff08016c977a328bc499d052c423890c8e7074bc91fb00b02b3d951dd0369ff772fa5f36a37e0b1b7d6b358c3df99bf70db9bec2bbc7f90eee596 SHA512 fa3380031e6e0a597eb34e597af91efbc824a3d5753793fdb00cb10e693943e0358afaad9624eb4333e81182c94424a56fbd1d434eeff098dbf2fc4e19167db0
DIST fio-2.16.tar.bz2 558662 BLAKE2B cbc6e6000bd497fc92779c34688c0862f3adccd7c399ca5d4e4ce9ee9c40faddfec9b3fcca2fad2cd91ca00eee95c4a108273496c9e63db8017695ecf42d294d SHA512 f71c8ab8423e82ceae160bae8c17ac1222c1b2dde2ccb1b2aedb2288e0eb60485f8e9f3908640d4f6cebf166a148f4ad64026c035381c5db5141bf3059349d75
DIST fio-3.2.tar.bz2 613565 BLAKE2B e721d698338dd8d2c6215780a2d9a10c643a5912d3c27b3e759b4c14585ae1afe4edab5bdc54df8cf19c6f3727f8f4b19ce9da3298a5f0ef3753a5d8f423f4ef SHA512 97ea5ed6587d1e7382a67ab7ad933b6e332ba84cb648d17dcebad3c95c9eb6b1c04a4537e3470f890607f2921da77fcd4e49079b8b78f2d15e9c199dab850d1e
+108
View File
@@ -0,0 +1,108 @@
# Copyright 1999-2017 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
EAPI=6
PYTHON_COMPAT=( python2_7 )
inherit eutils python-r1 toolchain-funcs
MY_PV="${PV/_rc/-rc}"
MY_P="${PN}-${MY_PV}"
DESCRIPTION="Jens Axboe's Flexible IO tester"
HOMEPAGE="http://brick.kernel.dk/snaps/"
SRC_URI="http://brick.kernel.dk/snaps/${MY_P}.tar.bz2"
LICENSE="GPL-2"
SLOT="0"
KEYWORDS="~amd64 ~arm ~ia64 ~ppc ~ppc64 ~x86"
IUSE="aio glusterfs gnuplot gtk numa rbd rdma static zlib"
REQUIRED_USE="gnuplot? ( ${PYTHON_REQUIRED_USE} )"
# GTK+:2 does not offer static libaries.
LIB_DEPEND="aio? ( dev-libs/libaio[static-libs(+)] )
glusterfs? ( sys-cluster/glusterfs[static-libs(+)] )
gtk? ( dev-libs/glib:2[static-libs(+)] )
numa? ( sys-process/numactl[static-libs(+)] )
rbd? ( sys-cluster/ceph[static-libs(+)] )
rdma? (
sys-fabric/libibverbs[static-libs(+)]
sys-fabric/librdmacm[static-libs(+)]
)
zlib? ( sys-libs/zlib[static-libs(+)] )"
RDEPEND="!static? ( ${LIB_DEPEND//\[static-libs(+)]} )
gtk? ( x11-libs/gtk+:2 )"
DEPEND="${RDEPEND}
static? ( ${LIB_DEPEND} )"
RDEPEND+="
gnuplot? (
sci-visualization/gnuplot
${PYTHON_DEPS}
)"
S="${WORKDIR}/${MY_P}"
PATCHES=(
"${FILESDIR}"/fio-2.2.13-libmtd.patch
)
src_prepare() {
sed -i '/^DEBUGFLAGS/s: -D_FORTIFY_SOURCE=2::g' Makefile || die
# Many checks don't have configure flags.
sed -i \
-e "s:\<pkg-config\>:$(tc-getPKG_CONFIG):" \
-e '/if compile_prog "" "-lz" "zlib" *; *then/ '"s::if $(usex zlib true false) ; then:" \
-e '/if compile_prog "" "-laio" "libaio" ; then/'"s::if $(usex aio true false) ; then:" \
configure || die
default
}
src_configure() {
chmod g-w "${T}"
# not a real configure script
# TODO: pmem
set -- \
./configure \
--disable-optimizations \
--extra-cflags="${CFLAGS} ${CPPFLAGS}" \
--cc="$(tc-getCC)" \
--disable-pmem \
$(usex glusterfs '' '--disable-gfapi') \
$(usex gtk '--enable-gfio' '') \
$(usex numa '' '--disable-numa') \
$(usex rbd '' '--disable-rbd') \
$(usex rdma '' '--disable-rdma') \
$(usex static '--build-static' '')
echo "$@"
"$@" || die 'configure failed'
}
src_compile() {
emake V=1 OPTFLAGS=
}
src_install() {
emake install DESTDIR="${D}" prefix="${EPREFIX}/usr" mandir="${EPREFIX}/usr/share/man"
if use gnuplot ; then
python_replicate_script \
"${ED}/usr/bin/fio2gnuplot" \
"${ED}/usr/bin/fiologparser_hist.py" \
"${ED}/usr/bin/fio_latency2csv.py" \
"${ED}/usr/bin/fiologparser.py"
else
rm "${ED}"/usr/bin/{fio2gnuplot,fio_generate_plots} || die
rm "${ED}"/usr/share/man/man1/{fio2gnuplot,fio_generate_plots}.1 || die
rm "${ED}"/usr/share/fio/*.gpm || die
rmdir "${ED}"/usr/share/fio/ 2>/dev/null
fi
# This tool has security/parallel issues -- it hardcodes /tmp/template.fio.
rm "${ED}"/usr/bin/genfio || die
dodoc README REPORTING-BUGS HOWTO
docinto examples
dodoc examples/*
}