gentoo-mirror/gentoo
1
0
Fork 0
mirror of https://github.com/gentoo-mirror/gentoo.git synced 2026-09-24 04:59:14 -07:00
Code Issues Projects Releases Wiki Activity

dev-libs/libwacom: add 2.19.0

Browse Source 
Signed-off-by: Lukas Schmelting <lschmelting@posteo.com>
Part-of: https://codeberg.org/gentoo/gentoo/pulls/1106
Signed-off-by: Pacho Ramos <pacho@gentoo.org>
This commit is contained in:
Lukas Schmelting
2026-06-08 20:11:50 +02:00
committed by Pacho Ramos
parent 7604d998b5
commit b9ed3bce8d
2 changed files with 62 additions and 0 deletions
Download Patch File Download Diff File Expand all files Collapse all files

1
dev-libs/libwacom/Manifest
View File

@@ -1,3 +1,4 @@
DIST libwacom-2.16.1.tar.xz 175036 BLAKE2B 60382947f720541f909ec43deab122b737ecc91cc7f7348d9dba8d347676202fd250ad049954156b3372b068ccce6aa0c02f5a53f4e20dee306e4835f619df8a SHA512 9aa78256ee0d485619f85ad1f0b7b0636f936f27c5d42856292653e16f43353c14bae49d635decbacc06bf43fdc0f318a40e8f06faf6e1801a713200c15e8498
DIST libwacom-2.17.0.tar.xz 179796 BLAKE2B 9026f4b2caef0ed06f2514042ccc67334f82931fbb069ab19c2518d824bc9cc3e2e7865736e91b54b9aa3f58755a1fa539adf6b4b266b4079f1099dc626fcfc3 SHA512 da0ef60920877d434a7b77923dd401bea9d784b2d9da72b3fa33a9c6f2572bf0144ba1aa94a76873b05acb2efdecaf9e3096c1853471f7960dbe3bfd9b23311d
DIST libwacom-2.18.0.tar.xz 181360 BLAKE2B 6d5d1e94e03577dc5013682c8d0e008c4c942b0f0b3526b8a9d5fa71e533895e8a4023a815da6217db66f396796f1d5cfdfb6426f554edce1146a0665c6fc21a SHA512 33e0289fbf9e61e113264ebc5fffc89f4c4141dbc2c8807af567888651287e8d8bf2f25140e8dc075b4e9803000486af2d55880c67ee637ead5926db7f39e235
DIST libwacom-2.19.0.tar.xz 185256 BLAKE2B 97b2caf4ed3b2a9be3141773b69c4067b9f9471fd4e0a2468416f2f7ba011535526e997fa74fbea0dd38591467134c6aa95e910103e891ca98cd12e95283d381 SHA512 b3348670a0fb0d570e750e21b59702a4b3dadafd6784758fbe7bdd4d76e019cb805b92cc16608e049f4392165093e7275df1af3619d32a67b8e00055113a4408

61
dev-libs/libwacom/libwacom-2.19.0.ebuild Normal file
View File

@@ -0,0 +1,61 @@
# Copyright 1999-2026 Gentoo Authors
# Distributed under the terms of the GNU General Public License v2
EAPI=8
PYTHON_COMPAT=( python3_{12..14} )
inherit meson python-any-r1 udev
DESCRIPTION="Library for identifying Wacom tablets and their model-specific features"
HOMEPAGE="https://github.com/linuxwacom/libwacom"
SRC_URI="https://github.com/linuxwacom/${PN}/releases/download/${P}/${P}.tar.xz"
LICENSE="MIT"
SLOT="0/9" # libwacom SONAME
KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~loong ~ppc ~ppc64 ~riscv ~x86"
IUSE="doc test"
RESTRICT="!test? ( test )"
RDEPEND="
>=dev-libs/glib-2.68:2
dev-libs/libevdev
dev-libs/libgudev:=
"
DEPEND="${RDEPEND}"
BDEPEND="
${PYTHON_DEPS}
virtual/pkgconfig
doc? ( app-text/doxygen )
test? (
$(python_gen_any_dep '
dev-python/libevdev[${PYTHON_USEDEP}]
dev-python/pyudev[${PYTHON_USEDEP}]
dev-python/pytest[${PYTHON_USEDEP}]
')
)
"
python_check_deps() {
use test || return 0
python_has_version \
"dev-python/libevdev[${PYTHON_USEDEP}]" \
"dev-python/pyudev[${PYTHON_USEDEP}]" \
"dev-python/pytest[${PYTHON_USEDEP}]"
}
src_configure() {
local emesonargs=(
$(meson_feature doc documentation)
$(meson_feature test tests)
-Dudev-dir=$(get_udevdir)
)
meson_src_configure
}
pkg_postinst() {
udev_reload
}
pkg_postrm() {
udev_reload
}