mirror of
https://github.com/gentoo-mirror/gentoo.git
synced 2026-09-24 04:59:14 -07:00
net-misc/nx: 3.5.99.2 bump
Package-Manager: Portage-2.3.82, Repoman-2.3.20 Signed-off-by: Bernard Cafarelli <voyageur@gentoo.org>
This commit is contained in:
Bernard Cafarelli
@@ -2,3 +2,4 @@ DIST nx-libs-3.5.0.33-full.tar.gz 6811378 BLAKE2B f20de5f9f7214fa38f290b2a200481
|
||||
DIST nx-libs-3.5.99.16-full.tar.gz 5269745 BLAKE2B c968b8dde07e397e84786131cede0dd82979c52069a653de540ec833e5189751db15347aa34cf68db523207aa13ae7507cce0b28b09e897606becdc6effd7fcc SHA512 6b80530345da879e62f9ea506a04c77bd918d3c48d46a22548d1534dab14cae5a715290942fdd5c77708f119522312cd667b6b9f286f106463c5a0debbb0451c
|
||||
DIST nx-libs-3.5.99.17-1-full.tar.gz 5287579 BLAKE2B 8ea54a55071e1161a349ecc1c897b1e774f43567e557cb5b06ed296922b87d2c9c613a58b2d86d7ef912d179d44ed09ca2aa6679c43c334bfbaa31edbf0aff11 SHA512 17c782ccd972c0b97de86195b5994e681570f0184813a8200fea4803d51e5033976e7c8300cb37ba6e811e26e526226a3d4e6a469eecdf772cbba7a12adeeabe
|
||||
DIST nx-libs-3.5.99.20-1-full.tar.gz 5404476 BLAKE2B 62509b76123373e5bed4e13d20ee22e5d52a2911a2a10db0bb73ba0ace4cd63d1f9e3aa900d4909f9a4b35be783d6b5246940108aef71ac785122982cf30d668 SHA512 7be65506c2345724de6986fca5c90d3a62f8a55e1b978d75e858324f85c63873b1ef882417ad313bf546a96252dc37fdaf401751b75cb71af8209002ecb0b602
|
||||
DIST nx-libs-3.5.99.22-full.tar.gz 5280116 BLAKE2B 1a15ba04ace5fd46b007652897aa911a883fa2840c07f4e89db970d3235556ee83600f5cd4d9c4b64f7ce4767dd448a3654412051496754d73a2815a7573692f SHA512 53e7f1ffd8bf9dfd08426e30b0a18433b64f926959ab95132c28960f9a2390e67a34b1e07c923bf11f889088711d7d97c1fd123507f39c2077211d2c3cd6857f
|
||||
|
||||
138
net-misc/nx/nx-3.5.99.22.ebuild
Normal file
138
net-misc/nx/nx-3.5.99.22.ebuild
Normal file
@@ -0,0 +1,138 @@
|
||||
# Copyright 1999-2019 Gentoo Authors
|
||||
# Distributed under the terms of the GNU General Public License v2
|
||||
|
||||
EAPI=7
|
||||
inherit autotools toolchain-funcs
|
||||
|
||||
DESCRIPTION="NX compression technology core libraries"
|
||||
HOMEPAGE="http://www.x2go.org/doku.php/wiki:libs:nx-libs"
|
||||
|
||||
SRC_URI="http://code.x2go.org/releases/source/nx-libs/nx-libs-${PV}-full.tar.gz"
|
||||
|
||||
LICENSE="GPL-2"
|
||||
SLOT="0"
|
||||
KEYWORDS="~amd64 ~ppc ~x86"
|
||||
IUSE="elibc_glibc"
|
||||
|
||||
RDEPEND="
|
||||
dev-libs/libxml2
|
||||
>=media-libs/libpng-1.2.8:0=
|
||||
>=sys-libs/zlib-1.2.3
|
||||
virtual/jpeg:*
|
||||
x11-libs/libX11
|
||||
x11-libs/libXcomposite
|
||||
x11-libs/libXdamage
|
||||
x11-libs/libXdmcp
|
||||
x11-libs/libXext
|
||||
x11-libs/libXfixes
|
||||
x11-libs/libXfont2
|
||||
x11-libs/libXinerama
|
||||
x11-libs/libXpm
|
||||
x11-libs/libXrandr
|
||||
x11-libs/libXrender
|
||||
x11-libs/libXtst
|
||||
x11-libs/pixman
|
||||
"
|
||||
|
||||
DEPEND="${RDEPEND}
|
||||
x11-base/xorg-proto
|
||||
x11-libs/libfontenc
|
||||
x11-misc/gccmakedep
|
||||
x11-misc/imake"
|
||||
|
||||
BDEPEND="
|
||||
virtual/pkgconfig
|
||||
"
|
||||
|
||||
S="${WORKDIR}/nx-libs-${PV}"
|
||||
|
||||
src_prepare() {
|
||||
default
|
||||
|
||||
# We want predictable behavior. So let's assume we never
|
||||
# have quilt installed.
|
||||
sed 's@which quilt@false@' -i mesa-quilt || die
|
||||
|
||||
# Do not compress man pages by default
|
||||
sed '/^[[:space:]]*gzip.*man/d' -i Makefile || die
|
||||
|
||||
# run autoreconf in all needed folders
|
||||
local subdir
|
||||
for subdir in nxcomp nxdialog nx-X11/lib nxcompshad nxproxy ; do
|
||||
pushd ${subdir} || die
|
||||
eautoreconf
|
||||
popd || die
|
||||
done
|
||||
|
||||
# From xorg-x11-6.9.0-r3.ebuild
|
||||
pushd nx-X11 || die
|
||||
HOSTCONF="config/cf/host.def"
|
||||
echo "#define CcCmd $(tc-getCC)" >> ${HOSTCONF}
|
||||
echo "#define OptimizedCDebugFlags ${CFLAGS} GccAliasingArgs" >> ${HOSTCONF}
|
||||
echo "#define OptimizedCplusplusDebugFlags ${CXXFLAGS} GccAliasingArgs" >> ${HOSTCONF}
|
||||
# Respect LDFLAGS
|
||||
echo "#define ExtraLoadFlags ${LDFLAGS}" >> ${HOSTCONF}
|
||||
echo "#define SharedLibraryLoadFlags -shared ${LDFLAGS}" >> ${HOSTCONF}
|
||||
# Disable SunRPC, #370767
|
||||
echo "#define HasSecureRPC NO" >> ${HOSTCONF}
|
||||
}
|
||||
|
||||
src_configure() {
|
||||
local subdir
|
||||
for subdir in nxcomp nxdialog nxcompshad nxproxy ; do
|
||||
pushd ${subdir} || die
|
||||
econf
|
||||
popd || die
|
||||
done
|
||||
|
||||
pushd "nx-X11/lib" || die
|
||||
econf --disable-poll
|
||||
popd || die
|
||||
}
|
||||
|
||||
src_compile() {
|
||||
# First set up the build environment
|
||||
emake build-env
|
||||
|
||||
# We replicate the "build-full" make target here because
|
||||
# we cannot call "make build-full" as it
|
||||
# - calls autoreconf several times
|
||||
# - invokes make directly but we prefer our emake
|
||||
|
||||
emake -C nxcomp
|
||||
emake -C nx-X11/lib
|
||||
|
||||
mkdir -p nx-X11/exports/lib/ || die
|
||||
local nxlib
|
||||
for nxlib in libNX_X11.so{,.6{,.3.0}} ; do
|
||||
ln -s ../../lib/src/.libs/${nxlib} nx-X11/exports/lib/${nxlib} || die
|
||||
done
|
||||
|
||||
emake -C nxcompshad
|
||||
|
||||
./mesa-quilt push -a || die
|
||||
|
||||
emake -C nx-X11 BuildDependsOnly
|
||||
# Parallel make issue resurfaced, upstream working on autotools switch
|
||||
emake -j1 -C nx-X11 World \
|
||||
USRLIBDIR="/usr/$(get_libdir)/${PN}/X11" \
|
||||
SHLIBDIR="/usr/$(get_libdir)"
|
||||
|
||||
emake -C nxproxy
|
||||
}
|
||||
|
||||
src_install() {
|
||||
emake \
|
||||
DESTDIR="${D}" \
|
||||
PREFIX="/usr" \
|
||||
NXLIBDIR="/usr/$(get_libdir)/${PN}" \
|
||||
SHLIBDIR="/usr/$(get_libdir)" \
|
||||
USRLIBDIR="/usr/$(get_libdir)/${PN}/X11" \
|
||||
install
|
||||
|
||||
# Already provided by mesa & related packages
|
||||
rm -r "${ED}"/usr/include/GL || die
|
||||
|
||||
# Get rid of libtool files and static libs.
|
||||
find "${ED}" \( -name "*.a" -o -name "*.la" \) -delete || die
|
||||
}
|
||||
Reference in New Issue
Block a user