mirror of
https://github.com/gentoo-mirror/gentoo.git
synced 2026-09-24 04:59:14 -07:00
net-fs/samba: Bump to version 4.8.1
Package-Manager: Portage-2.3.31, Repoman-2.3.9
This commit is contained in:
Lars Wendler
@@ -7,4 +7,5 @@ DIST samba-4.6.7-disable-python-patches.tar.xz 8896 BLAKE2B 99496f91d015f10d111e
|
||||
DIST samba-4.7.6.tar.gz 16864824 BLAKE2B 0c519f83e95f9ef9ff13c6a4998d0c98e67765253e855386febe20f836873b10e94161d1539d24af835f464d56edd7f5595abd30b8d6b039cd8ba887563394b1 SHA512 8190b06f543cc3d4a9a98f93ad5e4e16e4e87ea462435723044a780942cea7efc77c66cd3e61941bf449a2ac0f4346ced378f032d5fb1776280a3c4bcb951b46
|
||||
DIST samba-4.7.7.tar.gz 16875059 BLAKE2B 05ecf13562e847070498e923df0cc85836b2fb98d4618942f60e4f28d6c5110b382cfe494e6578bbc06e14052c5d87b0f542ada186e4f132375c4360eaa8bb9f SHA512 78f180f602f08ab9e3000ae016f667e44f059a865b606c21e18857efb89af469c2cb2f9c1316e658badf1a1f41826ba87ccb23f38dc31fe82bf9e5b8fb93daad
|
||||
DIST samba-4.8.0.tar.gz 17659751 BLAKE2B 389d7b6039a00734b514eb017bb201f119b8b894b98af4387ac3186a082b2de295e78b58e96539b93433d3d850e9be19f6ef9a63f66fa9a330f3a88d25b28a03 SHA512 64ffbddb6cf9eee00e5d67a471387b81759c3b4bf67793083aa021e232c8321182182eb9c642b9c25fb1a488f135dec34f7e092d286f94836c488022f8a15c01
|
||||
DIST samba-4.8.1.tar.gz 17675747 BLAKE2B 109692c46e87bcf8a0573c8523943e31086665f6683e4fd634dc5ed93d71da15f82c5354b10883067ea662f947e49b7139208490ae482df6fe3a8209ed77341e SHA512 0c48ca0efc2b5b456e4c77ba7d21cacda9e02534e9715b07f712951e47af1959deb3e30d733324b997573feb1aefd81d1eec1c0b691e417a89d81f302ed9e568
|
||||
DIST samba-disable-python-patches-4.2.12.tar.xz 6052 BLAKE2B 0ae755cbbd8921f4e2f5adf797cd3a77f81bb15ac2d1a65645bc9b53184c397a2bb35f83b88a0de680cc834a63b263e883e91206a7df99735f5ef8f091f54bb0 SHA512 c527d0a052d3211e5b12c17bc94db56cc5e5545189ed65a760c0656c94c22e27a4b159e6439eb0370873e1619873a741f3b3bd10d3876b38eb3914a87eace372
|
||||
|
||||
286
net-fs/samba/samba-4.8.1.ebuild
Normal file
286
net-fs/samba/samba-4.8.1.ebuild
Normal file
@@ -0,0 +1,286 @@
|
||||
# Copyright 1999-2018 Gentoo Foundation
|
||||
# Distributed under the terms of the GNU General Public License v2
|
||||
|
||||
EAPI=6
|
||||
PYTHON_COMPAT=( python2_7 )
|
||||
PYTHON_REQ_USE='threads(+),xml(+)'
|
||||
|
||||
inherit python-single-r1 waf-utils multilib-minimal linux-info systemd
|
||||
|
||||
MY_PV="${PV/_rc/rc}"
|
||||
MY_P="${PN}-${MY_PV}"
|
||||
|
||||
SRC_PATH="stable"
|
||||
[[ ${PV} = *_rc* ]] && SRC_PATH="rc"
|
||||
|
||||
SRC_URI="mirror://samba/${SRC_PATH}/${MY_P}.tar.gz"
|
||||
[[ ${PV} = *_rc* ]] || \
|
||||
KEYWORDS="~amd64 ~arm64 ~hppa ~x86"
|
||||
|
||||
DESCRIPTION="Samba Suite Version 4"
|
||||
HOMEPAGE="http://www.samba.org/"
|
||||
LICENSE="GPL-3"
|
||||
|
||||
SLOT="0"
|
||||
|
||||
IUSE="acl addc addns ads ceph client cluster cups debug dmapi fam gnutls gpg iprint ldap pam python
|
||||
quota selinux syslog system-heimdal +system-mitkrb5 systemd test winbind zeroconf"
|
||||
|
||||
MULTILIB_WRAPPED_HEADERS=(
|
||||
/usr/include/samba-4.0/policy.h
|
||||
/usr/include/samba-4.0/dcerpc_server.h
|
||||
/usr/include/samba-4.0/ctdb.h
|
||||
/usr/include/samba-4.0/ctdb_client.h
|
||||
/usr/include/samba-4.0/ctdb_protocol.h
|
||||
/usr/include/samba-4.0/ctdb_private.h
|
||||
/usr/include/samba-4.0/ctdb_typesafe_cb.h
|
||||
/usr/include/samba-4.0/ctdb_version.h
|
||||
)
|
||||
|
||||
# sys-apps/attr is an automagic dependency (see bug #489748)
|
||||
CDEPEND="
|
||||
>=app-arch/libarchive-3.1.2[${MULTILIB_USEDEP}]
|
||||
dev-lang/perl:=
|
||||
dev-libs/libaio[${MULTILIB_USEDEP}]
|
||||
dev-libs/libbsd[${MULTILIB_USEDEP}]
|
||||
dev-libs/iniparser:0
|
||||
dev-libs/popt[${MULTILIB_USEDEP}]
|
||||
dev-python/subunit[${PYTHON_USEDEP},${MULTILIB_USEDEP}]
|
||||
>=dev-util/cmocka-1.1.1[${MULTILIB_USEDEP}]
|
||||
sys-apps/attr[${MULTILIB_USEDEP}]
|
||||
>=sys-libs/ldb-1.3.2[ldap(+)?,python?,${PYTHON_USEDEP},${MULTILIB_USEDEP}]
|
||||
sys-libs/libcap
|
||||
sys-libs/ncurses:0=[${MULTILIB_USEDEP}]
|
||||
sys-libs/readline:0=
|
||||
>=sys-libs/talloc-2.1.11[python?,${PYTHON_USEDEP},${MULTILIB_USEDEP}]
|
||||
>=sys-libs/tdb-1.3.15[python?,${PYTHON_USEDEP},${MULTILIB_USEDEP}]
|
||||
>=sys-libs/tevent-0.9.36[python?,${PYTHON_USEDEP},${MULTILIB_USEDEP}]
|
||||
sys-libs/zlib[${MULTILIB_USEDEP}]
|
||||
virtual/libiconv
|
||||
pam? ( virtual/pam )
|
||||
acl? ( virtual/acl )
|
||||
addns? (
|
||||
net-dns/bind-tools[gssapi]
|
||||
dev-python/dnspython:=[${PYTHON_USEDEP}]
|
||||
)
|
||||
ceph? ( sys-cluster/ceph )
|
||||
cluster? ( !dev-db/ctdb )
|
||||
cups? ( net-print/cups )
|
||||
debug? ( dev-util/lttng-ust )
|
||||
dmapi? ( sys-apps/dmapi )
|
||||
fam? ( virtual/fam )
|
||||
gnutls? (
|
||||
dev-libs/libgcrypt:0
|
||||
>=net-libs/gnutls-1.4.0
|
||||
)
|
||||
gpg? ( app-crypt/gpgme )
|
||||
ldap? ( net-nds/openldap[${MULTILIB_USEDEP}] )
|
||||
system-heimdal? ( >=app-crypt/heimdal-1.5[-ssl,${MULTILIB_USEDEP}] )
|
||||
system-mitkrb5? ( >=app-crypt/mit-krb5-1.15.1[${MULTILIB_USEDEP}] )
|
||||
systemd? ( sys-apps/systemd:0= )
|
||||
|| (
|
||||
net-libs/libnsl
|
||||
<sys-libs/glibc-2.26[rpc(+)]
|
||||
)
|
||||
"
|
||||
DEPEND="${CDEPEND}
|
||||
${PYTHON_DEPS}
|
||||
app-text/docbook-xsl-stylesheets
|
||||
dev-libs/libxslt
|
||||
net-libs/libtirpc[${MULTILIB_USEDEP}]
|
||||
virtual/pkgconfig
|
||||
|| (
|
||||
net-libs/rpcsvc-proto
|
||||
<sys-libs/glibc-2.26[rpc(+)]
|
||||
)
|
||||
test? (
|
||||
!system-mitkrb5? (
|
||||
>=sys-libs/nss_wrapper-1.1.3
|
||||
>=net-dns/resolv_wrapper-1.1.4
|
||||
>=net-libs/socket_wrapper-1.1.7
|
||||
>=sys-libs/uid_wrapper-1.2.1
|
||||
)
|
||||
)"
|
||||
RDEPEND="${CDEPEND}
|
||||
python? ( ${PYTHON_DEPS} )
|
||||
client? ( net-fs/cifs-utils[ads?] )
|
||||
selinux? ( sec-policy/selinux-samba )
|
||||
!dev-perl/Parse-Yapp
|
||||
"
|
||||
|
||||
REQUIRED_USE="
|
||||
addc? ( python gnutls winbind )
|
||||
addns? ( python )
|
||||
ads? ( acl gnutls ldap winbind )
|
||||
cluster? ( ads )
|
||||
gpg? ( addc )
|
||||
python? ( ldap )
|
||||
test? ( python )
|
||||
?? ( system-heimdal system-mitkrb5 )
|
||||
${PYTHON_REQUIRED_USE}
|
||||
"
|
||||
|
||||
# the test suite is messed, it uses system-installed samba
|
||||
# bits instead of what was built, tests things disabled via use
|
||||
# flags, and generally just fails to work in a way ebuilds could
|
||||
# rely on in its current state
|
||||
RESTRICT="test"
|
||||
|
||||
S="${WORKDIR}/${MY_P}"
|
||||
|
||||
PATCHES=(
|
||||
"${FILESDIR}/${PN}-4.4.0-pam.patch"
|
||||
"${FILESDIR}/${PN}-4.5.1-compile_et_fix.patch"
|
||||
)
|
||||
|
||||
#CONFDIR="${FILESDIR}/$(get_version_component_range 1-2)"
|
||||
CONFDIR="${FILESDIR}/4.4"
|
||||
|
||||
WAF_BINARY="${S}/buildtools/bin/waf"
|
||||
|
||||
SHAREDMODS=""
|
||||
|
||||
pkg_setup() {
|
||||
python-single-r1_pkg_setup
|
||||
if use cluster ; then
|
||||
SHAREDMODS="idmap_rid,idmap_tdb2,idmap_ad"
|
||||
elif use ads ; then
|
||||
SHAREDMODS="idmap_ad"
|
||||
fi
|
||||
}
|
||||
|
||||
src_prepare() {
|
||||
default
|
||||
|
||||
# un-bundle dnspython
|
||||
sed -i -e '/"dns.resolver":/d' "${S}"/third_party/wscript || die
|
||||
|
||||
# unbundle iso8601 unless tests are enabled
|
||||
use test || sed -i -e '/"iso8601":/d' "${S}"/third_party/wscript || die
|
||||
|
||||
# ugly hackaround for bug #592502
|
||||
cp /usr/include/tevent_internal.h "${S}"/lib/tevent/ || die
|
||||
|
||||
sed -e 's:<gpgme\.h>:<gpgme/gpgme.h>:' \
|
||||
-i source4/dsdb/samdb/ldb_modules/password_hash.c \
|
||||
|| die
|
||||
|
||||
# Friggin' WAF shit
|
||||
multilib_copy_sources
|
||||
}
|
||||
|
||||
multilib_src_configure() {
|
||||
# when specifying libs for samba build you must append NONE to the end to
|
||||
# stop it automatically including things
|
||||
local bundled_libs="NONE"
|
||||
if ! use system-heimdal && ! use system-mitkrb5 ; then
|
||||
bundled_libs="heimbase,heimntlm,hdb,kdc,krb5,wind,gssapi,hcrypto,hx509,roken,asn1,com_err,NONE"
|
||||
fi
|
||||
|
||||
local myconf=(
|
||||
--enable-fhs
|
||||
--sysconfdir="${EPREFIX}/etc"
|
||||
--localstatedir="${EPREFIX}/var"
|
||||
--with-modulesdir="${EPREFIX}/usr/$(get_libdir)/samba"
|
||||
--with-piddir="${EPREFIX}/run/${PN}"
|
||||
--bundled-libraries="${bundled_libs}"
|
||||
--builtin-libraries=NONE
|
||||
--disable-rpath
|
||||
--disable-rpath-install
|
||||
--nopyc
|
||||
--nopyo
|
||||
$(multilib_native_use_with acl acl-support)
|
||||
$(multilib_native_usex addc '' '--without-ad-dc')
|
||||
$(multilib_native_use_with addns dnsupdate)
|
||||
$(multilib_native_use_with ads)
|
||||
$(multilib_native_use_enable ceph cephfs)
|
||||
$(multilib_native_use_with cluster cluster-support)
|
||||
$(multilib_native_use_enable cups)
|
||||
$(multilib_native_use_with dmapi)
|
||||
$(multilib_native_use_with fam)
|
||||
$(multilib_native_use_with gpg gpgme)
|
||||
$(multilib_native_use_enable iprint)
|
||||
$(multilib_native_use_with pam)
|
||||
$(multilib_native_usex pam "--with-pammodulesdir=${EPREFIX}/$(get_libdir)/security" '')
|
||||
$(multilib_native_use_with quota quotas)
|
||||
$(multilib_native_use_with syslog)
|
||||
$(multilib_native_use_with systemd)
|
||||
$(multilib_native_use_with winbind)
|
||||
$(multilib_native_usex python '' '--disable-python')
|
||||
$(multilib_native_use_enable zeroconf avahi)
|
||||
$(multilib_native_usex test '--enable-selftest' '')
|
||||
$(usex system-mitkrb5 '--with-system-mitkrb5' '')
|
||||
$(use_enable gnutls)
|
||||
$(use_with debug lttng)
|
||||
$(use_with ldap)
|
||||
)
|
||||
multilib_is_native_abi && myconf+=( --with-shared-modules=${SHAREDMODS} )
|
||||
|
||||
CPPFLAGS="-I${SYSROOT}${EPREFIX}/usr/include/et ${CPPFLAGS}" \
|
||||
waf-utils_src_configure ${myconf[@]}
|
||||
}
|
||||
|
||||
multilib_src_compile() {
|
||||
waf-utils_src_compile
|
||||
}
|
||||
|
||||
multilib_src_install() {
|
||||
waf-utils_src_install
|
||||
|
||||
# Make all .so files executable
|
||||
find "${ED}" -type f -name "*.so" -exec chmod +x {} +
|
||||
|
||||
if multilib_is_native_abi ; then
|
||||
# install ldap schema for server (bug #491002)
|
||||
if use ldap ; then
|
||||
insinto /etc/openldap/schema
|
||||
doins examples/LDAP/samba.schema
|
||||
fi
|
||||
|
||||
# create symlink for cups (bug #552310)
|
||||
if use cups ; then
|
||||
dosym ../../../bin/smbspool /usr/libexec/cups/backend/smb
|
||||
fi
|
||||
|
||||
# install example config file
|
||||
insinto /etc/samba
|
||||
doins examples/smb.conf.default
|
||||
|
||||
# Fix paths in example file (#603964)
|
||||
sed \
|
||||
-e '/log file =/s@/usr/local/samba/var/@/var/log/samba/@' \
|
||||
-e '/include =/s@/usr/local/samba/lib/@/etc/samba/@' \
|
||||
-e '/path =/s@/usr/local/samba/lib/@/var/lib/samba/@' \
|
||||
-e '/path =/s@/usr/local/samba/@/var/lib/samba/@' \
|
||||
-e '/path =/s@/usr/spool/samba@/var/spool/samba@' \
|
||||
-i "${ED%/}"/etc/samba/smb.conf.default || die
|
||||
|
||||
# Install init script and conf.d file
|
||||
newinitd "${CONFDIR}/samba4.initd-r1" samba
|
||||
newconfd "${CONFDIR}/samba4.confd" samba
|
||||
|
||||
systemd_dotmpfilesd "${FILESDIR}"/samba.conf
|
||||
systemd_dounit "${FILESDIR}"/nmbd.service
|
||||
systemd_dounit "${FILESDIR}"/smbd.{service,socket}
|
||||
systemd_newunit "${FILESDIR}"/smbd_at.service 'smbd@.service'
|
||||
systemd_dounit "${FILESDIR}"/winbindd.service
|
||||
systemd_dounit "${FILESDIR}"/samba.service
|
||||
fi
|
||||
}
|
||||
|
||||
multilib_src_test() {
|
||||
if multilib_is_native_abi ; then
|
||||
"${WAF_BINARY}" test || die "test failed"
|
||||
fi
|
||||
}
|
||||
|
||||
pkg_postinst() {
|
||||
ewarn "Be aware the this release contains the best of all of Samba's"
|
||||
ewarn "technology parts, both a file server (that you can reasonably expect"
|
||||
ewarn "to upgrade existing Samba 3.x releases to) and the AD domain"
|
||||
ewarn "controller work previously known as 'samba4'."
|
||||
|
||||
elog "For further information and migration steps make sure to read "
|
||||
elog "http://samba.org/samba/history/${P}.html "
|
||||
elog "http://wiki.samba.org/index.php/Samba4/HOWTO "
|
||||
}
|
||||
Reference in New Issue
Block a user